Всё началось с вопроса-задачи:
Есть набор «Ксерокопия», в который входит только один материл «Бумага офисная». Для набора определено 2 вида цен: «Розничная» и «От 6 шт». Настроена автоматическая скидка, но она не устанавливается. По условию применения автоматических скидок получается, что скидка не применятся, т.к. не выполняется условие.
Но как это условие выполнить, если скидка настроена на набор, а при его подборе в документ вставляется состав набора? Попробовали скидку сделать отдельно на материал из набора «Бумага офисная» (по таким же параметра) – так работает. Но так не надо, т.к. данный материал использует и в других местах. Как сделать так, чтобы устанавливалась автоматическая скидка для набора?
Данный вопрос был направлен на линию консультации фирмы 1С и был получен ответ:
Работа с автоматическими скидками для наборов в данный момент не поддерживается. Пожелание по добавлению такой возможности уже зарегистрировано, но в отношении сроков реализации сориентировать пока не можем, к сожалению. Добавили Ваш голос к этому пожеланию.
Данный ответ лично нас удовлетворил, но совершенно не удовлетворил нашего заказчика. Пришлось немного доработать функцию «ПолучитьТаблицуТовары» в общем модуле «СкидкиНаценкиСерверПереопределяемый» и автоматические скидки для наборов заработали.
&Вместо("ПолучитьТаблицуТовары")
Функция Дельта_ПолучитьТаблицуТовары(ТаблицаТоваров, пСоответствиеРеквизитов, пМассивУдаляемыхРеквизитов, ТаблицаРабот)
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| РасходнаяНакладнаяЗапасы.КлючСвязи КАК КлючСвязи,
//дельта стало теперь НАЧАЛО
//| ВЫРАЗИТЬ(РасходнаяНакладнаяЗапасы.Номенклатура КАК Справочник.Номенклатура) КАК Номенклатура,
| ВЫБОР
| КОГДА РасходнаяНакладнаяЗапасы.НоменклатураНабора = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
| ТОГДА ВЫРАЗИТЬ(РасходнаяНакладнаяЗапасы.Номенклатура КАК Справочник.Номенклатура)
| ИНАЧЕ ВЫРАЗИТЬ(РасходнаяНакладнаяЗапасы.НоменклатураНабора КАК Справочник.Номенклатура)
| КОНЕЦ КАК Номенклатура,
//дельта стало теперь КОНЕЦ
| РасходнаяНакладнаяЗапасы.Характеристика КАК Характеристика,
| РасходнаяНакладнаяЗапасы.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
| РасходнаяНакладнаяЗапасы.Количество КАК Количество,
| РасходнаяНакладнаяЗапасы.Цена КАК Цена,
| РасходнаяНакладнаяЗапасы.СуммаСкидкиНаценки КАК СуммаСкидкиНаценки,
| РасходнаяНакладнаяЗапасы.СтавкаНДС КАК СтавкаНДС,
| РасходнаяНакладнаяЗапасы.Заказ КАК Заказ,
| РасходнаяНакладнаяЗапасы.Сумма КАК Сумма
|ПОМЕСТИТЬ ВременнаяТаблица
|ИЗ
| &РасходнаяНакладнаяЗапасы КАК РасходнаяНакладнаяЗапасы";
Запрос.Текст = Запрос.Текст + "
|
|;
|";
Если ТаблицаРабот <> Неопределено Тогда
Запрос.Текст = Запрос.Текст +
"ВЫБРАТЬ
| РасходнаяНакладнаяРаботы.КлючСвязиДляСкидокНаценок КАК КлючСвязи,
//дельта стало теперь НАЧАЛО
//| ВЫРАЗИТЬ(РасходнаяНакладнаяРаботы.Номенклатура КАК Справочник.Номенклатура) КАК Номенклатура,
| ВЫБОР
| КОГДА РасходнаяНакладнаяРаботы.НоменклатураНабора = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
| ТОГДА ВЫРАЗИТЬ(РасходнаяНакладнаяРаботы.Номенклатура КАК Справочник.Номенклатура)
| ИНАЧЕ ВЫРАЗИТЬ(РасходнаяНакладнаяРаботы.НоменклатураНабора КАК Справочник.Номенклатура)
| КОНЕЦ КАК Номенклатура,
//дельта стало теперь КОНЕЦ
| РасходнаяНакладнаяРаботы.Характеристика КАК Характеристика,
| РасходнаяНакладнаяРаботы.Количество КАК Количество,
| РасходнаяНакладнаяРаботы.Коэффициент КАК Коэффициент,
| РасходнаяНакладнаяРаботы.Кратность КАК Кратность,
| РасходнаяНакладнаяРаботы.Цена КАК Цена,
| РасходнаяНакладнаяРаботы.СуммаСкидкиНаценки КАК СуммаСкидкиНаценки,
| РасходнаяНакладнаяРаботы.СтавкаНДС КАК СтавкаНДС,
| РасходнаяНакладнаяРаботы.Заказ КАК Заказ,
| РасходнаяНакладнаяРаботы.Сумма КАК Сумма
|ПОМЕСТИТЬ ВременнаяТаблицаРаботы
|ИЗ
| &РасходнаяНакладнаяРаботы КАК РасходнаяНакладнаяРаботы
|ГДЕ
| &ЕстьРаботы";
Запрос.Текст = Запрос.Текст + "
|
|;
|";
КонецЕсли;
Запрос.Текст = Запрос.Текст +
"ВЫБРАТЬ
| ВременнаяТаблица.КлючСвязи КАК КлючСвязи,
| ВременнаяТаблица.Номенклатура КАК Номенклатура,
| ВременнаяТаблица.Характеристика КАК Характеристика,
| ВременнаяТаблица.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
| ВременнаяТаблица.Количество КАК Количество,
| ВременнаяТаблица.Количество * ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ВременнаяТаблица.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ВЫРАЗИТЬ(ВременнаяТаблица.ЕдиницаИзмерения КАК Справочник.ЕдиницыИзмерения).Коэффициент
| ИНАЧЕ 1
| КОНЕЦ КАК КоличествоВБазовыхЕдиницах,
| ВременнаяТаблица.Цена КАК Цена,
| ВременнаяТаблица.СуммаСкидкиНаценки КАК СуммаСкидкиНаценки,
| ВременнаяТаблица.СтавкаНДС КАК СтавкаНДС,
| ВременнаяТаблица.Заказ КАК Заказ,
| ВременнаяТаблица.Сумма КАК Сумма
|ИЗ
| ВременнаяТаблица КАК ВременнаяТаблица
|ГДЕ
| ВременнаяТаблица.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.ПодарочныйСертификат)";
Если ТаблицаРабот <> Неопределено Тогда
Запрос.Текст = Запрос.Текст + "
|
|ОБЪЕДИНИТЬ ВСЕ
|";
Запрос.Текст = Запрос.Текст +
"ВЫБРАТЬ
| ВременнаяТаблицаРаботы.КлючСвязи КАК КлючСвязи,
| ВременнаяТаблицаРаботы.Номенклатура КАК Номенклатура,
| ВременнаяТаблицаРаботы.Характеристика КАК Характеристика,
| НЕОПРЕДЕЛЕНО КАК ЕдиницаИзмерения,
| ВременнаяТаблицаРаботы.Количество * ВременнаяТаблицаРаботы.Коэффициент * ВременнаяТаблицаРаботы.Кратность КАК Количество,
| ВременнаяТаблицаРаботы.Количество * ВременнаяТаблицаРаботы.Коэффициент * ВременнаяТаблицаРаботы.Кратность КАК КоличествоВБазовыхЕдиницах,
| ВременнаяТаблицаРаботы.Цена КАК Цена,
| ВременнаяТаблицаРаботы.СуммаСкидкиНаценки КАК СуммаСкидкиНаценки,
| ВременнаяТаблицаРаботы.СтавкаНДС КАК СтавкаНДС,
| ВременнаяТаблицаРаботы.Заказ КАК Заказ,
| ВременнаяТаблицаРаботы.Сумма КАК Сумма
|ИЗ
| ВременнаяТаблицаРаботы КАК ВременнаяТаблицаРаботы";
КонецЕсли;
Запрос.УстановитьПараметр("РасходнаяНакладнаяЗапасы", ТаблицаТоваров);
Запрос.УстановитьПараметр("РасходнаяНакладнаяРаботы", ?(ТаблицаРабот = Неопределено, Новый ТаблицаЗначений, ТаблицаРабот));
Запрос.УстановитьПараметр("ЕстьРаботы", ТаблицаРабот <> Неопределено);
Если пСоответствиеРеквизитов <> Неопределено Тогда
Для Каждого КлючЗначение Из пСоответствиеРеквизитов Цикл
Запрос.Текст = СтрЗаменить(Запрос.Текст, КлючЗначение.Ключ, КлючЗначение.Значение);
КонецЦикла;
КонецЕсли;
Если пМассивУдаляемыхРеквизитов <> Неопределено Тогда
Для Каждого ТекущееЗначение Из пМассивУдаляемыхРеквизитов Цикл
Запрос.Текст = СтрЗаменить(Запрос.Текст, ",
| РасходнаяНакладнаяЗапасы."+ТекущееЗначение+" КАК "+ТекущееЗначение, "");
Запрос.Текст = СтрЗаменить(Запрос.Текст, ",
| ВременнаяТаблица."+ТекущееЗначение+" КАК "+ТекущееЗначение, "");
// Для заказ-наряда
Запрос.Текст = СтрЗаменить(Запрос.Текст, ",
| РасходнаяНакладнаяРаботы."+ТекущееЗначение+" КАК "+ТекущееЗначение, "");
Запрос.Текст = СтрЗаменить(Запрос.Текст, ",
| ВременнаяТаблицаРаботы."+ТекущееЗначение+" КАК "+ТекущееЗначение, "");
КонецЦикла;
КонецЕсли;
РезультатЗапроса = Запрос.Выполнить();
Возврат РезультатЗапроса.Выгрузить();
КонецФункции
После данной доработки автоматические скидки для набора стали рассчитываться.
Для расчёта автоматических скидок можно самостоятельно доработать указанную функцию или скачать и установить приложенное к публикации расширение.
Разработка и тестирование осуществлялись на конфигурации «1С:Управление нашей фирмой, редакция 1.6» (1.6.18.168) и платформе 1С:Предприятие 8.3 (8.3.18.1289).
