Доработка документа для формирования проводок в регламентированном учете ERP

Публикация № 1571273 17.12.21

Задачи пользователя - Адаптация типовых решений

Отражение документа в регламентированном учете разработка функционала ERP регламентированный учет проводки хозрасчетный

Статья о том, как включить разработанный документ в подсистему формирования проводок в конфигурации ERP

Ранее в статье я описывал, как включить документ в основные подсистемы БСП на примере ERP, а также сделать формирование движений через механизмы ERP.

Но не затронул такой механизм, как формирование проводок через регистры сведений "Отражение документов в регламентированном учете" и регистре Хозрасчетный соответственно.

Есть разработанный документ, в моем случае "РасшСт_ДополнительныйРасходТоваров". Он уже делает движения по другим регистрам, поэтому мне не нужно для него прописывать процедуры формирования движений в модуле менеджера.

Напомню, что для этого используется подсистема формирования движений.


Процедура ОбработкаПроведения(Отказ, РежимПроведения)
	
	ПроведениеДокументов.ОбработкаПроведенияДокумента(ЭтотОбъект, Отказ);
	
КонецПроцедуры

 

1. Документ должен являться регистратором следующих регистров

Регистр сведений ОтражениеДокументовВРеглУчете

Регистр сведений ОтражениеДокументовВМеждународномУчете

Регистр бухгалтерии Хозрасчетный

Соответственно добавляем их в расширение и в документ "РасшСт_ДополнительныйРасходТоваров" добавляю движения по этим регистрам.

2. Добавляем в модуль регистра бухгалтерии Хозрасчетный дополнительное условие и ключ.


&Перед("ПередЗаписью")
Процедура РасшСт_ПередЗаписью(Отказ, Замещение)
	
	Если ТипЗнч(Отбор.Регистратор.Значение) = Тип("ДокументСсылка.РасшСт_ДополнительныйРасходТоваров") Тогда
		ДополнительныеСвойства.Вставить("НеОтражатьВБюджетировании", Истина);
	КонецЕсли;
	
КонецПроцедуры

Это необходимо, чтобы отключить проведение документа по подсистеме бюджетирования. Есть более сложный вариант, путем добавления документа регистратором регистра накопления "ФактическиеДанныеБюджетирования" и еще кучей мелких доработок, но представленный выше вариант проще.

3. Добавляем в расширение обработку "ОтражениеДокументовВРеглУчете" и две её формы "ПроводкиРегламентированногоУчета" и "ПроводкиРегламентированногоУчетаЧтение".

 

 

Для корректной работы обработки необходимо в указанных выше формах обработки, добавить реквизит формы Документ в расширение и расширить его тип для нашего документа.

 

 

4. Добавить в форму документа команду формирования проводок

 

Описание команды  
Имя ПроводкиРеглУчета
Заголовок Проводки регламентированного учета
Действие ПроводкиРеглУчета
Картинка ЖурналПроводок (добавить в расширение из типовой конфигурации)

 

И выводим эту команду в командную панель

 

 

В модуле формы добавляем обработчик команды

