Допиливаем типовой отчет "Связанные документы" (структура подчиненности) так, чтобы он видел документы из расширения конфигурации
Задачи пользователя - Адаптация типовых решений
Как вы догадались по названию темы, стандартный отчет "Связанные документы" (Структура подчиненности) требует доработки, поскольку он не видит документы из расширения.
Это и логично, ведь формирование отчета построено на анализе типового объекта конфигурации "КритерииОтбора.СвязанныеДокументы".
Если попытаться решить задачу в лоб - пробросить в расширение типовой критерий отбора "СвязанныеДокументы", то в расширение за ним подтянутся почти все объекты конфигурации и их реквизиты, указанные в критерии отбора. А это почти все документы из типовой конфигурации. Такой подход превратит ваше компактное и изящное расширение конфигурации в нагромождение копий объектов из типовой конфигурации.
Сразу понятно, такое решение не по фэншую. Будем решать задачу по-другому.
Задача:
Есть документ в расширении конфигурации "ИТ_ЗаданиеНаТранспортировку" и в нем есть поле "ДокументОснование", ссылающееся на типовой документ "ЗаказПокупателя". Нужно отразить документ из расширения конфигурации в типовом отчете "Связанные документы".
Условие:
И в новом документе "ИТ_ЗаданиеНаТранспортировку", и в типовом документе "ЗаказПокупателя" должен использоваться типовой отчет "Связанные документы", вызываемый через "СтандартныеПодсистемы.ПодключаемыеКоманды".
Решение:
В расширение ранее уже проброшен документ "ЗаказПокупателя", так как нам нужно было указать тип ссылки в поле "ДокументОснование".
Мы не будем добавлять в расширение типовой критерий отбора "СвязанныеДокументы", вместо этого создаём новый критерий отбора в расширении с названием "ИТ_СвязанныеДокументы" (1).
В разделе "Данные" заполняем тип данных нового критерия отбора теми объектами, которые должны добавляться к стандартному отчету "Связанные документы"
В разделе "Состав" проставляем флажок у реквизита "ДокументОснование" .
Не забываем пробросить в расширение конфигурации типовую роль "ПросмотрСвязанныеДокументы" и в нашем критерии отбора проставляем право на использование для этой роли.
С критерием отбора покончено.
Но стандартный отчет "Связанные документы" пока нас не замечает. Углубляемся в конфигурацию и понимаем, что все действия по выводу отчета производятся в общей форме "СвязанныеДокументы".
Для того, чтобы "научить" общую форму видеть наш критерий отбора из расширения конфигурации, мы пробрасываем в расширение одну процедуру и одну функцию в режиме "ИзменениеИКонтроль" из модуля формы "ОбщаяФорма.СвязанныеДокументы".
Вносим исправления в код.
Процедура "ВывестиРодительскиеОбъекты" большая, всю ее в статью добавлять не буду. В ней нужно изменить в двух местах условия, которые заставляют отчет пропускать документы, не входящие в критерии отбора:
&НаСервере
&ИзменениеИКонтроль("ВывестиРодительскиеОбъекты")
Процедура ИТ_ВывестиРодительскиеОбъекты(ТекущийОбъект, ДеревоРодитель, ВыведенныеОбъекты, СлужебныеОбъекты, ИндексСвязейОбъектов)
//...
// в двух местах, где найдете "Метаданные.КритерииОтбора.СвязанныеДокументы.Состав.Содержит(Реквизит)"
// делаете следующие одинаковые изменения:
#Удаление
Если Не Метаданные.КритерииОтбора.СвязанныеДокументы.Состав.Содержит(Реквизит) Тогда
Продолжить;
КонецЕсли;
#КонецУдаления
#Вставка
Если Не Метаданные.КритерииОтбора.СвязанныеДокументы.Состав.Содержит(Реквизит)
И Не Метаданные.КритерииОтбора.ИТ_СвязанныеДокументы.Состав.Содержит(Реквизит) Тогда
Продолжить;
КонецЕсли;
#КонецВставки
//...
КонецПроцедуры
Функция "ОбъектыПоКритериюОтбора" наоборот - маленькая. Дорабатываем ее, как указано ниже. Код сделан более читаемым в ущерб компактности.
&НаСервере
&ИзменениеИКонтроль("ОбъектыПоКритериюОтбора")
Функция ИТ_ОбъектыПоКритериюОтбора(ЗначениеКритерияОтбора)
#Удаление
Если Не Метаданные.КритерииОтбора.СвязанныеДокументы.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
Возврат Неопределено;
КонецЕсли;
УстановитьПривилегированныйРежим(Истина);
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| СвязанныеДокументы.Ссылка
|ИЗ
| КритерийОтбора.СвязанныеДокументы(&ЗначениеКритерияОтбора) КАК СвязанныеДокументы";
#КонецУдаления
#Вставка
Если Не Метаданные.КритерииОтбора.СвязанныеДокументы.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора))
И Не Метаданные.КритерииОтбора.ИТ_СвязанныеДокументы.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
Возврат Неопределено;
КонецЕсли;
УстановитьПривилегированныйРежим(Истина);
Запрос = Новый Запрос;
ТекстДляЗапроса="";
Если Метаданные.КритерииОтбора.СвязанныеДокументы.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
ТекстДляЗапроса = ТекстДляЗапроса+"ВЫБРАТЬ
| СвязанныеДокументы.Ссылка КАК Ссылка
|ИЗ
| КритерийОтбора.СвязанныеДокументы(&ЗначениеКритерияОтбора) КАК СвязанныеДокументы";
КонецЕсли;
Если Метаданные.КритерииОтбора.ИТ_СвязанныеДокументы.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
Если НЕ ПустаяСтрока(ТекстДляЗапроса) Тогда
ТекстДляЗапроса=ТекстДляЗапроса+"
|
|ОБЪЕДИНИТЬ ВСЕ
|";
КонецЕсли;
ТекстДляЗапроса = ТекстДляЗапроса+"ВЫБРАТЬ
| ИТ_СвязанныеДокументы.Ссылка
|ИЗ
| КритерийОтбора.ИТ_СвязанныеДокументы(&ЗначениеКритерияОтбора) КАК ИТ_СвязанныеДокументы";
КонецЕсли;
Запрос.Текст = ТекстДляЗапроса;
#КонецВставки
Запрос.УстановитьПараметр("ЗначениеКритерияОтбора", ЗначениеКритерияОтбора);
#Вставка
//Это простой костыль от бага в команде "Запрос.Выполнить().Выгрузить()"
//Команда ".Выгрузить()" из результата запроса работает с БАГОМ для смешанных ссылок
//на объекты из основной конфигурации и на объекты из расширения.
НовыйТЗ = Новый ТаблицаЗначений;
НовыйТЗ.Колонки.Добавить("Ссылка");
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
НоваяСтрока = НовыйТЗ.Добавить();
НоваяСтрока.Ссылка = Выборка.Ссылка;
КонецЦикла;
Возврат НовыйТЗ;
#КонецВставки
Возврат Запрос.Выполнить().Выгрузить();
КонецФункции
И в принципе, отчет "Связанные документы" уже будет работать с вашими документами из расширения конфигурации.
Однако, нужно провести еще одну доработку.
Если вы используете подключаемые команды из стандартных подсистем(2) в формах документов/списков документов из расширения, вы заметите, что вожделенный отчет "Связанные документы" не появляется в ваших интерфейсах. Типовая кнопка "Структура подчиненности", которая формирует отчет "Связанные документы", просто принудительно скрывается от нас, если документ отсутствует в индексах связанных объектов.
Давайте просто поправим действия с кнопкой "СтруктураПодчиненности".
Находим типовой общий модуль "СтруктураПодчиненностиСлужебный"(3) и пробрасываем из него в расширение конфигурации функцию "ИндексТиповСвязанныхОбъектов".
Вносим в функцию изменения:
&ИзменениеИКонтроль("ИндексТиповСвязанныхОбъектов")
Функция ИТ_ИндексТиповСвязанныхОбъектов()
Индекс = Новый Соответствие;
МетаданныеСвязанныхОбъектов = Метаданные.КритерииОтбора.СвязанныеДокументы;
ТипыСвязанныхОбъектов = МетаданныеСвязанныхОбъектов.Тип.Типы();
ТипПараметраКоманды = Метаданные.ОбщиеКоманды.СвязанныеДокументы.ТипПараметраКоманды;
Для Каждого ТипСвязанногоОбъекта Из ТипыСвязанныхОбъектов Цикл
Если Не ТипПараметраКоманды.СодержитТип(ТипСвязанногоОбъекта) Тогда
Индекс.Вставить(ТипСвязанногоОбъекта, Истина);
КонецЕсли;
КонецЦикла;
#Вставка
МетаданныеСвязанныхОбъектов = Метаданные.КритерииОтбора.ИТ_СвязанныеДокументы;
ТипыСвязанныхОбъектов = МетаданныеСвязанныхОбъектов.Тип.Типы();
ТипПараметраКоманды = Метаданные.ОбщиеКоманды.СвязанныеДокументы.ТипПараметраКоманды;
Для Каждого ТипСвязанногоОбъекта Из ТипыСвязанныхОбъектов Цикл
Если Не ТипПараметраКоманды.СодержитТип(ТипСвязанногоОбъекта) Тогда
Индекс.Вставить(ТипСвязанногоОбъекта, Истина);
КонецЕсли;
КонецЦикла;
#КонецВставки
Возврат Индекс;
КонецФункции
И все.
Теперь два оба критерия отбора, из основной конфигурации и из расширения, попадают в типовой отчет "Связанные документы".
(1) Префикс "ИТ_" в идентификаторах и префикс "(ИТ) " в синонимах является обязательным для новых объектов в соответствии с политикой внедрений 1С, принятой в нашей компании.
(2) Добавление подключаемых команд из стандартных подсистем на ваши формы документов - это отдельная большая тема, и в данной статье умышленно опущена.
(3) Мне не понятно, почему компания 1С не реализовала функционал добавления новых объектов в специальном модуле "СтруктураПодчиненностиПереопределяемый". Вместо добавления новых, они реализовали функционал по переименованию объектов.
PS: Благодаря комментарию (50), для сохранения режима совместимости с версией 8.3.16, можно воспользоваться опытом из статьи: Николая Ходырева "Критерии отбора в расширении. 16+".
PS: По просьбе комментария (67).
Данное решение не заработает на новых конфигурациях УТ11.5, КА2,5 ЕРП 2,5 и др.
Нужно в основной форме "Связанные документы" - дополнительно в состав реквизитов формы (ДеревоПодчиненныеОбъекты.Ссылка, ДеревоРодительскиеОбъекты.Ссылка, ИсходныйОбъект, ОсновнойОбъект) добавить ссылку на свой добавленный объект. Реализовать можно двумя способами: Тут кто как хочет так пусть и делает: Либо добавить их в расширение на форме и поставить галочки на свои объекты. Либо прописать их кодом ПриСозданииНаСервере.

