Гарантированно рабочий пример использования длительных операций на БСП с отображением прогресса. [Часть 1]
Разработка - БСП (Библиотека стандартных подсистем)
Введение
Привет всем! В данной статье предлагаю алгоритм по-шагового разбора примера создания "Длительной операции" на самой последней версии библиотеки стандартных подсистем (БСП) на момент публикации статьи - 3.1.3.303.
Вы спросите - для чего эта статья? уже неоднократно разбиралась эта тема, зачем повторять? К своему удивлению, здесь на ресурсе я не нашел НИ ОДНОЙ реально "работающей" статьи по длительным операциям. В примерах много лишнего, много воды, недосказанности, другие примеры - откровенно устарели.
Моя публикация "подводит черту актуальности" на текущую дату - 28.10.2020 - я привожу рабочий пример с "длительной операцией", с отображением прогресса как на основной форме, так и на форме "длительной операции".
В публикации я постараюсь придерживаться стандартов разработки, основанных на системе БСП.
В качестве примера будет разрабатываться внешняя обработка (я бы даже сказал шаблон), которая будет обращаться к созданному мной серверному общему модулю с функциями или процедурами длительных операций.
Не буду использовать расширения - не считаю нужным в этом примере. Так же посмотрим некоторые новые функции БСП для работы с "длительными операциями".
Разработка задания с отражением состояния на форме "Длительной операции"
Свою разработку я начну с написания общего серверного модуля, в котором размещу процедуру для длительной операции. Добавляем вот такой текст процедуры:
&НаСервере
Процедура ПровестиДокументы222(Параметры, АдресРезультата) Экспорт
//МассивВозврат = Новый Массив;
ПоискДляПроведения = Новый Запрос("ВЫБРАТЬ
| РеализацияТоваровУслуг.Ссылка КАК Ссылка
|ИЗ
| Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
|ГДЕ
| РеализацияТоваровУслуг.Дата МЕЖДУ &Дата1 И &Дата2
| И РеализацияТоваровУслуг.Организация = &Организация
|
|УПОРЯДОЧИТЬ ПО
| РеализацияТоваровУслуг.Дата");
ПоискДляПроведения.УстановитьПараметр("Дата1", Параметры.ДатаНач1);
ПоискДляПроведения.УстановитьПараметр("Дата2", Параметры.ДатаОкон1);
ПоискДляПроведения.УстановитьПараметр("Организация", Параметры.Орг1);
НашлиДокументы = ПоискДляПроведения.Выполнить().Выгрузить();
ВсегоДокументов = НашлиДокументы.Количество();
ТекДок = 1;
Для Каждого Стр11 ИЗ НашлиДокументы Цикл
Док = Стр11.Ссылка.ПолучитьОбъект();
Док.Проведен = Ложь;
Док.ПометкаУдаления = Ложь;
Попытка
Док.Записать(РежимЗаписиДокумента.Проведение, РежимПроведенияДокумента.Неоперативный);
Исключение
Док.Записать(РежимЗаписиДокумента.Запись);
КонецПопытки;
ПроцентВыполнения = (ТекДок/ВсегоДокументов)*100;
ПроцентВыполнения = Окр(ПроцентВыполнения,0);
//МассивВозврат.Добавить(ПроцентВыполнения);
// сообщаем "процент" и "текст сообщения"
ДлительныеОперации.СообщитьПрогресс(ПроцентВыполнения,СокрЛП(Док.Ссылка));
ТекДок = ТекДок + 1;
КонецЦикла;
//ПоместитьВоВременноеХранилище(МассивВозврат, АдресРезультата);
КонецПроцедуры
Данная процедура очень простенькая, но для того, чтобы она работала и "отдавала" состояние пользователю нам нужно - во-первых правильно передать ей структуру параметров, чтобы она "запустилась" вообще и во-вторых - использовать функционал БСП сообщать прогресс "Процентом", "Текстом" - ДлительныеОперации.СообщитьПрогресс.
На этом разработка общего модуля так быстро завершена и я перейду к программированию внешней обработки, в которой напишем всю "обвязку" к длительной операции процедурыПровестиДокументы222.
Для начала нарисуем форму обработки:

Рис.1 Базовая форма внешней обработки для запуска длительной операции
Добавим в форму вот такие реквизиты:

Рис.2 Необходимые реквизиты и их типы
Пройдемся по реквизитам : ДатаНачала, ДатаОкончания и Организация - это необходимые реквизиты для запуска процедуры "на удаленке - в фоне".
Индикатор и СтрокаСостояния - вспомогательные реквизиты отображения на форме обработки
ИдЗадания - один из важных реквизитов (он не выводится на форму) - это уникальный идентификатор создаваемого фонового задания, по которому это задание можно будет "отловить" в дальнейшем.
Начнем с написания кода кнопки "Запустить операцию" на форме обработки. Он выглядит вот так - можно его просто скопировать и привязать действие к кнопке (как и все далее - будет сразу работать, кстати):
&НаКлиенте
Процедура ЗапуститьОперацию(Команда)
ИДЗадания = "";
Индикатор = 0;
СтрокаСостояния = "";
ПараметрыЗапуска = Новый Структура;
ПараметрыЗапуска.Вставить("ДатаНач1", НачалоДня(ЭтаФорма.ДатаНачала));
ПараметрыЗапуска.Вставить("ДатаОкон1",КонецДня(ЭтаФорма.ДатаОкончания));
ПараметрыЗапуска.Вставить("Орг1", ЭтаФорма.Организация);
СтруктураФоновогоЗадания = ВыполнитьФоновоеЗаданиеНаСервере(ПараметрыЗапуска, УникальныйИдентификатор);
ИДЗадания = СтруктураФоновогоЗадания.ИдентификаторЗадания;
ПараметрыОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
ПараметрыОжидания.ВыводитьПрогрессВыполнения = Истина;
ПараметрыОжидания.Интервал = 2;
ДлительныеОперацииКлиент.ОжидатьЗавершение(СтруктураФоновогоЗадания, Новый ОписаниеОповещения("ОбработатьДанные", ЭтотОбъект), ПараметрыОжидания);
КонецПроцедуры
В этой процедуре мы заполняем ПараметрыЗапуска для структуры фонового задания, задаем вывод ПрогрессаВыполнения с интервалом на форму длительной операции. Также, мы "активируем" фоновое задание и "отслеживаем его" с помощью ДлительныеОперацииКлиент.ОжидатьЗавершение().
Опишем оповещение "ОбработатьДанные". Это оповещение вызывается при завершении фонового задания. Выглядит вот так:
&НаКлиенте
Процедура ОбработатьДанные(Результат, ДополнительныеПараметры) Экспорт
ОтключитьОбработчикОжидания("ОбработчикОжиданияИндикатор");
Если Результат = Неопределено Тогда
Возврат;
ИначеЕсли Результат.Статус = "Ошибка" Тогда
ОбщегоНазначенияКлиентСервер.СообщитьПользователю(Результат.ПодробноеПредставлениеОшибки);
ЭтаФорма.СтрокаСостояния = "Ошибка";
ИначеЕсли Результат.Статус = "Выполнено" Тогда
ЭтаФорма.Индикатор = 100;
ЭтаФорма.СтрокаСостояния = "Выполнено";
КонецЕсли;
КонецПроцедуры
Теперь, опишем основную функцию внешней обработки ВыполнитьФоновоеЗаданиеНаСервере(). Выглядит она вот так:
&НаСервере
Функция ВыполнитьФоновоеЗаданиеНаСервере(ПараметрыЗапуска, УникальныйИдентификатор)
НаименованиеЗадания = "Моя длительная операции";
ВыполняемыйМетод = "ДлительныйМодуль.ПровестиДокументы222";
ПараметрыВыполнения = ДлительныеОперации.ПараметрыВыполненияВФоне(УникальныйИдентификатор);
ПараметрыВыполнения.НаименованиеФоновогоЗадания = НаименованиеЗадания;
ПараметрыВыполнения.ЗапуститьВФоне = Истина;
ПараметрыВыполнения.Вставить("ИдентификаторФормы", УникальныйИдентификатор);
СтруктураФоновогоЗадания = ДлительныеОперации.ВыполнитьВФоне(ВыполняемыйМетод, ПараметрыЗапуска, ПараметрыВыполнения);
Возврат СтруктураФоновогоЗадания;
КонецФункции
В принципе, все - можно уже работать и получать информацию о статусе фонового задания.
Отмечу сразу, что функция БСП "ВыполнитьВФоне" уже немного устарела. Взамен ее рекомендуют использовать функции - ВыполнитьФункцию и ВыполнитьПроцедуру. Но, о них я напишу чуть позже.
Процесс выполнения фонового задания в "стандартном режиме" будет выглядеть вот так:

Рис.3 Отражение статуса выполнения запущенного фонового задания - в данном случае - это проведение документов.
Так, тут все просто и понятно - достаточно запомнить один раз и использовать многократно. Теперь, перейдем к разработке функционала для отображения статуса и состояния на форме внешней обработки.
Разработка задания с отражением состояния на форме внешней обработки
Для этого изначально доработаем нашу исходную процедуру - повесим в нее "обработчик ожидания" на отслеживание нашего состояния по заданному уникальному идентификатору
&НаКлиенте
Процедура ЗапуститьОперацию(Команда)
ИДЗадания = "";
Индикатор = 0;
СтрокаСостояния = "";
ПараметрыЗапуска = Новый Структура;
ПараметрыЗапуска.Вставить("ДатаНач1", НачалоДня(ЭтаФорма.ДатаНачала));
ПараметрыЗапуска.Вставить("ДатаОкон1",КонецДня(ЭтаФорма.ДатаОкончания));
ПараметрыЗапуска.Вставить("Орг1", ЭтаФорма.Организация);
СтруктураФоновогоЗадания = ВыполнитьФоновоеЗаданиеНаСервере(ПараметрыЗапуска, УникальныйИдентификатор);
ИДЗадания = СтруктураФоновогоЗадания.ИдентификаторЗадания;
ПараметрыОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
//ПараметрыОжидания.ВыводитьПрогрессВыполнения = Истина;
//ПараметрыОжидания.Интервал = 2;
ПараметрыОжидания.ВыводитьОкноОжидания = Ложь;
ДлительныеОперацииКлиент.ОжидатьЗавершение(СтруктураФоновогоЗадания, Новый ОписаниеОповещения("ОбработатьДанные", ЭтотОбъект), ПараметрыОжидания);
// подключим обработку ожидания получения "отклика" на форму
ПодключитьОбработчикОжидания("ОбработчикОжиданияИндикатор",5);
КонецПроцедуры
Так же, заблокируем Интервал и ВыводитьПрогрессВыполнения. И добавим ПараметрыОжидания.ВыводитьОкноОжидания = Ложь (запрет вывода типовой формы длительной операции).
Опишем процедуру ПодключитьОбработкиОжидания - ОбработчикОжиданияИндикатор. Выглядит она вот так:
&НаКлиенте
Процедура ОбработчикОжиданияИндикатор()
Прогресс = ПрочитатьПрогресс(ИДЗадания);
Если НЕ ТипЗнч(Прогресс) = Тип("Структура") Тогда
ЭтаФорма.СтрокаСостояния = "";
Возврат;
КонецЕсли;
Если ТипЗнч(Прогресс) = Тип("Структура")
И Прогресс.Свойство("ЗавершеноАварийно") Тогда
ОтключитьОбработчикОжидания("ОбработчикОжиданияИндикатор");
Возврат;
КонецЕсли;
Если Прогресс.Свойство("ЗаданиеВыполнено") И Прогресс.ЗаданиеВыполнено Тогда
ЭтаФорма.Индикатор = 100;
ЭтаФорма.СтрокаСостояния = "Задание завершено.";
Иначе
Если Прогресс.Свойство("Процент") Тогда
ЭтаФорма.Индикатор = Прогресс.Процент;
КонецЕсли;
Если Прогресс.Свойство("Текст") Тогда
ЭтаФорма.СтрокаСостояния = Прогресс.Текст;
КонецЕсли;
КонецЕсли;
КонецПроцедуры
Серверная функция ПрочитатьПрогресс на базе БСП библиотеки - выглядит вот так:
&НаСервере
Функция ПрочитатьПрогресс(Знач ИдентификаторФоновогоЗадания) Экспорт
Задание = ФоновыеЗадания.НайтиПоУникальномуИдентификатору(ИдентификаторФоновогоЗадания);
Если Задание = Неопределено Тогда
Возврат Неопределено;
КонецЕсли;
Если Задание.Состояние = СостояниеФоновогоЗадания.ЗавершеноАварийно Тогда
ОтключитьОбработчикОжидания("ОбработчикОжиданияИндикатор");
Возврат Неопределено;
КонецЕсли;
// используем БСП
ПрогрессЗадания = ДлительныеОперации.ПрочитатьПрогресс(ИдентификаторФоновогоЗадания);
Если ПрогрессЗадания = Неопределено
Или ТипЗнч(ПрогрессЗадания) <> Тип("Структура") Тогда
ПрогрессЗадания = Новый Структура;
КонецЕсли;
ПрогрессЗадания.Вставить("ЗаданиеВыполнено", ДлительныеОперации.ЗаданиеВыполнено(ИдентификаторФоновогоЗадания));
Возврат ПрогрессЗадания;
КонецФункции
Итог работы данных изменений и добавлений в обработку будет такой:

Рис.4 Отражение статуса выполнения запущенного фонового задания на форме обработке. Окно выполнения фонового задания отключено. Но, процесс идет и отражается на идентификаторе и передает текущее состояние.
Заключение и выводы
В данной статье я сделал выжимку из своего опыта, отсек лишнее и показал как можно быстро и понятно использовать стандартные методы БСП для реализации, так сказать, асинхронности в базах данных 1с (т.е. запуска обработок) без блокирования интерфейса пользователя.
Хорошо это или плохо - 100 % оценить не могу, но по своему опыту всегда пользователь запускал обработку, которая "лочила" его действия в базе.... так, для надежности чтоли....
Хочу отметить, что в БСП функция ВыполнитьВФоне - является на данный момент немного "устаревшей", но до сих пор применяется во многих типовых конфигурациях. Вместо нее предлагают использовать функции - ВыполнитьФункцию и ВыполнитьПроцедуру. Об этих функциях я напишу во второй части данного материала о фоновых заданиях. Но, забегая вперед, данные функции основаны на той же ВыполнитьВФоне - эти функции своего рода надстройки над основной функцией ВыполнитьВФоне
В своем примере я использовал Платформу 1с 8.3.17.1549 и конфигурацию БСП 3.1.3.303.
Еще раз отмечу - почему я решил написать данную статью - на ресурсе я не нашел ничего действенного, очень много лишнего пишет народ, много воды, не хватает вводных данных.
Функции данной статьи вы сможете скопировать к себе в обработку и это все будет работать. Спасибо, что прочитали данную статью.
Другие материалы
Если вам интересен мой практический подход и информация, которую вы сможете реально использовать, если у вас есть желание, чтобы данный комплекс статей наполнялся практическими материалы для программистов - я не откажусь от поддержки как данной статьи, так и всего комплекса статей в целом.
Так же прошу ознакомиться с другими моими статьями по БСП и типовым конфигурациям:
Работаем с контактной информацией в конфигурациях на БСП
Базовые вещи БСП, которые облегчат жизнь программисту 1С
Возможности работы со строками при помощи БСП, которые должен знать каждый программист
ТОП-6 инструментов для разработчика 1С
Подборка лучших инструментов для разработчика 1С включает Toolkit, DCT, OneDebugger, PrintWizard, DataFormWizard и Infostart MCP. Любой инструмент со скидкой 20% при покупке от двух решений.
Вступайте в нашу телеграмм-группу Инфостарт
длительная операция фоновые задания БСП
Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
См. также
БСП (Библиотека стандартных подсистем) Разработчик Платные (руб)
Синтакс-помощник БСП - cправочник по библиотекам стандартных подсистем и электронных документов. В состав справочника входит описание экспортных процедур и функций, размещенных в областях кода ПрограммныйИнтерфейс БСП и БЭД.
3254 руб.
21.11.2024 14653 51 30
Файловый обмен (TXT, XML, DBF), FTP БСП (Библиотека стандартных подсистем) Разработчик 1С:Предприятие 8 1С:Библиотека стандартных подсистем Россия Бесплатно (free)
Продолжение истории о своём движке, который превращает CF в XML без базы и без платформы. Теперь БСП 3.1 выгружается полностью: 9 174 из 9 174 файлов совпадают со штатной выгрузкой байт в байт, ошибок ноль. Для разработчиков, которым интересен внутренний формат 1С и выгрузка конфигураций в файлы.
29.10.2026 2148 vanya_gonchar 21
БСП (Библиотека стандартных подсистем) Разработчик 1С:Предприятие 8 1С:Библиотека стандартных подсистем Бесплатно (free)
Наиболее часто используемые методы БСП 3.1.12. На момент публикации БСП 3.1.12 - является последней версией, и на ней построены все новые типовые конфигурации.
28.09.2026 5026 SergMuravev 2
БСП (Библиотека стандартных подсистем) Разработчик 1С 8.3 1С:Библиотека стандартных подсистем Россия Абонемент ($m)
Все мы когда-то писали свои функции для получения реквизита через точку или парсинга строк. В этой статье собрана выжимка самых полезных и ежедневно необходимых процедур и функций БСП. Никакой сухой документации ИТС — только жизненные кейсы, чистый код и разбор ситуаций, когда стандартные подсистемы делают работу за нас.
1 стартмани
30.07.2026 10421 Elya_Elya 14
БСП (Библиотека стандартных подсистем) Разработчик Стажер 1С:Предприятие 8 1С:Библиотека стандартных подсистем Бесплатно (free)
Часто требуется вывести понятное пользователю сообщение, ткнув его в конкретный проблемный реквизит, что называется, "носом"... И вот тут довольно часто приходится перечитывать параметры функции ОбщегоНазначения[Клиент].СообщениеПользователю. Решила написать для себя шпаргалку и поделиться с сообществом.
24.07.2026 3165 check2 2
БСП (Библиотека стандартных подсистем) Разработчик 1С 8.3 1С:Библиотека стандартных подсистем Бесплатно (free)
Каждый раз, когда разработчик 1С пишет очередной цикл для свертки массива или использует конструкцию Попытка / Исключение для проверки наличия реквизита, где-то грустит один архитектор фирмы «1С». Мы привыкли изобретать велосипеды там, где в Библиотеке стандартных подсистем (БСП) уже давно лежат готовые, оптимизированные и протестированные на тысячах баз решения. Ниже — практическая подборка из 8 методов актуальных релизов БСП (3.X), которые сделают ваш код чище, быстрее и профессиональнее. Разберем на примерах «Было / Стало».
04.06.2026 14086 Kaliostr0 21
Адаптация типовых решений БСП (Библиотека стандартных подсистем) Кадровый учет ЭДО и ОФД 1C:Бухгалтерия 1С:Зарплата и кадры 7.7 1C:ERP 1С:ЗУП 1С:УТ 1С:ДО Платные (руб)
Наше расширение 1С Госключ обеспечивает интеграцию любой конфигурации 1С на базе БСП с мобильным приложением «Госключ», позволяя сотрудникам подписывать кадровые документы (КЭДО) и документы материальной ответственности (МОЛ, ПБ) усиленной электронной подписью прямо со смартфона. Решение автоматизирует формирование и отправку документов на подпись, отслеживает статусы подписания и хранит подписанные файлы непосредственно в базе 1С
25000 руб.
06.03.2026 2806 4 0
БСП (Библиотека стандартных подсистем) Универсальные функции Разработчик 1С 8.3 1С:Библиотека стандартных подсистем Бесплатно (free)
Когда появляется необходимость сделать подключаемую внешнюю обработку, будь это печатная форма или отчет - нам всегда приходится прописывать сведения о внешней обработке для подключения их в соответствующий справочник. И это занимает некоторое время, что не очень удобно. Как для себя, так и для вас - я подготовил ряд примеров использования этой функции, можете выбрать один из них, чтобы в дальнейшем использовать их в шаблонах текста. Комментарии по дополнению и исправлению статьи - приветствуются.
06.02.2026 25742 manul1c 7
За развитие направления "БСП в картинках" плюс.
Код можно под спойлеры убрать, чтобы общее повествование не разрывалось.
Если уж запуск идет во внешней обработке, то надо запускать процедуру в модуле объекта и учесть варианты когда обработка добавлена во внешние и когда через "Файл-открыть".
Ну и еще нужна команда остановки выполнения)
Но через подключенную обработку примерно понимаю как сделать:
1) в общим модуле (можно в расширении) в процедуре (методе) прописать запуск подключенной обработки
2) в обработке подсунуть этот метод (который выполняется в фоне)
п.с. Нажмите "Отмена" и будет остановка
Чтобы выполнить обработку в модуле объекта надо вызывать метод ДлительныеОперации.ВыполнитьПроцедуруМодуляОбъектаОбработки. И в зависимости от того, как подключена обработка передавать нужно разные параметры.
Команда отмены имелась в виду на собственной форме, а не в стандартной.
По тексту:
Выделение жирным шрифтом раздражает глаз.
Про воду, тоже много.
По коду:
Не понравились имена вроде "ПровестиДокументы222" или "Орг1" и т.п. Даже для примера нужно делать красиво.
Описание параметров лучше делать у самой процедуры а не отдельным абзацем, было бы удобно их себе скопировать :)
Она доступна из общего модуля или нужно себе добавлять?
А так да согласен, тоже делал для внешней обработки подобное по публикации (не помню какой, но более менее где хоть понятно было) и хотел убиться об стену :) Будет время проверю вашу.
Молодец, если рабочее :)
Жаль, что так до сих пор нет нормального способа реализации длительных операци именно на клиенте (все примеры реализуют "длительность" только на сервере), уже несколько раз столкнулась с задачами, где выполнение определенных длительных действий могло быть реализовано только на стороне клиента (обращение к объектам, установленным на ПК-клиенте, работа в защищенной сети, в которой находится ПК-клиент и т.п.).
Как то в прошлом году про , было предложено только решение-хак через параллельное открытие другой формы. В новой платформе 8.3.18 упомянули новые способы асинхронности, интересно, решится ли там этот вопрос...
Длительные операции используют разработчики типовых конфигураций. Не припомню, чтобы кто-то описал свой опыт использования длительных операций.
Я вот к примеру, написал про распараллеливание матем. расчетов - как вам статья?
воды много? :)
я предположу, что в самой БСП тоже много воды, лишнего, недосказанности, ряд процедур наверное устарели - следить за развитием БСП - не лучшее времяпрепровождение по жизни.
а вам, как автору спасибо, что поднимаете тему БСП - чем больше примеров, тем легче программировать
С некоторых пор стало тупо жаль время тратить на такие изыскания. Копаешься, берёшь за образец, а оно бац, и "более не используется".
Спасибо, буду использовать.
Надеюсь что действительно - оно будет долго работать.
2-й вариант с выводом индикатора на форму хуже чем 1-й:
1) чуть дольше по времени отработал;
2) периодически подвисала система на доли секунд, через 3-5 секунд;
3) нет возможности прервать выполнение
Гммм, может я что то пропустил - но "УникальныйИдентификатор" - это что, где определяется?
Вот "от нашего стола - вашему столу" пример только на БСП (без своих подписчиков) с выводом прогресса, состояния и сообщений:
Исполняемая процедура:
Процедура ФоновоеЗадание() Экспорт
МаксИнд = 100000;
Для Инд = 1 По МаксИнд Цикл
ПроцентВыполнения = Инд/МаксИнд*100;
Если ПроцентВыполнения%0.1 = 0 Тогда
ДлительныеОперации.СообщитьПрогресс(ПроцентВыполнения,"Выполняется операция: " + ПроцентВыполнения + "%");
КонецЕсли;
Если ПроцентВыполнения%10 = 0 Тогда
ОбщегоНазначения.СообщитьПользователю("Выполнено " + ПроцентВыполнения + "%");
КонецЕсли;
КонецЦикла;
КонецПроцедуры
ПоказатьЗапуск (клиентская часть):
&НаКлиенте
Процедура ВыполнитьОперацию()
// Запустить задание
ДлительнаяОперация = ВыполнитьОперациюНаСервере();
Если ДлительнаяОперация = Неопределено Тогда
ИдентификаторФоновогоЗадания = Неопределено;
Возврат;
КонецЕсли;
ИдентификаторФоновогоЗадания = ДлительнаяОперация.ИдентификаторЗадания;
// Настроить обработку оповещений
ОповещениеПрогрессДлительнойОперации = Новый ОписаниеОповещения("ОповещениеПрогрессДлительнойОперации", ЭтотОбъект);
ОповещениеЗавершенияДлительнойОперации = Новый ОписаниеОповещения("ОповещениеЗавершениеДлительнойОперации", ЭтотОбъект);
ПараметрыОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
ПараметрыОжидания.ВыводитьОкноОжидания = Ложь;
ПараметрыОжидания.ВыводитьПрогрессВыполнения = Истина;
ПараметрыОжидания.ВыводитьСообщения = Истина;
ПараметрыОжидания.ОповещениеОПрогрессеВыполнения = ОповещениеПрогрессДлительнойОперации;
ДлительныеОперацииКлиент.ОжидатьЗавершение(ДлительнаяОперация, ОповещениеЗавершенияДлительнойОперации, ПараметрыОжидания);
КонецПроцедуры
ПоказатьЗапуск (серверная часть):
&НаСервере
Функция ВыполнитьОперациюНаСервере()
ПараметрыВыполнения = ДлительныеОперации.ПараметрыВыполненияПроцедуры();
ПараметрыВыполнения.КлючФоновогоЗадания = "НашеФоновоеЗадание";
ПараметрыВыполнения.НаименованиеФоновогоЗадания = НСтр("ru = 'Наше фоновое задание'");
Результат = ДлительныеОперации.ВыполнитьПроцедуру(ПараметрыВыполнения,"Обработки.НашиФоновыеЗадания.ФоновоеЗадание");
Возврат Результат;
КонецФункции ПоказатьВывод прогресса и сообщений:
&НаКлиенте
Процедура ОповещениеПрогрессДлительнойОперации(Результат, ДополнительныеПараметры) Экспорт
Если Результат <> Неопределено
И Результат.Статус = "Выполняется" Тогда
Если Результат.Свойство("Прогресс")
И Результат.Прогресс <> Неопределено Тогда
ПрогрессОперации = Результат.Прогресс.Процент;
СостояниеОперации = Результат.Прогресс.Текст;
КонецЕсли;
КонецЕсли;
Если Результат.Свойство("Сообщения")
И Результат.Сообщения <> Неопределено Тогда
Для Каждого Сообщение Из Результат.Сообщения Цикл
Сообщение.Сообщить();
КонецЦикла;
КонецЕсли;
КонецПроцедуры
ПоказатьВывод завершения задания:
&НаКлиенте
Процедура ОповещениеЗавершениеДлительнойОперации(Результат, ДополнительныеПараметры) Экспорт
Если Результат = Неопределено
Или Результат.Статус = "Отменено" Тогда
ИдентификаторФоновогоЗадания = Неопределено;;
СостояниеОперации = "Выполнение операции отменено";
ИначеЕсли Результат.Статус = "Выполнено" Тогда
ПрогрессОперации = 100;
ИдентификаторФоновогоЗадания = Неопределено;
СостояниеОперации = "Задание выполнено успешно";
ИначеЕсли Результат.Статус = "Ошибка" Тогда
ИдентификаторФоновогоЗадания = Неопределено;
СостояниеОперации = "Ошибка при выполнении задания";
ШаблонСообщения = НСтр("ru = 'Не удалось выполнить задание.'");
ШаблонСообщения = ШаблонСообщения + Символы.ПС + Результат.ПодробноеПредставлениеОшибки;
ОбщегоНазначенияКлиент.СообщитьПользователю(ШаблонСообщения);
КонецЕсли;
КонецПроцедуры
ПоказатьПрерываение задания:
&НаСервере
Процедура ОстановитьЗаданиеНаСервере()
Если ИдентификаторФоновогоЗадания <> Неопределено Тогда
ДлительныеОперации.ОтменитьВыполнениеЗадания(ИдентификаторФоновогоЗадания);
ИдентификаторФоновогоЗадания = Неопределено;
КонецЕсли;
КонецПроцедуры
Все процедуры, кроме первой, размещены в форме обработки. Реквизиты "ПрогрессОперации" и "СостояниеОперации" связаны с элементами формы типов "Прогресс" и "Текст" соответственно. Реквизит ИдентификаторФоновогоЗадания используется только для прерывания заданий
Я готовлю статью - набор рабочих примеров применения длительных операций, где освежу их применение.
Касаемого вашего вопроса - используйте расширения.
Вобщем (моя точка зрения, после попытки повторить) - и эта статья - несильно отличается других (которые Не Работали у меня, тоже) примеров.
Ну да - воды, слегка поменьше, но - результата, всё-равно не дало.
Конкретизирую -
Мне интересен Прогресс - для внешних обработок.
(Без всяких регистраций в Доп.Обработках - просто открыть и просто Индикатор (и/или Окно - без особой разницы) Прогресса получить.
Первый Описанный Способ ("на форме "Длительной операции""), вроде похож на рабочий, но - Не Доступна процедура из Модуля Внешней Обработки!
(Если подскажете вариант синтаксиса написания для ВыполняемыйМетод, чтобы работало - буду благодарен)
Второй Способ - Просто не Рабочий.
(возможно - причина, как и у других авторов/источников, воды много лишней, в которой распутаться мне не удалось, тоже, но - результат аналогичен им((((...)
- Буду Благодарен.
(подозреваю, нетолько я!)
И да, всем в Новом Году - Всего хорошего!!
суть такая что предварительно пользователь выбрать настройки, ему на экране с помощью запроса вывелись документы, он какие то документы удалил, какие то наоборот добавил в таблице значений. И после он хочет нажать кнопку - изменить количество( в каждом документе, по 200+ строк тч). И посему я хочу передать в фоновое задание итоговую таблицу значений. в ней строки обработать. Не могу сообразить, дайте пожалуйста совет.
У вас процедура, которая должна выполняться в фоне, находится, как я понимаю, в модуле формы внешней обработки. Как указать к ней путь?
ВнешняяОбработка.НазваниеОбработки.МодульОбъекта.НазваниеМетодаМодуляОбъекта
Данный метод недоступен на сервере.
Вместо
Если Задание.Состояние = СостояниеФоновогоЗадания.ЗавершеноАварийно Тогда
ОтключитьОбработчикОжидания("ОбработчикОжиданияИндикатор");
Возврат Неопределено;
КонецЕсли;Сделать:
Если Задание.Состояние = СостояниеФоновогоЗадания.ЗавершеноАварийно Тогда
СтруктураОтвета = Новый Структура;
СтруктураОтвета.Вставить("ЗавершеноАварийно", Истина);
Возврат СтруктураОтвета;
КонецЕсли;при вызове просто подвисает, индикации прогресса нет
Скрытый текст |
|---|
| &НаСервере
Функция ВыполнитьФоновоеЗаданиеНаСервере(ПараметрыЗапуска, УникальныйИдентификатор) НаименованиеЗадания = "Выгрузка реестров в СберБанк"; ВыполняемыйМетод = "ВнешняяОбработка.ЭкспортРеестровСбер.МодульОбъекта.ПровестиДокументы222"; ПараметрыВыполнения = ДлительныеОперации.ПараметрыВыполненияВФоне(УникальныйИдентификатор); ПараметрыВыполнения.НаименованиеФоновогоЗадания = НаименованиеЗадания; ПараметрыВыполнения.ЗапуститьВФоне = Истина; ПараметрыВыполнения.Вставить("ИдентификаторФормы", УникальныйИдентификатор); СтруктураФоновогоЗадания = ДлительныеОперации.ВыполнитьВФоне(ВыполняемыйМетод, ПараметрыЗапуска, ПараметрыВыполнения); Возврат СтруктураФоновогоЗадания; КонецФункции &НаКлиенте Процедура ОбработатьДанные(Результат, ДополнительныеПараметры) Экспорт //ОтключитьОбработчикОжидания("ОбработчикОжиданияИндикатор"); Если Результат = Неопределено Тогда Возврат; ИначеЕсли Результат.Статус = "Ошибка" Тогда ОбщегоНазначенияКлиентСервер.СообщитьПользователю(Результат.ПодробноеПредставлениеОшибки); //ЭтаФорма.СтрокаСостояния = "Ошибка"; ИначеЕсли Результат.Статус = "Выполнено" Тогда //ЭтаФорма.Индикатор = 100; //ЭтаФорма.СтрокаСостояния = "Выполнено"; Сообщить("заебца"); КонецЕсли; КонецПроцедуры &НаКлиенте Процедура Команда2(Команда) ПараметрыЗапуска = Новый Структура; ПараметрыЗапуска.Вставить("ДатаНач1", НачалоДня(ТекущаяДата())); ПараметрыЗапуска.Вставить("ДатаОкон1",КонецДня(ТекущаяДата())); ПараметрыЗапуска.Вставить("Орг1", ""); СтруктураФоновогоЗадания = ВыполнитьФоновоеЗаданиеНаСервере(ПараметрыЗапуска, УникальныйИдентификатор); ИДЗадания = СтруктураФоновогоЗадания.ИдентификаторЗадания; ПараметрыОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект); ПараметрыОжидания.ВыводитьПрогрессВыполнения = Истина; ПараметрыОжидания.ВыводитьОкноОжидания = Истина; ПараметрыОжидания.ВыводитьСообщения = Истина; ПараметрыОжидания.Интервал = 0; ДлительныеОперацииКлиент.ОжидатьЗавершение(СтруктураФоновогоЗадания, Новый ОписаниеОповещения("ОбработатьДанные", ЭтотОбъект), ПараметрыОжидания); КонецПроцедуры |
Скрытый текст |
|---|
| &НаСервере
Процедура ПровестиДокументы222(Параметры, АдресРезультата) Экспорт //МассивВозврат = Новый Массив; ВсегоДокументов = 300000; ТекДок = 1; Для ТекДок = 1 по 300000 Цикл ПроцентВыполнения = (ТекДок/ВсегоДокументов)*100; ПроцентВыполнения = Окр(ПроцентВыполнения,0); //МассивВозврат.Добавить(ПроцентВыполнения); // сообщаем "процент" и "текст сообщения" ДлительныеОперации.СообщитьПрогресс(ПроцентВыполнения,СокрЛП("ыыы")); КонецЦикла; //ПоместитьВоВременноеХранилище(МассивВозврат, АдресРезультата); КонецПроцедуры |
тоже пробовал , не работает
может быть конечно что то сделано не так.
Платформа 8.3.18.1334
БП 3.0.95.24
БСП 3.1.3.494
БП 3.0.95.24
БСП 3.1.3.494
пример не работает
Во избежание избыточного потребления памяти и ее утечек при выполнении одной длительной операции
не следует сообщать прогресс более 100 раз.
Думаю, нужно это учесть в коде процедуры ПровестиДокументы
Более того - такие мелкие шажочки (каждое из которых - действительно ресурсы требует) - просто бессмысленны.
Да - так, размер кода, меньше выходит.
Но, в результате же (например - для выборки из 1000 документов) - придётся сообщать 1000 раз.
Причём "движение" прогресса - рассмотреть трудновато будет.
Именно поэтому - шаг прогрессы обычно делают <=10 (в крайнем случае 5) %.от общего количества.
БСП 3.1.2.223
Отличная статья. Перед тем, как нашел ее, скачал две обработки, ни одна не сработала. Здесь пошагово все расписано, получилось почти с первого раза потому, что с начала взял интервал день. Взял за месяц и все сработало так, как здесь написано. Может быть кто подскажет, как обратиться к функции модуля объекта этой же обработки?
А в форме остается для запуска интерактивно.
Т.е. в форме обвязка, обвязка запускает фоновое, фоновое выполняет метод из модуля менеджера.
Один раз сделал, потом везде копируешь.
А еще есть фишка в параметрами сеанса, передавая их в фон они по новой инициализируются. Поэтому копируем в структуру параметры сеанса и по новой заполняем в фоне, чтобы наши хитрости отработали!
Рейтинг: 4024
Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.
№ 1260411
Создание 29.10.20 06:00
Обновление 22.03.22 16:42
Просмотры 96367
Загрузки 0
Рейтинг
279
Комментарии 71
Код открыт Да
Рубрики БСП (Библиотека стандартных подсистем)
Кому Разработчик
Тип файла Нет файла
Платформа 1С:Предприятие 8
Конфигурация 1C:Бухгалтерия
Операционная система Windows
Страна Россия
Отрасль Не имеет значения
Налоги Не имеет значения
Вид учета Не имеет значения
Доступ к файлу Бесплатно (free)