&НаКлиенте
Процедура ПроводкиРеглУчета(Команда)
	
	Отбор = Новый Структура("Регистратор", Объект.Ссылка);
	ПараметрыФормы = Новый Структура("Отбор", Отбор);
	
	Если ЕстьПравоРучнойКорректировкиПроводок() Тогда
		ИмяФормыПроводок = "Обработка.ОтражениеДокументовВРеглУчете.Форма.ПроводкиРегламентированногоУчета";
	Иначе
		ИмяФормыПроводок = "Обработка.ОтражениеДокументовВРеглУчете.Форма.ПроводкиРегламентированногоУчетаЧтение";
	КонецЕсли;
	
	ОткрытьФорму(ИмяФормыПроводок, ПараметрыФормы, ЭтотОбъект,,,,,РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
		
КонецПроцедуры

&НаСервере
Функция ЕстьПравоРучнойКорректировкиПроводок()
	
	Возврат Пользователи.РолиДоступны("ПравоРучнойКорректировкиПроводок");
	
КонецФункции

 

5. Перейдем к модификации модуля менеджера документа.

5.1 В процедуру ЗарегистрироватьУчетныеМеханизмы добавить учетный механизм по регл. учету.

	МеханизмыДокумента.Добавить("РегламентированныйУчет");

 

5.2 В модуле менеджера модифицируем процедуру "ДанныеДокументаДляПроведения". 

необходимо добавить текст запроса для формирования таблицы отражения в регл. учете.

		ТекстЗапросаТаблицаОтражениеДокументовВРеглУчете(ТекстыЗапроса, Регистры);
 
Процедура ТекстЗапросаТаблицаОтражениеДокументовВРеглУчете(ТекстыЗапроса, Регистры)
	
	ИмяРегистра = "ОтражениеДокументовВРеглУчете";
	
	ТекстЗапроса =
	"ВЫБРАТЬ
	|	&Период КАК Период,
	|	&Организация КАК Организация,
	|	НАЧАЛОПЕРИОДА(&Период, ДЕНЬ) КАК ДатаОтражения";
	
	ТекстыЗапроса.Добавить(ТекстЗапроса, ИмяРегистра);
	
КонецПроцедуры

 

Добавить процедуру формирования непосредственно проводок.


Функция ТекстОтраженияВРеглУчете() Экспорт
	
	ТекстЗапроса = "
	|ВЫБРАТЬ
	|
	|	Операция.Ссылка КАК Ссылка,
	|	Операция.Дата КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	ЕСТЬNULL(Суммы.СуммаБезНДСРегл, 0) КАК Сумма,
	|	0 КАК СуммаУУ,
	|
	|	НЕОПРЕДЕЛЕНО КАК ВидСчетаДт,
	|	НЕОПРЕДЕЛЕНО КАК АналитикаУчетаДт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаДт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаДт,
	|	Операция.Подразделение КАК ПодразделениеДт,
	|	НЕОПРЕДЕЛЕНО КАК НаправлениеДеятельностиДт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ТМЦнаскладах) КАК СчетДт,
	|	Строки.Номенклатура КАК СубконтоДт1,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	0 КАК ВалютнаяСуммаДт,
	|	Строки.Количество КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	НЕОПРЕДЕЛЕНО КАК ВидСчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК АналитикаУчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаКт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаКт,
	|	Операция.Подразделение КАК ПодразделениеКт,
	|	НЕОПРЕДЕЛЕНО КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка) КАК СчетКт,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт1,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт3,
	|
	|	0 КАК ВалютнаяСуммаКт,
	|	Строки.Количество КАК КоличествоКт,
	|	0 КАК СуммаНУКт,
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,
	|	""Пример формирования проводки"" КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РасшСт_ДополнительныйРасходТоваров КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РасшСт_ДополнительныйРасходТоваров.Товары КАК Строки
	|	ПО 
	|		(Строки.Ссылка = Операция.Ссылка)
	|	
	|	ЛЕВОЕ СОЕДИНЕНИЕ 
	|		РегистрСведений.СуммыДокументовВВалютахУчета КАК Суммы
	|	ПО 
	|		Строки.Ссылка = Суммы.Регистратор 
	|		И Суммы.СуммаБезНДСРегл <> 0
	|";

	ТекстыОтражения = Новый Массив;
	ТекстыОтражения.Добавить(ТекстЗапроса);
	
	Возврат СтрСоединить(ТекстыОтражения, ОбщегоНазначенияУТ.РазделительЗапросовВОбъединении());
	
КонецФункции

 

Собственно этих доработок достаточно, чтобы базово прописать для документа механизм формирования проводок.

Как это работает. Мы проводим документ. У нас регистрируется запись, что документ необходимо отразить в регл. учете.

 

 

Далее мы нажимаем "Отразить в регл. учете" и у нас формируются проводки.

 

 