Вступайте в нашу телеграмм-группу Инфостарт
Связанные документы критерии отбора структура подчиненности.
Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
См. также
Разработка Адаптация типовых решений Производство готовой продукции (работ, услуг) Розничная торговля 1С:Управление торговлей 10 Россия Платные (руб)
Доработка для 1С:Управление торговлей 10.3 (релиз 10.3.88.3) добавляет поддержку маркировки новых категорий товаров согласно постановлениям Правительства РФ 2025–2026 гг. Конфигурация УТ 10.3 снята с поддержки — новые маркируемые категории в типовую поставку больше не попадают. Доработка закрывает этот пробел: новые виды номенклатуры, обмен с ГИС МТ «Честный Знак». Поставляется в виде файла .cf
14640 руб.
23.04.2026 5678 50 13
Банковские операции Адаптация типовых решений Бухгалтер Пользователь 1С:Предприятие 8 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)
Решение позволяет автоматически заполнять отдельные реквизиты загружаемых банковских документов, основываясь на известных значениях реквизитов и тексте назначения платежа. Простая настройка, широкие возможности анализа назначения платежа без написания кода и сложных шаблонов.
12200 руб.
17.06.2025 5417 16 0
Печатные формы Адаптация типовых решений Бухгалтер Пользователь 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Платные (руб)
Расширение позволяет вывести в табличном документе факсимиле печати и подписей и/или вывести произвольную картинку из прикреплённых файлов организации для 1С УТ 11.5, КА 2.5, ERP 2.5, УНФ 3, Розница 3. Вывод факсимиле возможен в табличные документы УПД, УКД, Счёт-фактура, ТОРГ-12 и другие. Возможно настроить вывод для любых типовых макетов (Акт сверки, М-15, ТТН), для этого потребуется отредактировать макет и разместить на нём картинки с соответствующими именами, при выводе на печать в размещённые картинки будут выводиться факсимиле из прикреплённых рисунков. Редактирование осуществляется через типовой механизм в пользовательском интерфейсе.
6000 руб.
07.02.2023 14567 123 25
Адаптация типовых решений 1С:Предприятие 8 1С:Документооборот Россия Платные (руб)
Расширение конфигурации для «1С:Документооборот КОРП», редакция 3.0. позволяет: 1.использовать произвольные табличные части в качестве дополнительных реквизитов к документу; 2 использовать произвольные табличные части в шаблонах в формате docx для автоматического заполнения таблиц.
32330 руб.
29.06.2023 13378 36 15
Логистика, склад и ТМЦ Адаптация типовых решений Пользователь 1С:Предприятие 8 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)
Чтобы не допустить путаницы с обещаниями клиентам и для четкого контроля исполнения заказов мы используем резервирование товаров. Расширение для УНФ, чтобы автоматически отменять старые резервы и не мешалть эффективно продавать.
9150 руб.
02.08.2023 9021 27 5
Адаптация типовых решений Создание на основании Пользователь 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Управленческий учет Платные (руб)
Расширение позволяет в 1 клик поставить весь состав заказа клиента в отгрузку и открыть заполненные формы документов отгрузки по заказу.
4880 руб.
25.08.2023 4344 9 0
Адаптация типовых решений 1С 8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Платные (руб)
Расширение, которое в форму списка и форму выбора справочника «Номенклатура» добавляет табличную часть в виде дерева, в которую выводится информация об остатках и доступности выбранной номенклатурной позиции.
6710 руб.
20.04.2026 1026 1 0
Адаптация типовых решений БСП (Библиотека стандартных подсистем) Кадровый учет ЭДО и ОФД 1C:Бухгалтерия 1С:Зарплата и кадры 7.7 1C:ERP 1С:ЗУП 1С:УТ 1С:ДО Платные (руб)
Наше расширение 1С Госключ обеспечивает интеграцию любой конфигурации 1С на базе БСП с мобильным приложением «Госключ», позволяя сотрудникам подписывать кадровые документы (КЭДО) и документы материальной ответственности (МОЛ, ПБ) усиленной электронной подписью прямо со смартфона. Решение автоматизирует формирование и отправку документов на подпись, отслеживает статусы подписания и хранит подписанные файлы непосредственно в базе 1С
25000 руб.
06.03.2026 2817 4 0
Я не понял вашего вопроса.
В расширении конфигурации заменять типы в критерии отбора не приходится, поскольку мы создаем НОВЫЙ критерий отбора как раз для того, что бы использовать любые свои типы и ссылки из расширения.
PS/ Это решение не подойдёт, если вы захотите создать в расширении конфигурации документ или справочник, который ссылается на все(почти все) объекты в типовой конфигурации. Ведь для указания ссылки на объект из типовой конфигурации вам нужно пробросить его "корень" в расширение.
Все сделал как у Вас.
Но не работает выдает ошибку. (У меня есть самописный документ Доставка на основание него создается документ СчетНаОплатуПокупателя и когда в нем нажимаешь кнопку посмотреть подчиненные документы выдает ошибку:
22.08.2022 19:03:51
TOS_ACC_Логистика: Обычная: Ошибка применения модуля "TOS_ACC_Логистика ОбщаяФорма.СвязанныеДокументы.Форма". Текст модуля для метода "ОбъектыПоКритериюОтбора" изменился
--------------------------------------------------------------------------------
22.08.2022 19:03:51
TOS_ACC_Логистика: Обычная: Ошибка применения модуля "TOS_ACC_Логистика ОбщаяФорма.СвязанныеДокументы.Форма". Текст модуля для метода "ВывестиРодительскиеОбъекты" изменился
--------------------------------------------------------------------------------
22.08.2022 19:03:28
TOS_ACC_Логистика: Обычная: Ошибка применения модуля "TOS_ACC_Логистика ОбщийМодуль.СтруктураПодчиненностиСлужебный.Модуль". Текст модуля для метода "ИндексТиповСвязанныхОбъектов" изменился
Может пункт 2 обязателен и что то из него у меня нет?
P.S. Кнопка Печать в документе есть печатает макет. Кнопка ввести на основание есть и выбор нужного документа это было реализовано до того как я начал делать "Связанные документы".
Помогите понять где ошибка. Спасибо.
Это у вас не проходит проверка применимости расширения при использовании директивы "ИзменениеИКонтроль"
Можно сделать вывод что у вас в этих модулях другой текст... наверно версия конфигурации у вас другая.
Соответственно нужно не бездумно копировать мой код в ваш модуль, а наоборот, свой модуль пробросить в расширение и внести в него изменения по смыслу. Смысл следующий: везде где проверяется стандартный критерий отбора, добавить проверку и критерия отбора из расширения.
Попробуйте полностью убрать (удалить) из расширения конфигурации проблемные объекты
- ОбщийМодуль.СтруктураПодчиненностиСлужебный
- ОбщаяФорма.СвязанныеДокументы.Форма
и заново расширить модули с контролем
Удаление обозначить
#Удаление ... #КонецУдаленияТут аналогичная проблема...
В ближайшее время напишу статью по своему решению аналогичной задачи
&НаСервере
Процедура Лот_ПриСозданииНаСервереПеред(Отказ, СтандартнаяОбработка)
ТипПроизвольный = Новый ОписаниеТипов();
МассивРеквизитов = Новый Массив;
МассивРеквизитов.Добавить(Новый РеквизитФормы("Лот_Ссылка", ТипПроизвольный, "ДеревоПодчиненныеОбъекты", НСтр("ru = 'Лот_Ссылка'")));
МассивРеквизитов.Добавить(Новый РеквизитФормы("Лот_Ссылка", ТипПроизвольный, "ДеревоРодительскиеОбъекты", НСтр("ru = 'Лот_Ссылка'")));
МассивРеквизитов.Добавить(Новый РеквизитФормы("Лот_ОсновнойОбъект", ТипПроизвольный, , НСтр("ru = 'Основной объект (Лотос)'")));
ИзменитьРеквизиты(МассивРеквизитов);
КонецПроцедуры ПоказатьНапример, создавая поддержку стандартных интересов (подключаемых печатных форм, прикладываемых файлов и т.п.) для документов из расширения нам пришлось аналогичным способом решать проблемы, связанные с переопределяемыми типами.
Сложности были аналогичные критериям отбора: нельзя было дополнить переопределяемый тип новыми типами из расширения конфигурации, без проброса в расширение всех объектов из основной конфигурации.
А что если надо добавить в связанные бизнес процесс, ну, задание например?
Или расширить реквизит документы основания и добавить туда пару документов. Это пока никак ведь не обойти?
Не хватает внешнего вида формы идентичного типовым.
Согласны с утверждением и вот почему.
Доработка типового отчета "Связанные документы" (Структура подчинённости) дает неоспоримое преимущество, чем городить свою независимую систему связей документов.
Все документы из типовой конфигурации автоматически показывают кнопку на данный отчет не только в формах документах, но и во всех формах списках (журналах). По сути - это динамический отчет по всем связям. При очередном обновлении, совершенно не приходятся беспокоится, что какая то связь не отразиться.
Изучив пример из (3) у меня мурашки по спине от самой идеи "заполнение регистра сведений при каждом обновлении с доработкой запросов".
Помножьте все на то, что в своих документах в расширении конфигурации мы так же подключаем типовые команды и печатные формы, среди которых автоматом появляется отчет "Связанные документы".
Только тестировать.
Мы когда запускали новый завод на ЕРП, сразу решили уйти от режима совместимости...
Были серьезные проблемы с расширением (конфигурация не сохранялась), Письма в поддержку 1С...ожидание устранения и теперь все работает.
"Помножьте все на то, что в своих документах в расширении конфигурации мы так же подключаем типовые команды и печатные формы" - когда подключаю перехватываю вызов типовой команды.
"8.3.20 и смогли отказаться от режима совместимости в 1С ЕРП" - в вашей ситуации можете добавлять критерии отбора и в данном контексте ваш подход более удобен, но у меня Розницы, УТ и поддержку 8.3.20 завезут не скоро.
(7) Да проблемы будут и типовые вообще не будут запускаться и падать по ошибке проверки этого режима.
Типовая 2.5.7 Конфигурация работает без нареканий, даже не смотря на то, что официально не поддерживается данная платформа (пришлось обмануть чтоб стартовала).
Были серьезные проблемы с расширениями на уровне платформы (писал выше), но потом поправили все в 1С и теперь только 8.3.20.1710 и не ниже. Главные плюсы этой версии - предопределенные объекты в расширении, поддержка "любых ссылок" в расширении.
В функции "ОбъектыПоКритериюОтбора", описанной в статье есть строка с багом:
Возврат Запрос.Выполнить().Выгрузить();Команда ".Выгрузить()" для создаваемой таблицы неверно определяет тип колонки "ССЫЛКА" и в результате мы получаем таблицу с ссылками на "неопределено".
Это возникает только в случае, когда запрос возвращает в одну колонку ссылки на объекты как из основой конфигурации, так и из расширения конфигурации.
Команда "выгрузить()" в этот момент создает колонку с типами объектов только из основной конфигурации и все ссылки на объекты из расширения очищаются. Баг проявляется пока только при работе в запросе с критериями отборов.
Для обхода бага нам пришлось добавить такой костыль:
#Вставка
НовыйТЗ = Новый ТаблицаЗначений;
НовыйТЗ.Колонки.Добавить("Ссылка");
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
НоваяСтрока = НовыйТЗ.Добавить();
НоваяСтрока.Ссылка = Выборка.Ссылка;
КонецЦикла;
Возврат НовыйТЗ;
#КонецВставки
//Возврат Запрос.Выполнить().Выгрузить(); //работает неправильно команда ВЫГРУЗИТЬ().
ПоказатьОбновлю в публикации.
Сделал все как в статье (только у меня типовой документ - "ПриобретениеТоваровУслуг" и свой документ в расширении - "Отгрузка"), но вылетает ошибка:
{ОбщаяФорма.СвязанныеДокументы.Форма(164)}: Значение не является значением объектного типа (Метаданные)
МетаданныеОбъекта = СтрокаДерева.Ссылка.Метаданные();
Стал копать.
В итоге в функции "ДобавитьСтрокуВДерево()" после выполнения строки
ЗаполнитьЗначенияСвойств(НоваяСтрока, Данные, ОбщиеСвойства)НоваяСтрока.Ссылка остается Неопределено, хотя в переменной Данные "Ссылка" заполнена.
Подскажите куда копать ?
&НаСервере
Функция ДобавитьСтрокуВДерево(Родитель, Данные, ВыведенныеОбъекты, ЭтоПодчиненный = Ложь)
УстановитьЧастотуВыводаОбъекта(Данные.Ссылка, ВыведенныеОбъекты, ЭтоПодчиненный);
Если Не ВыводитьТекущийОбъект(Родитель, Данные.Ссылка, ВыведенныеОбъекты, ЭтоПодчиненный) Тогда
Возврат Неопределено;
КонецЕсли;
НоваяСтрока = Родитель.ПолучитьЭлементы().Добавить();
ОбщиеСвойства = "Ссылка, Представление, СуммаДокумента, Валюта, Проведен, ПометкаУдаления";
ЗаполнитьЗначенияСвойств(НоваяСтрока, Данные, ОбщиеСвойства);
ПереопределенноеПредставление = ПредставлениеОбъектаДляВывода(Данные);
Если ПереопределенноеПредставление <> Неопределено Тогда
НоваяСтрока.Представление = ПереопределенноеПредставление;
Иначе
НоваяСтрока.Представление = ПредставлениеОбъектаДляВыводаВОтчет(Данные);
КонецЕсли;
Возврат НоваяСтрока;
КонецФункции ПоказатьУ вас проблема в версии платформы.
В этой функции производится заполнение двух таблиц в общей форме. Таблицы "ДеревоПодчиненныеОбъекты" и "ДеревоРодительскиеОбъекты", они имеют поля "ссылка" с типом "ДокументСсылка".
Поддержка в расширении конфигурации типов "ЛюбаяСсылка", "СправочникСсылка", "ДокументСсылка" началось только с 20 платформы.
На старых платформах документы из расширения не попадают в типы с любыми ссылками... соответственно, когда вы присваиваете такую ссылку, платформа заменяет ссылку на Неопределено.
+/- как и ты в (21). Добавил к ДеревуПодчиненных в расширении реквизит дерева "НашаСсылка" и в процедурах формирования строк дерева проверял на значение.
#Вставка
Если ТИПЗНЧ(Данные.Ссылка) = ТИП("ДокументСсылка.МойДокумент") Тогда
НоваяСТрока.нашаСсылка = Данные.Ссылка;
КонецЕсли;
#КонецВставки
А затем в момент вывода дерева в отчет "СвязанныеДокументы" подменял на свою ссылку.
В статье я об этом писал - мы сняли для ЕРП режим совместимости полностью.
Вам пришлось перехватывать вывод на форму списка и повторно заменять ссылку.
Поэтому пришлось установить платформу 8.3.20 и самый крайний релиз, в котором есть возможность работать БЕЗ режима совместимости вообще.
У УНФ в принципе стоит режим совместимости 8.3.16 и даже 8.3.17 не работал в той версии, хотя в списке выбора был.
"ОбщегоНазначенияКлиентСервер.ВерсияКонфигурацииБезНомераСборки"
&Вместо("ВерсияКонфигурацииБезНомераСборки")
Функция ИТ_ВерсияКонфигурацииБезНомераСборки(Знач Версия) Экспорт
//ИТ на данный момент поддерживается только в режиме совместиости с 3.8.16
// как только официально 1С увеличит поддержку до 3.8.18, эту доработку нужно убрать
Массив = СтрРазделить(Версия, ".");
Если Массив.Количество() < 3 Тогда
Возврат Версия;
КонецЕсли;
Результат = "[Редакция].[Подредакция].[Релиз]";
Результат = СтрЗаменить(Результат, "[Редакция]", Массив[0]);
Результат = СтрЗаменить(Результат, "[Подредакция]", Массив[1]);
Результат = СтрЗаменить(Результат, "[Релиз]", "16"); //Массив[2]); //ИТ наши измения
Возврат Результат;
КонецФункции
ПоказатьЧто то типа
&Вместо("ВывестиПредставлениеИКартинку")
Процедура Расш_ВывестиПредставлениеИКартинку(СтрокаДерева, Макет, ЭтоТекущийОбъект, ЭтоПодчиненный)
//-->
_СтрокаДереваСсылка = СтрокаДерева.Ссылка;
Если Не ЗначениеЗаполнено(СтрокаДерева.Ссылка) Тогда
Для каждого _стр из _Ссылки Цикл
Если СокрЛП(_стр.Представление)=СокрЛП(СтрокаДерева.Представление) Тогда
_СтрокаДереваСсылка = _стр.Значение;
Прервать;
КонецЕсли;
КонецЦикла;
КонецЕсли;
//--<
//МетаданныеОбъекта = СтрокаДерева.Ссылка.Метаданные();
МетаданныеОбъекта = _СтрокаДереваСсылка.Метаданные();
в тексте
а у меня в конфигурации
Процедура ВывестиРодительскиеОбъекты(ТекущийОбъект, ДеревоРодитель, ВыведенныеОбъекты, СлужебныеОбъекты = Неопределено)нет параметра "ИндексСвязейОбъектов" и вообще не отображаются подчиненные объекты в структуре подчиненности.
Конфигурация УНФ 1.6.25.236
Платформа 8.3.18.1779
Режимы совместимости 8.3.16 и у конфы, и у расширения
Процедура "ИТ_ВывестиРодительскиеОбъекты" это выведенная в расширение конфигурации для изменений стандартная процедура "ВывестиРодительскиеОбъекты". Префикс ИТ добавляется в соответствии с настройками расширения
но я обновился до актуального релиза и он появился.
Проблему решил немного по-другому. УНФ отличается от других конфигураций. Много заморочек возникло по поводу режимов совместимости. Но, в принципе, проблему решил.
Благодарю за статью, добавил в избранное.
В УНФ есть общая команда "СвязанныеДокументы", как наверное и в любой другой конфигурации.
В модуле единственная процедура (закомментировано от 1С, конфигурация типовая)
///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright © 2021, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
//
//////////////////////////////////////////////////////////// ///////////////////////////////////////////
#Область ОбработчикиСобытий
&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
Если Не ЗначениеЗаполнено(ПараметрКоманды) Тогда
Возврат;
КонецЕсли;
// УНФ
//ОткрытьФорму("ОбщаяФорма.СвязанныеДокументы",
// Новый Структура("ОбъектОтбора", ПараметрКоманды),
// ПараметрыВыполненияКоманды.Источник,
// ПараметрыВыполненияКоманды.Источник.КлючУникальности,
// ПараметрыВыполненияКоманды.Окно);
//
ОткрытьФорму("ОбщаяФорма.ФормаСтруктурыПодчиненности", Новый Структура("ДокументСсылка", ПараметрКоманды),, Истина, ПараметрыВыполненияКоманды.Окно);
СтатистикаИспользованияФормКлиент.ПроверитьЗаписатьСтатистикуКоманды("СтруктураПодчиненности", ПараметрыВыполненияКоманды.Источник);
// Конец УНФ
КонецПроцедуры
#КонецОбласти
ПоказатьВозникло ощущение, что конкретно для УНФ часть кода изменили и открывается другая общая форма
Я полагаю, что в случае с УНФ нужно либо в расширение перенести из общих форм не "СвязанныеДокументы", а "СтруктураПодчиненности", либо добавить в расширение эту общую команду и заменить форму в фрагменте
ОткрытьФорму("ОбщаяФорма.ФормаСтруктурыПодчиненности", Новый Структура("ДокументСсылка", ПараметрКоманды),, Истина, ПараметрыВыполненияКоманды.Окно);на
ОткрытьФорму("ОбщаяФорма.СвязанныеДокументы", Новый Структура("ДокументСсылка", ПараметрКоманды),, Истина, ПараметрыВыполненияКоманды.Окно);{ОбщаяФорма.СвязанныеДокументы.Форма(164)}:МетаданныеОбъекта = СтрокаДерева.Ссылка.Метаданные();
{ОбщаяФорма.СвязанныеДокументы.Форма(151)}:ВывестиПредставлениеИКартинку(ТекущаяСтрокаДерева, Макет, Ложь, Ложь);
{ОбщаяФорма.СвязанныеДокументы.Форма(99)}:ВывестиРодительскиеЭлементыДерева(ДеревоРодительскиеОбъекты.ПолучитьЭлементы(), Макет);
{ОбщаяФорма.СвязанныеДокументы.Форма(445)}:ВывестиТабличныйДокумент();
{ОбщаяФорма.СвязанныеДокументы.Форма(20)}:ОбновитьДеревоСтруктурыПодчиненности();
{ОбщаяКоманда.СвязанныеДокументы.МодульКоманды(18)}:ОткрытьФорму("ОбщаяФорма.СвязанныеДокументы",
Подскажите куда смотреть?
Все верно.
Я с самого начала в статье написал:
"Наконец-то мы перешли на платформу 1С 8.3.20 и смогли отказаться от режима совместимости в 1С ЕРП."
Только после этого можно реализовать данное решение.
Движок не ниже 8.3.20.1710
Снимается с поддержки корень конфигурации и устанавливаем РЕЖИМ СОВМЕСТИМОСТИ - Не использовать
и поправляются модули
Общий модуль.ОбщегоНазначенияКлиентСервер
Функция ВерсияКонфигурацииБезНомераСборки(Знач Версия) Экспорт
... Результат = СтрЗаменить(Результат, "[Релиз]", "16"); //++ говорим что у нас старый релиз, а не 20 // было: Массив[2]);
У кого не взлетит тут еще шаманьте:
ОбщийМодуль.СтандартныеПодсистемыСервер
Процедура ПередЗапускомПрограммы()
... Или СтрЗаканчиваетсяНа(ТекущийРежимСтрокой, "8_3_20") //++ ИТ добавляем нужную последнюю поддерживаемую версию
Нет не будет, так как поддержка переопределяемых типов в расширениях конфигурации (для критериев отбора) появилась только с 20.1710
(43)
Вы же не полностью снимаете... а переводите в режим "Редактируется с сохранением поддержки"
А подробно можно или у Вас есть расширение которое при снятие той галочки что и где на что изменить? Спасибо.
Соответственно, пробросить в расширение ОбщуюФорму.СвязанныеДокументы у вас не получится. Наверное ))
И к тому же, на форме есть дерево документов, которые использует ссылку на ЛюбойДокумент, что тоже не поддерживается в старый версиях платформы.
Вариант без расширения конфигурации и с пробросом всех документов в расширение конфигурации я не предлагаю.
(55)
Это стандартная команда.
Если вы хотите что бы у вашего документа появились стандартные команды, убедитесь что вы прикрутили типовые обработчики команд в формах.
Форма списка:
#Область ОбработчикиСобытийФормы
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
// СтандартныеПодсистемы.ПодключаемыеКоманды
ПараметрыРазмещения = ПодключаемыеКоманды.ПараметрыРазмещения();
ПараметрыРазмещения.КоманднаяПанель = Элементы.ФормаКоманднаяПанель;
ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект, ПараметрыРазмещения);
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
КонецПроцедуры
#КонецОбласти
#Область ОбработчикиСобытийЭлементов
&НаКлиенте
Процедура СписокПриАктивизацииСтроки(Элемент)
// СтандартныеПодсистемы.ПодключаемыеКоманды
ПодключаемыеКомандыКлиент.НачатьОбновлениеКоманд(ЭтотОбъект);
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
КонецПроцедуры
#КонецОбласти
#Область ОбработчикиКоманд
#КонецОбласти
#Область СлужебныеПроцедурыФункции
// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
ОчиститьСообщения();
ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Элементы.Список);
КонецПроцедуры
&НаСервере
Процедура Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат) Экспорт
ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, Контекст, Элементы.Список, Результат);
КонецПроцедуры
&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Элементы.Список);
КонецПроцедуры
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
#КонецОбласти
ПоказатьФорма документа
////////////////////////////////////////////////////////////
//СОБЫТИЯ ФОРМЫ
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
// СтандартныеПодсистемы.ПодключаемыеКоманды
ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект);
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
КонецПроцедуры
&НаКлиенте
Процедура ПриОткрытии(Отказ)
// СтандартныеПодсистемы.ПодключаемыеКоманды
ПодключаемыеКомандыКлиент.НачатьОбновлениеКоманд(ЭтотОбъект);
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
КонецПроцедуры
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
ПодключаемыеКомандыКлиент.НачатьВыполнениеКоманды(ЭтотОбъект, Команда, Объект);
КонецПроцедуры
&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Объект);
КонецПроцедуры
&НаКлиенте
Процедура Подключаемый_ВыполнитьПереопределяемуюКоманду(Команда)
СобытияФормКлиент.ВыполнитьПереопределяемуюКоманду(ЭтаФорма, Команда);
КонецПроцедуры
Как то так.
И само собой -нужно придерживаться правил наименования групп элементов для команд на форме (подсмотрите в типовом документе).
В статье было описано - как обмануть стандартные процедуры для показа команды "СвязанныеДокументы" для документа из расширения.
один только маааленький минус - Укажите минимальную версию - режима совместимости ....
напоролся на ошибку:
Использование критериев отбора в расширениях недопустимо в режиме совместимости 8.3.15 и ниже
старая конфигурация КА 2.4.13.209 - в режиме совместимости аж 8.3.14
а режим совместимости расширения нельзя сделать выше чем в конфигурации ...
и упс ... это решение не подойдёт
я же написал, что выходит ошибка:
Использование критериев отбора в расширениях недопустимо в режиме совместимости 8.3.15 и ниже
т.е. не важно какая платформа, у нас 8.3.20 стоит, но режим совместимости у конфигурации включён 8.3.14
и критерии отбора в расширении из-за этого не работают.
В этой статье не снимая с поддержки режим совместимости обязан быть не ниже чем 8.3.20 и поэтому автор предлагает снять с поддержки и его отключить. И я ему сразу сказал что я не могу это сделать. Поэтому не снимая с поддержки только автор другой статьи.
ОШИБКА ПЛАТФОРМЫ
Использование критериев отбора в расширениях недопустимо в режиме совместимости 8.3.15 и ниже
В стать, ссылку на которую Вы скинули, и которая и так есть и в этой статье - сразу написано
Итак, с подъемом совместимости актуальных универсальных конфигураций до 8.3.16, мы получили возможность в расширениях использовать Критерии отбора, ....
Отключен режим совместимости.
В скором времени, когда переопределяемые типы и критерии отбора можно будет дополнять через расширение объектами из расширения, то данную статью можно СИЛЬНО упростить.
Про режим совместимости.
Может многие не понимают, но если вы оставляете режим совместимости для своей конфигурации, это значит, что в вашей конфигурации новая платформа работает как старая - без нового функционала и изменения поведения некоторых команд. Режим совместимости вам отключает все новые возможности платформы, включая так нужные доработки в расширениях.
У нас, отключение в конфигурации ЕРП 2.5 режима совместимости на 20 платформе было сопряжено с параллельным устранением ошибок в конфигурации, связанных с изменением поведения работы команды "ПредопределенноеЗначение" в новой платформе.
----------------------------------
Вот выписка из моего письма в 1С поддержку:
"Обнаружили очередную ошибку – попытку получить ПРЕДОПРЕДЕЛЕННОЕЗНАЧЕНИЕ по имени реквизита перечисления, которого нет в конфигурации.
Ошибка обнаруживается в ЕРП только при отключении режима совместимости с 8.3.17
Разница в поведение 1С вызвано тем, что если конфигурация работает с режиме совместимости 8.3.17, то ПРЕДОПРЕДЕЛЕННОЕЗНАЧЕНИЕ по имени реквизита перечисления, которого нет, присвоится значение Неопределено, а на движке 8.3.20 и позже, с отключенным режимом совместимости, уже вызывается исключение."
Комплексная автоматизация, редакция 2, версия 2.5.10.73
Внимание! Минимальные сборки для каждой версии системы 1С:Предприятие для использования текущей версии
"1С:Комплексная автоматизация 2": 8.3.17.2757; 8.3.18.1957; 8.3.19.1723; 8.3.20.2180; 8.3.21.1622; 8.3.22.1704.
Рекомендуемая версия платформы 8.3.21.1622 (и выше) в режиме совместимости "Версия 8.3.17".
Если нет доступа к ИТС и нужно обновление пишите скину.
Поддержка подредакции 2.4 (версия 2.4.14) прекращается с мая 2022 года.
я же не про КА 2.5 говорю,
и да, конечно мы знаем про "снятие с поддержки" ....
так же как УПП каждый год грозили снять с поддержки ещё 10 лет назад.
да, мы будем переходить (переносить многолетние доработки) на КА 2.5
но пока у меня конкретная задача с новым документом в КА 2.4.13.209 в режиме совместимости 8.3.14
и "стандартная" структура подчиненности через Критерии отбора тут НЕ работает
у меня "структура" всегда 1 (мой документ) ко многим (из типовой) - выведу значит просто списком.
А там вроде обновления с 2.4 на 2.5 просто обычным обновлением. Я вот перешел с унф 1.6 на 3.0 все доработки расширения и ВПФ, и отчеты как работали так и работают.
Всё очень правильно описано в статье - только если всё сделать так - то не заработает на новых конфигурациях УТ11.5, КА2,5 ЕРП 2,5 и др.
Нужно в основной форме "Связанные документы" - дополнительно в состав реквизитов формы (ДеревоПодчиненныеОбъекты.Ссылка, ДеревоРодительскиеОбъекты.Ссылка, ИсходныйОбъект, ОсновнойОбъект) добавить ссылку на свой добавленный объект. Реализовать можно двумя способами: Тут кто как хочет так пусть и делает: Либо добавить их в расширение на форме и поставить галочки на свои объекты. Либо прописать их кодом ПриСозданииНаСервере. Скриншот прилагаю.
Если что, в 11.5 (11.5.14.82) это не нужно делать, у них тип ДокументСсылка, СправочникСсылка
А как быть с реквизитами, которые добавили в конфигурацию (основную) к типовым документам - как их учесть в Критерии отбора?
Добавил в расширение и основной документ с реквизитом, а так же документ того типа, который в новом реквизите - В критерии отбора из расширения на закладке Состав ничего не показывает.
Куда копать?
А критерий отбора не видит реквизитов документов! Чувствую что-то упускаю, но не могу понять что.
В Критерии отбора указал все возможные документы (закладка Данные), а закладка Состав - пустая.
Конфа УНФ 3.0.5. платформа 8.3.23. режим совместимости 8.3.21
В конфигурации есть документ Корректировка реализации и Ввод в оборот ИС МП, в типовой конфигурации эти документы не связаны критериями отбора.
Как в вашей статье создал в расширении свой критерий отбора, пробросил эти документы в расширении, но в критерии отбора в разделе состав они не появляются.
Может это быть связано с ограничениями возможностей расширения 8.3.20 или я что-то делаю не так?
Вот выдержка с ИТС
" Критерии отбора
Критерии отбора могут быть заимствованными и собственными. В состав собственных критериев отбора расширения могут входить реквизиты только собственные объектов расширения. Заимствованные критерии отбора могут быть расширены реквизитами только собственных объектов расширения."
&НаСервере
&ИзменениеИКонтроль("ОбъектыПоКритериюОтбора")
Функция ИТ_ОбъектыПоКритериюОтбора(ЗначениеКритерияОтбора)
ШаблонЗапроса = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
| ПредставлениеТаблицы.Ссылка КАК Ссылка
|ИЗ
| ИмяТаблицы КАК ПредставлениеТаблицы
|ГДЕ
| ПредставлениеТаблицы.ИмяРеквизита = &ЗначениеКритерияОтбора";
ШаблонЗапросаОбъединения = "ВЫБРАТЬ
| ПредставлениеТаблицы.Ссылка КАК Ссылка
|ИЗ
| ИмяТаблицы КАК ПредставлениеТаблицы
|ГДЕ
| ПредставлениеТаблицы.ИмяРеквизита = &ЗначениеКритерияОтбора";
ЧастиЗапроса = Новый Массив;
ТекстЧастиЗапроса = "";
Для Каждого ЭлементСостава Из Метаданные.КритерииОтбора.СвязанныеДокументы.Состав Цикл
Если НЕ ЭлементСостава.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
Продолжить;
КонецЕсли;
ПутьКДанным = ЭлементСостава.ПолноеИмя();
Если СтрНайти(ПутьКДанным, "ТабличнаяЧасть") Тогда
ОбъектМетаданных = ЭлементСостава.Родитель().Родитель();
Иначе
ОбъектМетаданных = ЭлементСостава.Родитель();
КонецЕсли;
Если НЕ ПравоДоступа("Чтение", ОбъектМетаданных) Тогда
Продолжить;
КонецЕсли;
Точка = СтрНайти(ПутьКДанным, ".", НаправлениеПоиска.СКонца);
ИмяРеквизита = Сред(ПутьКДанным, Точка + 1);
ИмяТаблицы = ЭлементСостава.Родитель().ПолноеИмя();
ИмяТаблицы = СтрЗаменить(ИмяТаблицы, "ТабличнаяЧасть.", "");
Точка = СтрНайти(ИмяТаблицы, ".", НаправлениеПоиска.СКонца);
ПредставлениеТаблицы = Сред(ИмяТаблицы, Точка + 1);
ТекстЧастиЗапроса = ?(ТекстЧастиЗапроса = "", ШаблонЗапроса, ШаблонЗапросаОбъединения);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяТаблицы", ИмяТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ПредставлениеТаблицы", ПредставлениеТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяРеквизита", ИмяРеквизита);
ЧастиЗапроса.Добавить(ТекстЧастиЗапроса);
КонецЦикла;
#Вставка
Для Каждого ЭлементСостава Из Метаданные.КритерииОтбора.ИТ_СвязанныеДокументы.Состав Цикл
Если НЕ ЭлементСостава.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
Продолжить;
КонецЕсли;
ПутьКДанным = ЭлементСостава.ПолноеИмя();
Если СтрНайти(ПутьКДанным, "ТабличнаяЧасть") Тогда
ОбъектМетаданных = ЭлементСостава.Родитель().Родитель();
Иначе
ОбъектМетаданных = ЭлементСостава.Родитель();
КонецЕсли;
Если НЕ ПравоДоступа("Чтение", ОбъектМетаданных) Тогда
Продолжить;
КонецЕсли;
Точка = СтрНайти(ПутьКДанным, ".", НаправлениеПоиска.СКонца);
ИмяРеквизита = Сред(ПутьКДанным, Точка + 1);
ИмяТаблицы = ЭлементСостава.Родитель().ПолноеИмя();
ИмяТаблицы = СтрЗаменить(ИмяТаблицы, "ТабличнаяЧасть.", "");
Точка = СтрНайти(ИмяТаблицы, ".", НаправлениеПоиска.СКонца);
ПредставлениеТаблицы = Сред(ИмяТаблицы, Точка + 1);
ТекстЧастиЗапроса = ?(ТекстЧастиЗапроса = "", ШаблонЗапроса, ШаблонЗапросаОбъединения);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяТаблицы", ИмяТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ПредставлениеТаблицы", ПредставлениеТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяРеквизита", ИмяРеквизита);
ЧастиЗапроса.Добавить(ТекстЧастиЗапроса);
КонецЦикла;
#КонецВставки
Если ЧастиЗапроса.Количество() > 0 Тогда
Запрос = Новый Запрос;
Разделитель = Символы.ПС + "ОБЪЕДИНИТЬ" + Символы.ПС;
Запрос.Текст = СтрСоединить(ЧастиЗапроса, Разделитель);
Запрос.УстановитьПараметр("ЗначениеКритерияОтбора", ЗначениеКритерияОтбора);
Возврат Запрос.Выполнить().Выгрузить();
Иначе
Возврат Новый ТаблицаЗначений;
КонецЕсли;
КонецФункции
ПоказатьФункция txl_ОбъектыПоКритериюОтбора(ЗначениеКритерияОтбора)
ШаблонЗапроса = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
| ПредставлениеТаблицы.Ссылка КАК Ссылка
|ИЗ
| ИмяТаблицы КАК ПредставлениеТаблицы
|ГДЕ
| ПредставлениеТаблицы.ИмяРеквизита = &ЗначениеКритерияОтбора";
ШаблонЗапросаОбъединения = "ВЫБРАТЬ
| ПредставлениеТаблицы.Ссылка КАК Ссылка
|ИЗ
| ИмяТаблицы КАК ПредставлениеТаблицы
|ГДЕ
| ПредставлениеТаблицы.ИмяРеквизита = &ЗначениеКритерияОтбора";
ЧастиЗапроса = Новый Массив;
ТекстЧастиЗапроса = "";
#Удаление
Для Каждого ЭлементСостава Из Метаданные.КритерииОтбора.СвязанныеДокументы.Состав Цикл
#КонецУдаления
#Вставка
Критерии = Новый Массив;
Критерии.Добавить(Метаданные.КритерииОтбора.СвязанныеДокументы.Состав);
Критерии.Добавить(Метаданные.КритерииОтбора.txl_СвязанныеДокументы.Состав);
Для каждого Критерий Из Критерии Цикл
Для Каждого ЭлементСостава Из Критерий Цикл
#КонецВставки
Если НЕ ЭлементСостава.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
Продолжить;
КонецЕсли;
ПутьКДанным = ЭлементСостава.ПолноеИмя();
Если СтрНайти(ПутьКДанным, "ТабличнаяЧасть") Тогда
ОбъектМетаданных = ЭлементСостава.Родитель().Родитель();
Иначе
ОбъектМетаданных = ЭлементСостава.Родитель();
КонецЕсли;
Если НЕ ПравоДоступа("Чтение", ОбъектМетаданных) Тогда
Продолжить;
КонецЕсли;
Точка = СтрНайти(ПутьКДанным, ".", НаправлениеПоиска.СКонца);
ИмяРеквизита = Сред(ПутьКДанным, Точка + 1);
ИмяТаблицы = ЭлементСостава.Родитель().ПолноеИмя();
ИмяТаблицы = СтрЗаменить(ИмяТаблицы, "ТабличнаяЧасть.", "");
Точка = СтрНайти(ИмяТаблицы, ".", НаправлениеПоиска.СКонца);
ПредставлениеТаблицы = Сред(ИмяТаблицы, Точка + 1);
ТекстЧастиЗапроса = ?(ТекстЧастиЗапроса = "", ШаблонЗапроса, ШаблонЗапросаОбъединения);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяТаблицы", ИмяТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ПредставлениеТаблицы", ПредставлениеТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяРеквизита", ИмяРеквизита);
ЧастиЗапроса.Добавить(ТекстЧастиЗапроса);
КонецЦикла;
#Вставка
КонецЦикла;
#КонецВставки
Если ЧастиЗапроса.Количество() > 0 Тогда
Запрос = Новый Запрос;
Разделитель = Символы.ПС + "ОБЪЕДИНИТЬ" + Символы.ПС;
Запрос.Текст = СтрСоединить(ЧастиЗапроса, Разделитель);
Запрос.УстановитьПараметр("ЗначениеКритерияОтбора", ЗначениеКритерияОтбора);
Возврат Запрос.Выполнить().Выгрузить();
Иначе
Возврат Новый ТаблицаЗначений;
КонецЕсли;
КонецФункции
ПоказатьОднако, в общей форме "СвязанныеОбъекты" также нужно расширить типы реквизитов формы, которые обозначение как ДокументСсылка дополнительно ссылками на добавленные документы.
Реквизиты: ОсновнойОбъект, ИсходныйОбъект, реквизиты табличных частей:
ДеревоПодчиненныеОбъекты.Ссылка
ДеревоРодительскиеОбъекты.Ссылка
Для того, чтобы выводился свой документ, добавленный в расширении, достаточно доработать всего функцию ПолучитьСписокПодчиненныхДокументов общего модуля ДокументыУНФ.
Пример:
&Вместо("ПолучитьСписокПодчиненныхДокументов")
Функция Дор_ПолучитьСписокПодчиненныхДокументов(ДокументОснование)
Запрос = Новый Запрос;
ТекстЗапроса = "";
//+++доработка+++
Если ДокументОснование = Неопределено Тогда
Возврат Новый ТаблицаЗначений;
КонецЕсли;
//---доработка---
Для Каждого ЭлементСостава Из Метаданные.КритерииОтбора.СтруктураПодчиненности.Состав Цикл
Если НЕ ЭлементСостава.Тип.СодержитТип(ТипЗнч(ДокументОснование)) Тогда
Продолжить;
КонецЕсли;
ПутьКДанным = ЭлементСостава.ПолноеИмя();
СтруктураПутьКДанным = РазобратьПутьКОбъектуМетаданных(ПутьКДанным);
Если НЕ ПравоДоступа("Чтение", СтруктураПутьКДанным.Метаданные) Тогда
Продолжить;
КонецЕсли;
ИмяОбъекта = СтруктураПутьКДанным.ТипОбъекта + "." + СтруктураПутьКДанным.ВидОбъекта;
ТекущаяСтрокаГДЕ = "ГДЕ Объект" + СтруктураПутьКДанным.ВидОбъекта + "." + СтруктураПутьКДанным.ИмяРеквизита
+ " = &ЗначениеКритерияОтбора";
ИмяРеквизита = Лев(СтруктураПутьКДанным.ИмяРеквизита, СтрНайти(СтруктураПутьКДанным.ИмяРеквизита, ".") - 1);
ТекстЗапроса = ТекстЗапроса + ?(ТекстЗапроса = "", "ВЫБРАТЬ РАЗРЕШЕННЫЕ", "ОБЪЕДИНИТЬ
|ВЫБРАТЬ") + "
|Объект" + СтруктураПутьКДанным.ВидОбъекта +".Ссылка ИЗ " + ИмяОбъекта + "." + СтруктураПутьКДанным.ИмяТаблЧасти + " КАК Объект" + СтруктураПутьКДанным.ВидОбъекта + "
|" + СтрЗаменить(ТекущаяСтрокаГДЕ, "..", ".") + "
|";
КонецЦикла;
Если ТекстЗапроса<>"" Тогда
//+++доработка, добавляем Заявку на доставку+++
Если ТипЗнч(ДокументОснование) = Тип("ДокументСсылка.ЗаказПокупателя") Тогда
ТекстЗапроса = ТекстЗапроса + "
|ОБЪЕДИНИТЬ
|ВЫБРАТЬ
|ЗаявкаНаДоставку.Ссылка ИЗ Документ.ЗаявкаНаДоставку КАК ЗаявкаНаДоставку
|ГДЕ ЗаявкаНаДоставку.Заказ = &ЗначениеКритерияОтбора";
КонецЕсли;
//---доработка---
Запрос.Текст = ТекстЗапроса;
Запрос.УстановитьПараметр("ЗначениеКритерияОтбора", ДокументОснование);
Возврат Запрос.Выполнить().Выгрузить();
Иначе
Возврат Новый ТаблицаЗначений;
КонецЕсли;
КонецФункции Показать1. Добавляем форму СвязанныеДокументы
2. Переопределяем в ней функцию ОбъектыПоКритериюОтбора:
&НаСервере
&Вместо("ОбъектыПоКритериюОтбора")
Функция Доработка_ОбъектыПоКритериюОтбора(ЗначениеКритерияОтбора)
ШаблонЗапроса = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
| ПсевдонимТаблицы.Ссылка КАК Ссылка
|ИЗ
| ИмяТаблицы КАК ПсевдонимТаблицы
|ГДЕ
| ПсевдонимТаблицы.ИмяРеквизита = &ЗначениеКритерияОтбора";
ШаблонЗапросаОбъединения = "ВЫБРАТЬ
| ПсевдонимТаблицы.Ссылка КАК Ссылка
|ИЗ
| ИмяТаблицы КАК ПсевдонимТаблицы
|ГДЕ
| ПсевдонимТаблицы.ИмяРеквизита = &ЗначениеКритерияОтбора";
ЧастиЗапроса = Новый Массив;
ТекстЧастиЗапроса = "";
Для Каждого ЭлементСостава Из Метаданные.КритерииОтбора.СвязанныеДокументы.Состав Цикл
Если НЕ ЭлементСостава.Тип.СодержитТип(ТипЗнч(ЗначениеКритерияОтбора)) Тогда
Продолжить;
КонецЕсли;
ПутьКДанным = ЭлементСостава.ПолноеИмя();
Если СтрНайти(ПутьКДанным, "ТабличнаяЧасть") Тогда
ОбъектМетаданных = ЭлементСостава.Родитель().Родитель();
Иначе
ОбъектМетаданных = ЭлементСостава.Родитель();
КонецЕсли;
Если НЕ ПравоДоступа("Чтение", ОбъектМетаданных) Тогда
Продолжить;
КонецЕсли;
Точка = СтрНайти(ПутьКДанным, ".", НаправлениеПоиска.СКонца);
ИмяРеквизита = Сред(ПутьКДанным, Точка + 1);
ИмяТаблицы = ЭлементСостава.Родитель().ПолноеИмя();
ИмяТаблицы = СтрЗаменить(ИмяТаблицы, "ТабличнаяЧасть.", "");
Точка = СтрНайти(ИмяТаблицы, ".", НаправлениеПоиска.СКонца);
ПсевдонимТаблицы = "Таблица_" + Сред(ИмяТаблицы, Точка + 1);
ТекстЧастиЗапроса = ?(ТекстЧастиЗапроса = "", ШаблонЗапроса, ШаблонЗапросаОбъединения);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяТаблицы", ИмяТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ПсевдонимТаблицы", ПсевдонимТаблицы);
ТекстЧастиЗапроса = СтрЗаменить(ТекстЧастиЗапроса, "ИмяРеквизита", ИмяРеквизита);
ЧастиЗапроса.Добавить(ТекстЧастиЗапроса);
КонецЦикла;
Если ЧастиЗапроса.Количество() > 0 Тогда
Запрос = Новый Запрос;
Разделитель = Символы.ПС + "ОБЪЕДИНИТЬ" + Символы.ПС;
Запрос.Текст = СтрСоединить(ЧастиЗапроса, Разделитель);
//+++доработка, добавляем добавленный реквизит "Задание на перевозку" из табличной части Товары документа Приобретения товаров и услуг+++
Если ТипЗнч(ЗначениеКритерияОтбора) = Тип("ДокументСсылка.ПриобретениеТоваровУслуг") Тогда
Запрос.Текст = Запрос.Текст + "
|ОБЪЕДИНИТЬ
|ВЫБРАТЬ
|ПриобретениеТоваровУслугТовары.ЗаданиеНаПеревозку ИЗ Документ.ПриобретениеТоваровУслуг.Товары КАК ПриобретениеТоваровУслугТовары
|ГДЕ ПриобретениеТоваровУслугТовары.Ссылка = &ЗначениеКритерияОтбора";
КонецЕсли;
//---доработка, добавляем добавленный реквизит "Задание на перевозку" из табличной части Товары документа Приобретения товаров и услуг---
Запрос.УстановитьПараметр("ЗначениеКритерияОтбора", ЗначениеКритерияОтбора);
Возврат Запрос.Выполнить().Выгрузить();
Иначе
Возврат Новый ТаблицаЗначений;
КонецЕсли;
КонецФункции Показать
&НаСервере
&Вместо("ОбъектыПоКритериюОтбора")
Функция ИТЛ_ОбъектыПоКритериюОтбора(ЗначениеКритерияОтбора)
Результат = ПродолжитьВызов(ЗначениеКритерияОтбора);
МассивСсылок = Результат.ВыгрузитьКолонку("Ссылка");
Результат.Колонки.Добавить("Ссылка1");
Результат.ЗагрузитьКолонку(МассивСсылок, "Ссылка1");
Результат.Колонки.Удалить(Результат.Колонки.Найти("Ссылка"));
Результат.Колонки.Ссылка1.Имя = "Ссылка";
Если ТипЗнч(ЗначениеКритерияОтбора) = Тип("ДокументСсылка.ЭтапПроизводства2_2") Тогда
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ИТЛ_КомплектовочнаяВедомость.Ссылка КАК Ссылка
|ИЗ
| Документ.ИТЛ_КомплектовочнаяВедомость КАК ИТЛ_КомплектовочнаяВедомость
|ГДЕ
| ИТЛ_КомплектовочнаяВедомость.Распоряжение = &ЗначениеКритерияОтбора";
Запрос.УстановитьПараметр("ЗначениеКритерияОтбора", ЗначениеКритерияОтбора);
Если Результат = Неопределено Тогда
Результат = Новый ТаблицаЗначений;
Результат.Колонки.Добавить("Ссылка");
КонецЕсли;
ТЗ = Запрос.Выполнить().Выгрузить();
Для Каждого Строка ИЗ ТЗ Цикл
Если Результат.Найти(Строка.Ссылка, "Ссылка") = Неопределено Тогда
Результат.Добавить().Ссылка = Строка.Ссылка;
КонецЕсли;
КонецЦикла;
КонецЕсли;
Возврат Результат;
Показать&ИзменениеИКонтроль("ИндексТиповСвязанныхОбъектов")
Функция ИТЛ_ИндексТиповСвязанныхОбъектов()
Индекс = Новый Соответствие;
МетаданныеСвязанныхОбъектов = Метаданные.КритерииОтбора.СвязанныеДокументы;
ТипыСвязанныхОбъектов = МетаданныеСвязанныхОбъектов.Тип.Типы();
ТипПараметраКоманды = Метаданные.ОбщиеКоманды.СвязанныеДокументы.ТипПараметраКоманды;
Для Каждого ТипСвязанногоОбъекта Из ТипыСвязанныхОбъектов Цикл
Если Не ТипПараметраКоманды.СодержитТип(ТипСвязанногоОбъекта) Тогда
Индекс.Вставить(ТипСвязанногоОбъекта, Истина);
КонецЕсли;
КонецЦикла;
#Вставка
Индекс.Вставить(Тип("ДокументСсылка.ИТЛ_КомплектовочнаяВедомость"), Истина);
Индекс.Вставить(Тип("ДокументСсылка.ИТЛ_ЗаявкаНаЗакупку"), Истина);
Индекс.Вставить(Тип("ДокументСсылка.АП_ПротоколЦены"), Истина);
#КонецВставки
Возврат Индекс;
КонецФункции Показать
Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.
№ 1653703
Создание 02.05.22 18:00
Обновление 28.04.23 16:11
Просмотры 51996
Загрузки 0
Рейтинг
124
Комментарии 90
Код открыт Да
Рубрики Адаптация типовых решений
Кому Разработчик
Тип файла Нет файла
Платформа 1С:Предприятие 8
Конфигурация 1С:ERP Управление предприятием 2
Операционная система Не имеет значения
Страна Россия
Отрасль Не имеет значения
Налоги Не имеет значения
Вид учета Не имеет значения
Доступ к файлу Бесплатно (free)