Но тут уже работают типовые алгоритмы и подчиняются типовым правилам формирования проводок. В том смысле, что доступна ручная корректировка проводок или работает автоматическое формирование проводок.

В данном примере я использовал забалансовый счет 002.01. Прошу не судить строго, это просто пример, а не практическое пособие как правильно использовать забалансовые счета. Так же в моем документе есть только количество. 

Как вы видите, в функции ТекстОтраженияВРеглУчете можно собрать произвольный запрос для формирования проводок на основе  не только документа.

С каждый релизом платформы, в расширениях появляется все больше возможностей. Возможно в свежих версиях платформы (>=8.3.20), не обязательно добавлять команду формирования проводок в документ, а будет достаточно расширить тип типовой команды.

Писалось и тестировалось на релизе 1С:ERP Управление предприятием 2 (2.5.7.201), платформа 8.3.20.1613.

Скачать файлы

Наименование Файл Версия Размер
Доработка документа для формирования проводок в регламентированном учете ERP:

.cfe 179,05Kb
6
.cfe 179,05Kb 6 Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. glek 117 17.12.21 13:29 Сейчас в теме
Хорошая статья, плюс заслуженный. Только это... может я отстал, но разве в УТ формируются проводки?
2. maraty 358 17.12.21 13:56 Сейчас в теме
(1)
Хорошая статья, плюс заслуженный. Только это... может я отстал, но разве в УТ формируются проводки?

Вот тут наверное я переборщил :) Сама подсистема формирования движений идентична, а вот проводок действительно не должно быть. Спасибо, исправлю.
3. Legavaz 696 07.01.22 09:25 Сейчас в теме
Марат, большое спасибо, за первую и вторую статью! Сэкономил много времени на изучение
4. user811769 13 22.02.22 14:46 Сейчас в теме
Спасибо, хорошая статья!

Сегодня решала аналогичную задачу, на вашу статью наткнулась уже после завершения своей работы)

Отмечу два момента:

1) при доработке конфигурации не через расширение, чтобы избежать изменения настроек поддержки, я скопировала команду "ПроводкиРеглУчета" из обработки "ОтражениеДокументовВРеглУчете" и добавила в свой документ (вместо пунктов 3 и 4).

2) мне потребовалось изменить состав плана обмена ОбновлениеИнформационнойБазы и доработать РеглУчетВыборкиСерверПовтИсп.ИспользуемыеТаблицыДляОтраженияТипа(), чтобы обойти ошибку при выполнении РеглУчетПроведениеСервер.ПроверитьБлокировкуВходящихДанных(). У вас такой ошибки не было?
5. maraty 358 22.02.22 15:45 Сейчас в теме
(4) Если посмотреть процедуру РеглУчетПроведениеСервер.ПроверитьБлокировкуВходящихДанных(), то в ней есть условие
Если ПолучитьФункциональнуюОпцию("ОтложенноеОбновлениеЗавершеноУспешно") Тогда
Возврат; // обновление ИБ завершено полностью
КонецЕсли;

У вас не завершились отложенные обработчики обновления.
Korolev; user811769; +2 Ответить
6. Biilsun 13.05.22 10:26 Сейчас в теме
Спасибо за статью, в версии 2.5.8.179 , как понял нужно и в регистр сведений "ОтражениеДокументовВМеждународномУчете" добавлять документ в качестве регистратора. так как при проведении происходит блокировка по данному регистру в независимости используется международный учет или нет.
на данный кусок кода наткнулся в функции "РеглУчетПроведениеСервер.ВыполнитьОтражение"

Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить("РегистрСведений.ОтражениеДокументовВРеглУчете.НаборЗаписей");
ЭлементБлокировки.УстановитьЗначение("Регистратор", ВыборкаСтатусов.Ссылка);
//++ НЕ УТКА
ЭлементБлокировки = Блокировка.Добавить("РегистрСведений.ОтражениеДокументовВМеждународномУчете.НаборЗаписей");
ЭлементБлокировки.УстановитьЗначение("Регистратор", ВыборкаСтатусов.Ссылка);
//-- НЕ УТКА
ЭлементБлокировки = Блокировка.Добавить("РегистрБухгалтерии.Хозрасчетный.НаборЗаписей");
ЭлементБлокировки.УстановитьЗначение("Регистратор", ВыборкаСтатусов.Ссылка);

Блокировка.Заблокировать();
Оставьте свое сообщение

См. также

Работа с документами PDF

Файловый обмен (TXT, XML, DBF), FTP Адаптация типовых решений Платформа 1С v8.3 1С:Бухгалтерия 3.0 Абонемент ($m)

Начиная с версии 8.3.21, в платформе 1С:Предприятие появились новые объекты для работы с популярным форматом PDF. Примеров использования в типовых конфигурациях пока найти не удалось, но задачи, где это было бы полезно, встречаются. В результате решения некоторых из них и родилось представляемое вашему вниманию расширение.

1 стартмани

12.04.2023    4227    6    VladimirElohov    5    

17

Автоприкрепление документов в ДИАДОК

Обработка документов Документооборот и делопроизводство (СЭД) Адаптация типовых решений ЭДО и ОФД Платформа 1С v8.3 1С:Бухгалтерия 3.0 Абонемент ($m)

"А можно, чтоб подписанные контрагентом документы сами в присоединённые файлы добавлялись?" Ответ сотрудников Диадок: можно. С вас 53 000 (с год назад) или ну хотя бы 30 000 (на днях) ... ага, деньги вы заплатили ... и полная база со всеми доступами, иначе мы пальцем не пошевелим!" Мой ответ: можно. Забирайте.

1 стартмани

20.02.2023    4484    7    e.kogan    5    

17

Корректный вывод суммы и сроков в печатной форме

Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Простой лайфхак для вывода суммы или числа дней В скобках и склоняемых единиц измерения или валюты ЗА скобками.

16.11.2022    942    vladimir-89    0    

12

Дополнительные сведения в типовых конфигурациях 1С

Адаптация типовых решений Платформа 1С v8.3 1С:Бухгалтерия 3.0 Бесплатно (free)

В статье рассказывается, как использование дополнительных сведений помогает расширить функциональность типовых конфигураций без «снятия с замка» и с минимумом программирования.

08.11.2022    6588    accounting_cons    17    

27

Добавляем новый документ в обработку Диадок

Файловый обмен (TXT, XML, DBF), FTP Адаптация типовых решений Платформа 1С v8.3 1С:Комплексная автоматизация 2.х Абонемент ($m)

Добавляем новый документ для подписания и отправки в обработку Диадок (через подключаемый модуль). Отправлять его будем, как неформализованный (внешняя печатная форма в формате pdf).

2 стартмани

07.10.2022    8976    15    John_d    21    

59

Удаление дублирующихся файлов в томах на диске

Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Типовой механизм хранения файлов позволяет один и тот же файл прикреплять несколько раз. Это бесит наших админов, и по их просьбе был реализован следующий алгоритм.

1 стартмани

05.10.2022    4244    5    human_new    19    

29

Сжатие фотографий физических лиц в ЗУП 3.1

Адаптация типовых решений Платформа 1С v8.3 1С:Зарплата и Управление Персоналом 3.x Россия Бесплатно (free)

Сжатие фотографий физических лиц при загрузке, плюс обработка уже загруженных фото.

06.09.2022    1087    mrChOP93    5    

16

Присоединенные файлы в 1С:Бухгалтерии в расширении

Адаптация типовых решений Платформа 1С v8.3 1С:Бухгалтерия 3.0 Россия Абонемент ($m)

Столкнулся с необходимостью добавить возможность прикреплять файлы в конфигурации 1С:Бухгалтерия предприятия, находящейся на поддержке. Разработал расширение, которое можно подключить к конфигурации не снимая ее с поддержки, и реализовать функционал присоединенных файлов к любому документу системы.

3 стартмани

05.09.2022    5710    32    NightBreez    19    

16

Параметризация печатных форм под контрагентов (подключаемое расширение)

Печатные формы Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Расширение добавляет возможности параметризации печати для контрагентов. Подробнее описано здесь https://infostart.ru/1c/articles/1510459/

10 стартмани

05.08.2022    8572    13    sapervodichka    4    

51

Просмотр объектов очереди сообщений в 1С:Документооборот

Адаптация типовых решений Документооборот и делопроизводство (СЭД) Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В базах с бесшовной интеграцией с 1С:Документооборот есть Регистр сведений "Очередь сообщений в 1С:Документооборот". Для пользователя он мало информативен. Расширение позволяет просматривать сообщение в человеческом виде. И понимать проблему до объекта.

2 стартмани

02.08.2022    9240    22    sapervodichka    4    

45

Изменение размера штампа электронной подписи (ЭП) в файле Docx

Документооборот и делопроизводство (СЭД) Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Россия Бесплатно (free)

В конфигурации 1С:Документооборот реализована возможность вставки изображения электронной подписи (ЭП) в файлы формата Docx, Doc, Odt. В данной статье мы расскажем, как изменить размер вставки изображения ЭП в файлы формата Docx.

25.07.2022    2280    iclect    6    

13

Добавление собственного виджета в 1С:Документооборот версии 3.0

Документооборот и делопроизводство (СЭД) Адаптация типовых решений Механизмы типовых конфигураций Платформа 1С v8.3 1С:Документооборот Россия Бесплатно (free)

В данной публикации я хочу описать процесс добавления собственного виджета для отслеживания задач по видам документов в 1С документооборот версии 3.0.

18.07.2022    3033    ArseniyFenix    2    

45

Критерии отбора в расширении. 16+

Адаптация типовых решений Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Абонемент ($m)

Связываем критерии отбора расширения с типовой структурой подчиненности в универсальных решениях 1С.

3 стартмани

09.06.2022    8796    64    Ankare    28    

37

Как настроить вывод списка документов 1С в режиме предприятия? Часть 1. Настройка колонок

Адаптация типовых решений Инструкции пользователю Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данной статье представлена подробная инструкция по настройке списка документов программных продуктах 1С в режиме предприятия. Ответим на следующие вопросы: 1. Как убрать колонку? 2. Как добавить колонку? 3. Как вывести свой реквизит (Добавленный в режиме «Предприятие» или расширением/доработкой). 4. Как поменять порядок вывода колонок ? 5. Как добавить дополнительный элемент, которого нет в документе. (Например: Контактное лицо).

12.05.2022    5104    Yotata    7    

10

Еще раз о дополнительных реквизитах и дополнительных сведениях

Адаптация типовых решений БСП (Библиотека стандартных подсистем) Механизмы типовых конфигураций Платформа 1С v8.3 Конфигурации 1cv8 Россия Бесплатно (free)

Дополнительные реквизиты и сведения существуют давно. Задумка очень хорошая. Суть этих механизмов понятна всем. По этому поводу написано много. Что тут можно сказать нового? Однако бес, как всегда, в деталях. Как создавали реквизиты в объектах типовых конфигураций, так и продолжаем это делать. Почему это происходит? За всех сказать не могу. Могу рассуждать только на своем примере. Являясь убежденным практиком, одно могу сказать вполне определенно. Если что-то на практике недостаточно удобно, то останется оно главным образом в теории... Если не приложить немного усилий.

11.05.2022    9397    user1374747    19    

48

Добавление состояния согласования из 1С: Документооборот

Документооборот и делопроизводство (СЭД) Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Добавляем статус согласования из подключенной базы 1С Документооборот в типовые и нетиповые конфигурации с использованием библиотеки интеграции с 1С: Документооборотом. Статусы добавляются в формы списка и формы объектов.

1 стартмани

11.05.2022    5993    1    Free_Danial    0    

11

Автозаполнение шаблонов файлов MXL в "1С:Документообороте"

Документооборот и делопроизводство (СЭД) Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Добавление возможности создавать автозаполняемые шаблоны файлов в формате MXL в 1С:Документооборот и сохранением заполненного файлы в формате PDF (таблицы, результаты запроса реквизиты...)

1 стартмани

05.05.2022    6840    28    JIEX@    0    

14

Допиливаем типовой отчет "Связанные документы" (структура подчиненности) так, чтобы он видел документы из расширения конфигурации

Адаптация типовых решений Платформа 1С v8.3 1С:ERP Управление предприятием 2 Россия Бесплатно (free)

Наконец-то мы перешли на платформу 1С 8.3.20 и смогли отказаться от режима совместимости в 1С ЕРП. Это позволило нам окончательно закрыть вопрос о перемещении ВСЕХ добавленных объектов из самой конфигурации в её расширение.  Одним из камней преткновения на пути к переезду, был вопрос работы типового отчета "связанные документы".  Ну что же, давайте вместе его решим.

02.05.2022    11447    dima_home    68    

76

Пример доработки проведения в ERP 2.5 по одному регистру накопления

Адаптация типовых решений Платформа 1С v8.3 1С:ERP Управление предприятием 2 Бесплатно (free)

В дополнение к публикации № 1343740 показан быстрый способ встраивания в механизмы конфигурации проведения существующего документа "ПриобретениеТоваровУслуг" по добавленному новому регистру накопления "АТХ_ПартииНоменклатурыДляРемонтовТверь_НД". Пример реализован на 1С:ERP Управление предприятием 2 (2.5.7.390).

27.04.2022    2191    vsasav    5    

29

Получение контактной информации из отбора

Адаптация типовых решений Универсальные функции БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Универсальная функция получения контактной информации из отбора компоновки данных. Весь код в статье.

25.03.2022    1861    ixijixi    0    

12

Не удалось сделать проверку отзыва сертификата в 1С (при маркировке, директ-банк, 1С-Отчетность, ЭДО)

Адаптация типовых решений ЭДО и ОФД Платформа 1С v8.3 Конфигурации 1cv8 Россия Бесплатно (free)

Если возникает ошибка при подписании ЭЦП документов в 1С, при проверке и подписании маркировки и документов в ЧЗ, при подключении к директ-банку и всем, что связано с электронной подписью.

18.03.2022    6441    ClickUp    10    

19

Остаток в табличной части документа

Обработка документов Учет ТМЦ Адаптация типовых решений Платформа 1С v8.3 1С:Управление торговлей 11 Россия Управленческий учет Абонемент ($m)

Расширение, показывающее остаток номенклатуры на текущий момент времени по строчке в табличной части документов.

1 стартмани

16.01.2022    5423    121    user720820720    6    

12

Программное создание и расчет документов начисления зарплаты в конфигурации ЗУП 3.1 и ERP (по подразделениям)

Зарплата Адаптация типовых решений Платформа 1С v8.3 Сложные периодические расчеты 1С:ERP Управление предприятием 2 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

Краткое описание типового механизма расчета зарплаты в конфигурации ЗУП 3.1 и ERP и описание разработанной обработки по программному расчету документов зарплаты в разрезе подразделений. Т.к. формирование документов происходит полностью программно, с минимумов параметров, его можно брать за основу для расчета документов по своим условиям, вплоть до создания по расписанию при необходимости.

10 стартмани

27.12.2021    11003    30    maraty    39    

26

БСП 3.1.5 Форма отчета. Быстрый вызов редактирования варианта

БСП (Библиотека стандартных подсистем) Адаптация типовых решений Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В последних релизах современных конфигураций, основанных на БСП версии 3.1.5, спрятали кнопку настройки варианта в дебри вложенных форм. Вернём всё как было, и даже лучше.

1 стартмани

20.12.2021    6584    1    ixijixi    0    

10

Как сделать сотрудникам детей

Адаптация типовых решений Платформа 1С v8.3 Бесплатно (free)

За этим провокационным заголовком скрывается небольшая задача, которая, однако, вызвала некоторую дискуссию в кулуарах на последней конференции. Как хранить список детей сотрудников - в табличной части справочника или в регистре сведений?

28.10.2021    4323    Alxby    50    

29

Загрузка данных из внешних файлов для управляемых форм

Загрузка и выгрузка в Excel Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Простая и удобная обработка загрузки из файлов формата Excel, dbf и csv для конфигураций на управляемых формах (без модальности). Встраивается в любую конфигурацию (на управляемых формах) в любое место, где нужна загрузка из файлов.

2 стартмани

29.08.2021    6597    27    ALBA2009    2    

15

Обмен УТ 11 (11.4.13.227) с БП 3.0 (из серии - никогда такого не было, и вот опять)

Обмен между базами 1C Адаптация типовых решений Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

После обновления на редакцию Управление торговлей, редакция 11 (11.4.13.227) перестал работать обмен с конфигурацией Бухгалтерия предприятия, редакция 3.0. Расширение конфигурации, исправляющее эту ошибку.

2 стартмани

28.07.2021    14717    50    capitan    21    

14

Подсистема "Пользовательские автоподстановки" для 1С: Документооборот 2.1

Документооборот и делопроизводство (СЭД) Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Россия Управленческий учет Абонемент ($m)

Подсистема позволяет описать собственные алгоритмы автоподстановок исполнителей задач бизнес-процессов. Механизмы подсистемы может использовать любой компетентный пользователь/программист.

1 стартмани

12.05.2021    9943    26    Lok`Tar    16    

14

Исправление ошибки работы с RLS в обработке "Диадок стандартный модуль"

Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

У пользователя стоят ограничения RLS на документе "РеализацияТоваровУслуг" по подразделению(пользователь видит документы только по своему подразделению). Обработка "Диадок стандартный модуль" выдает в таком случае ошибку, потому что пытается показать пользователю все документы без учета RLS.

11.05.2021    3461    John_d    17    

23

Регламентные задания: коротко и ясно о детальных расписаниях

Адаптация типовых решений Платформа 1С v8.3 Бесплатно (free)

Как программно создать регламентное задание и добавить детальные расписания для него.

04.03.2021    14023    user1502278    6    

71

Доработка политики учета серий "Учет себестоимости по сериям" в 1C:ERP

Механизмы типовых конфигураций Адаптация типовых решений Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Бухгалтерский учет Управленческий учет Бесплатно (free)

Политика учета серий "Учет себестоимости по сериям" предполагает обязательное указание серий в заказах, если вид обеспечения установлен "Отгрузить" или "Отгрузить обособленно". Доработка политики учета серий состоит в том, чтобы отключить обязательное заполнение серий в заказах.

01.03.2021    2136    Drivingblind    4    

18

Использование отчета как печатной формы документа

Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пользователь попросил создать новый отчёт, но чтобы была возможность его распечатать из документа (в таком случае отчёт должен формироваться по этому документу), плюс при печати из документа должен быть заголовок и подвал с подписями. Однако, вид у внешней обработки может быть либо "Дополнительный отчет", либо "Печатная форма" (может быть ещё "Отчет" - для документа, но это тоже "либо" и задача была использовать типовой механизм формирования печатных форм). Чтобы не делать, по сути, два одинаковых отчёта, напрашивается мысль создать отдельно отчёт и печатную форму, но печатная форма должна вызывать формирование отчёта. В данной публикации представлен один из способов такой реализации.

20.02.2021    10462    ltfriend    6    

47

Пример создания кадрового отчета для ЗУП 3.1

Адаптация типовых решений Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бесплатно (free)

Пример создания отчёта "Изменение графиков работы" для ЗУП 3.1 с использованием механизма представлений и объекта СхемаЗапроса.

22.12.2020    5185    vazelin    0    

29