Счет с QR-кодом (внешняя печатная форма)

30.07.15

Учетные задачи - Печатные формы

Для удобства работы с терминалами  банка при оплате счета сделана форма счета с QR-кодом (внешняя печатная форма).

Скачать файлы

Наименование Файл Версия Размер
счет на оплату
.epf 13,54Kb
72
.epf 13,54Kb 72 Скачать

Возникла необходимость осуществления оплат через терминалы Сбербанка. Для этого, собственно, и делал печатную форму.

Работа проверена на УТ 10 и БП.2.0

QR-код счет на оплату

См. также

SALE! 25%

Infostart PrintWizard

Пакетная печать Печатные формы Инструментарий разработчика Платформа 1С v8.3 Запросы 1С:Зарплата и кадры бюджетного учреждения 1С:Конвертация данных 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Платные (руб)

Инструмент, позволяющий абсолютно по-новому взглянуть на процесс разработки печатных форм. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и "прозрачность" разработки, а также навести порядок в многообразии корпоративных печатных форм.

18000 15300 руб.

06.10.2023    7344    22    6    

39

Универсальная печать по шаблонам Word (Печать договоров из 1С БП 3, УНФ 1.6, ЗУП 3, УТ 11, КА 2, ERP 2, ДО 3)

Печатные формы Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 1С:ERP Управление предприятием 2 Платные (руб)

Научите вашу 1C печатать из 1С в файл Word (Например: трудовые договоры, договоры с контрагентами, спецификации, дополнительные соглашения, приказы, коммерческие предложения, акты, накладные, карточки партнера или любого справочника и многие другие). Универсальная печать предназначена для формирования печатных форм на основе шаблонов в формате Word из любой конфигурации 1С. С помощью данного инструмента можно самостоятельно заполнить шаблон реквизитами справочника или документа 1С и сформировать печатные формы на основании ссылки на любой объект.

5400 руб.

08.10.2019    42728    144    88    

134

SALE! 25%

УТ 11, КА 2, ERP 2: Настраиваемые под каждую организацию печать и подпись ответственных лиц в печатных формах (ТОРГ-12, Счёт-фактура, УПД, УКД, Заказ клиента, Акт сверки, М-15 и др.)

Печатные формы Взаиморасчеты Оптовая торговля Производство готовой продукции (работ, услуг) Акт сверки Оперативный учет Управляемые формы 1С:Управление торговлей 11 Россия Бухгалтерский учет Управленческий учет Платные (руб)

Задайте для каждой организации свою печать и для каждого физического лица свою подпись. Выберите в документе печатную форму "... с печатью и подписью" - и автоматически сформируется табличный документ с печатью и подписями той организации и ответственных лиц, которые указаны в документе.

12000 9000 руб.

13.03.2018    56485    179    76    

112

Печатные формы КС-2 и КС-3 в "1С:Бухгалтерия 3.0"

Печатные формы Производство готовой продукции (работ, услуг) Платформа 1С v8.3 Бухгалтерский учет Оперативный учет 1С:Бухгалтерия 3.0 Строительство Россия Бухгалтерский учет Платные (руб)

Откройте для себя заполнение КС-2 и КС-3 в "1С:Бухгалтерия 3.0". Вы получаете удобство, скорость и систему, чтобы заполнить, распечатать и сохранить формы КС-2 и КС-3 из документов "Оказание производственных услуг" или "Реализация товаров услуг". Вы можете заполнить дополнительную информацию о материалах из документов "Требование-накладная" и указать сведения, которые не предусмотрены типовой конфигурацией "1С:Бухгалтерия 3.0". Так же доступно множество настроек для формирования КС-2 и КС-3.

3240 руб.

13.02.2019    88039    388    44    

371

Печать актов МХ-1, МХ-3 в 1С:Бухгалтерия 3.0

Печатные формы Логистика, склад и ТМЦ Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)

Обработки для "1С:Бухгалтерия 3.0", которые формируют акты МХ-1 и МХ-3 для документов "ПоступлениеТоваровУслуг", "Реализация товаров услуг", "Возврат товаров поставщику", "Передача материалов в эксплуатацию" соответственно. Так же можно сформировать акты с факсимиле, которая загружена в 1С:Бухгалтерия 3.0.

2520 руб.

18.02.2019    61118    170    14    

139

Путевые листы (расширение)

Печатные формы Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Транспорт, автопарки, такси Бухгалтерский учет Платные (руб)

Учет путевых листов выполнен в виде расширения. Предназначен для учета путевых листов в конфигурации Бухгалтерия предприятия 3.0. и Комплексная автоматизация 2. Печатная форма: Типовая межотраслевая форма № 3. Утверждена постановлением Госкомстата России от 28.11.97 № 78. Типовая межотраслевая форма № 4-П от 18.09.2008 г. N 152 с учетом изменений указанных в Приказе Министерства транспорта Российской Федерации №368 от 11 сентября 2020 г. №368, Типовая межотраслевая форма № ЭСМ-7, и др. ЭСМ-2, 4-С, 3 спец., 6 спец., ПЛ для Автомобильного крана. .

2000 руб.

14.10.2019    36587    225    216    

139
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. TrinitronOTV 14 31.07.15 05:56 Сейчас в теме
Для самого штрих-кода какие-то внешние компоненты используются или реализовывали средствами 1С?
MherArsh; +1 Ответить
3. mentozavr 68 31.07.15 16:29 Сейчас в теме
(1) TrinitronOTV, все 1с. Силами модуля УпрвлениеПечатью
2. mentozavr 68 31.07.15 16:28 Сейчас в теме
все средствами 1с там есть модули
4. 1v7 235 31.07.15 16:33 Сейчас в теме
Интересная идея. Плюсую.В пользовательском режиме тоже можно текст в QR перевести? Или только в конфигураторе?
6. mentozavr 68 12.08.15 16:35 Сейчас в теме
(4) 1v7, помоему без проблем
(5) simuljakr, прикрепил файл. будут вопросы готов ответить
Прикрепленные файлы:
Стандарт ДШК.pdf
5. simuljakr 203 11.08.15 13:48 Сейчас в теме
А какая информация шифруется в QR-код ?
9. mentozavr 68 22.02.18 22:20 Сейчас в теме
(5)вся необходимая для сбербанка
7. suncho25343 21.02.18 08:33 Сейчас в теме
При считывании кода приложением от Сбера, назначение платежа не формируется, как исправить?
8. mentozavr 68 22.02.18 22:19 Сейчас в теме
(7) Надо смотреть отладчиком. скорее всего какие-то поля не заполняются. В какой конфигурации пробуете. на БП 2.0. работает...планирую переписать ее для УТ и 11-ые версии.
10. suncho25343 23.02.18 11:54 Сейчас в теме
(8) У меня стандартная БП 2.0 редакция 8.2 Не заполняет именно при сканировании из приложения сер онлайн...
11. mentozavr 68 23.02.18 23:07 Сейчас в теме
а когда считываете банкоматом как? ....но таких вопросов мне не задавали...т.к. у моих считывает вроде норм...арендаторы (кот. счета выдают молчат...а что-нибудь в это поле заполняет?
12. suncho25343 24.02.18 13:27 Сейчас в теме
(11) В поле ничего не заполняет, еще в поле услуга вписывает название организации . Напишите в личку, сколько будет стоить исправить?
Прикрепленные файлы:
13. mentozavr 68 25.02.18 22:53 Сейчас в теме
Попробуйте мою. мои с этим работают.
Прикрепленные файлы:
Счет на оплату с кодом для Сбербанка.epf
snami_ru; +1 Ответить
14. suncho25343 25.02.18 23:05 Сейчас в теме
Так же все... В терминалах не проверял, только сбер онлайн.
15. smax 22.05.18 11:13 Сейчас в теме
Андрей Вадимович, добрый день!
Скачал обработку, проверяю её на УТ10, как у Вас написано в описании. Даёт ошибку. Проверяю причину, в модуле УправлениеПечатью нету вообще процедур для QR кода, которые Вы используете в обработке.

QRСтрока = УправлениеПечатью.ФорматнаяСтрокаУФЭБС(РеквизитыПлатежа)

или

ДанныеQRКода = УправлениеПечатью.ДанныеQRКода(QRСтрока, 1, 120);

В последних релизах УТ10 она вообще работоспособна?
16. mentozavr 68 22.05.18 21:50 Сейчас в теме
(15)Добрый вечер. Если конфу менять не боитесь то в УТ 10 в модуль УправлениеПечатью надо эту процедуру добавить...до недавних релизов данная процедура там была..я ее из ут 10 в БП20 и забирал.



// Печать QR кода

// Возвращает двоичные данные для формирования QR кода
//
// Параметры:
//  QRСтрока         - Строка - данные, которые необходимо разместить в QR-коде.
//
//  УровеньКоррекции - Число - уровень погрешности изображения при котором данный QR-код все еще возможно 100% распознать.
//                     Параметр должен иметь тип целого и принимать одно из 4 допустимых значений:
//                     0(7% погрешности), 1(15% погрешности), 2(25% погрешности), 3(35% погрешности).
//
//  Размер           - Число - определяет длину стороны выходного изображения в пикселях.
//                     Если минимально возможный размер изображения больше этого параметра – код сформирован не будет.
//
//  ТекстОшибки      - Строка - в этот параметр помещается описание возникшей ошибки (если возникла).
//
// Возвращаемое значение:
//  Двоичные данные  - буфер, содержащий байты PNG-изображения QR-кода.
// 
// Пример:
//  
//  //Выводим на печать QR-код, содержащий в себе информацию зашифрованную по УФЭБС
//
//  QRСтрока = УправлениеПечатью.ФорматнаяСтрокаУФЭБС(РеквизитыПлатежа);
//  ТекстОшибки = "";
//  ДанныеQRКода = УправлениеПечатью.ДанныеQRКода(QRСтрока, 0, 190, ТекстОшибки);
//  Если Не ПустаяСтрока(ТекстОшибки)
//      ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстОшибки);
//  КонецЕсли;
//
//  КартинкаQRКода = Новый Картинка(ДанныеQRКода);
//  ОбластьМакета.Рисунки.QRКод.Картинка = КартинкаQRКода;
//
Функция ДанныеQRКода(QRСтрока, УровеньКоррекции, Размер) Экспорт
	
	Отказ = Ложь;
	
	ГенераторQRКода = КомпонентаФормированияQRКода(Отказ);
	Если Отказ Тогда
		Возврат Неопределено;
	КонецЕсли;
	
	Попытка
		ДвоичныеДанныеКартинки = ГенераторQRКода.GenerateQRCode(QRСтрока, УровеньКоррекции, Размер);
	Исключение
		ЗаписьЖурналаРегистрации("Формирование QR-кода",УровеньЖурналаРегистрации.Ошибка,,,
								  ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
	КонецПопытки;
	
	Возврат ДвоичныеДанныеКартинки;
	
КонецФункции

// Формирует форматную строку согласно "Унифицированному формату электронных банковских сообщений" для ее отображения в виде QR-кода
// Параметры:
// ДанныеДокумента  - Структура - содержит значения полей документа
//					- Данные документа будут закодированы согласно стандарту 
//						"СТАНДАРТЫ ФИНАНСОВЫХ ОПЕРАЦИЙ Символы двумерного штрихового кода для осуществления платежей физических лиц"
//					- ДанныеДокумента должны содержать информацию в полях, описанных ниже.
//
//					- Обязательные поля структуры
//		* ТекстПолучателя             - Наименование получателя платежа         - Макс. 160 символов;
//		* НомерСчетаПолучателя        - Номер счета получателя платежа          - Макс. 20 символов;
//		* НаименованиеБанкаПолучателя - Наименование банка получателя платежа   - Макс. 45 символов;
//		* БИКБанкаПолучателя          - БИК                                     - Макс. 9 символов;
//		* СчетБанкаПолучателя         - Номер кор./сч. банка получателя платежа - Макс. 20 символов;
//					- Дополнительные поля структуры
//		* СуммаЧислом         - Сумма платежа, в рублях                 - Макс. 16 символов 
//		* НазначениеПлатежа   - Наименование платежа (назначение)       - Макс. 210 символов;
//		* ИННПолучателя       - ИНН получателя платежа                  - Макс. 12 символов;
//		* ИННПлательщика      - ИНН плательщика                         - Макс. 12 символов;
//		* СтатусСоставителя   - Статус составителя платежного документа - Макс. 2 символа;
//		* КПППолучателя       - КПП получателя платежа                  - Макс. 9 символов
//		* КодБК               - КБК                                     - Макс. 20 символов;
//		* КодОКАТО            - Код ОКАТО                               - Макс. 11 символов;
//		* ПоказательОснования - Основание налогового платежа            - Макс. 2 символа;
//		* ПоказательПериода   - Налоговый период                        - Макс. 10 символов;
//		* ПоказательНомера    - Номер документа                         - Макс. 15 символов;
//		* ПоказательДаты      - Дата документа                          - Макс. 10 символ
//		* ПоказательТипа      - Тип платежа                             - Макс. 2 символа
//					- Прочие дополнительные  поля
//		* ФамилияПлательщика               - Фамилия плательщика
//		* ИмяПлательщика                   - Имя плательщика
//		* ОтчествоПлательщика              - Отчество плательщика
//		* АдресПлательщика                 - Адрес плательщика
//		* ЛицевойСчетБюджетногоПолучателя  - Лицевой счет бюджетного получателя
//		* ИндексПлатежногоДокумента        - Индекс платежного документа
//		* СНИЛС                            - № лицевого счета в системе персонифицированного учета в ПФР - СНИЛС
//		* НомерДоговора                    - Номер договора
//		* НомерЛицевогоСчетаПлательщика    - Номер лицевого счета плательщика в организации (в системе учета ПУ)
//		* НомерКвартиры                    - Номер квартиры
//		* НомерТелефона                    - Номер телефона
//		* ВидПлательщика                   - Вид ДУЛ плательщика
//		* НомерПлательщик                  - Номер ДУЛ плательщика
//		* ФИОРебенка                       - Ф.И.О. ребенка/учащегося
//		* ДатаРождения                     - Дата рождения
//		* СрокПлатежа                      - Срок платежа/дата выставления счета
//		* ПериодОплаты                     - Период оплаты
//		* ВидПлатежа                       - Вид платежа
//		* КодУслуги                        - Код услуги/название прибора учета
//		* НомерПрибораУчета                - Номер прибора учета
//		* ПоказаниеПрибораУчета            - Показание прибора учета
//		* НомерИзвещения                   - Номер извещения, начисления, счета
//		* ДатаИзвещения                    - Дата извещения/начисления/счета/постановления (для ГИБДД)
//		* НомерУчреждения                  - Номер учреждения (образовательного, медицинского)
//		* НомерГруппы                      - Номер группы детсада/класса школы
//		* ФИОПреподавателя                 - ФИО преподавателя, специалиста, оказывающего услугу
//		* СуммаСтраховки                   - Сумма страховки/дополнительной услуги/Сумма пени (в копейках)
//		* НомерПостановления               - Номер постановления (для ГИБДД)
//		* НомерИсполнительногоПроизводства - Номер исполнительного производства
//		* КодВидаПлатежа                   - Код вида платежа (например, для платежей в адрес Росреестра)
//		* ИдентификаторНачисления          - Уникальный идентификатор начисления
//		* ТехническийКод                   - Технический код, рекомендуемый для заполнения поставщиком услуг.
//                                           Может использоваться принимающей организацией для вызова соответствующей обрабатывающей ИТ-системы. 
//                                           Перечень значений кода представлен ниже.
//
//	Код назначения			Наименование назначения платежа
//		платежа	
//	
//			01				Мобильная связь, стационарный телефон
//			02				Коммунальные услуги, ЖКХ
//			03				ГИБДД, налоги, пошлины, бюджетные платежи
//			04				Охранные услуги
//			05				Услуги, оказываемые УФМС
//			06				ПФР
//			07				Погашение кредитов
//			08				Образовательные учреждения
//			09				Интернет и ТВ
//			10				Электронные деньги
//			11				Отдых и путешествия
//			12				Инвестиции и страхование
//			13				Спорт и здоровье
//			14				Благотворительные и общественные организации
//			15				Прочие услуги
//
// Возвращаемое значение:
//   Строка - строка данных в формате УФЭБС
//
Функция ФорматнаяСтрокаУФЭБС(ДанныеДокумента) Экспорт
	
	ТекстОшибки = "";
	СтрокаОбязательныхРеквизитов = СтрокаОбязательныхРеквизитов(ДанныеДокумента, ТекстОшибки);
	
	Если ПустаяСтрока(СтрокаОбязательныхРеквизитов) Тогда
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстОшибки, , , ,);
		Возврат "";
	КонецЕсли;
	
	СтруктураПредставленийИРеквизитов = СтруктураПредставленийИРеквизитов();
	СтрокаДополнительныхРеквизитов = "";
	ДополнительныеРеквизиты = Новый Структура;
	ДобавитьДополнительныеРеквизиты(ДополнительныеРеквизиты);
	
	Для Каждого Элемент Из ДополнительныеРеквизиты Цикл
		
		Если Не ДанныеДокумента.Свойство(Элемент.Ключ) Тогда
			ДанныеДокумента.Вставить(Элемент.Ключ, "");
			Продолжить;
		КонецЕсли;
		
		Если ЗначениеЗаполнено(ДанныеДокумента[Элемент.Ключ]) Тогда
			Если Элемент.Ключ = "СуммаЧислом" Тогда
				ЗначениеСтрокой = Формат(ДанныеДокумента.СуммаЧислом * 100, "ЧГ=");
			Иначе
				ЗначениеСтрокой = СтрЗаменить(СокрЛП(Строка(ДанныеДокумента[Элемент.Ключ])), "|", "");
			КонецЕсли;
			СтрокаДополнительныхРеквизитов = СтрокаДополнительныхРеквизитов + СтруктураПредставленийИРеквизитов[Элемент.Ключ]
			                                 + "=" + ЗначениеСтрокой + "|";
		КонецЕсли;
	КонецЦикла;
	
	Если Не ПустаяСтрока(СтрокаДополнительныхРеквизитов) Тогда
		ДлинаСтроки = СтрДлина(СтрокаДополнительныхРеквизитов);
		СтрокаДополнительныхРеквизитов = Сред(СтрокаДополнительныхРеквизитов, 1, ДлинаСтроки - 1);
	КонецЕсли;

	ПрочиеДополнительныеРеквизиты = Новый Структура;
	ДобавитьПрочиеДополнительныеРеквизиты(ПрочиеДополнительныеРеквизиты);
	СтрокаПрочихДополнительныхРеквизитов = "";
	
	Для Каждого Элемент Из ПрочиеДополнительныеРеквизиты Цикл
		
		Если Не ДанныеДокумента.Свойство(Элемент.Ключ) Тогда
			ДанныеДокумента.Вставить(Элемент.Ключ, "");
			Продолжить;
		КонецЕсли;
		
		Если ЗначениеЗаполнено(ДанныеДокумента[Элемент.Ключ]) Тогда
			ЗначениеСтрокой = СтрЗаменить(СокрЛП(Строка(ДанныеДокумента[Элемент.Ключ])), "|", "");
			СтрокаПрочихДополнительныхРеквизитов = СтрокаПрочихДополнительныхРеквизитов
			                                       + СтруктураПредставленийИРеквизитов[Элемент.Ключ] + "=" + ЗначениеСтрокой
			                                       + "|";
		КонецЕсли;
	КонецЦикла;
	
	Если Не ПустаяСтрока(СтрокаПрочихДополнительныхРеквизитов) Тогда
		ДлинаСтроки = СтрДлина(СтрокаПрочихДополнительныхРеквизитов);
		СтрокаПрочихДополнительныхРеквизитов = Сред(СтрокаПрочихДополнительныхРеквизитов, 1, ДлинаСтроки - 1);
	КонецЕсли;
	
	ИтоговаяСтрока =  СтрокаОбязательныхРеквизитов
	                 + ?(ПустаяСтрока(СтрокаДополнительныхРеквизитов), "", "|" + СтрокаДополнительныхРеквизитов)
	                 + ?(ПустаяСтрока(СтрокаПрочихДополнительныхРеквизитов), "", "|" + СтрокаПрочихДополнительныхРеквизитов);
	
	Возврат ИтоговаяСтрока;
	
КонецФункции

Функция СтрокаОбязательныхРеквизитов(ДанныеДокумента, ТекстСообщения)
	
	ОбязательныеРеквизиты = Новый Структура();
	СтруктураПредставленийИРеквизитов = СтруктураПредставленийИРеквизитов();
	ДобавитьОбязательныеРеквизиты(ОбязательныеРеквизиты);
	
	Если Не ЗначениеЗаполнено(ДанныеДокумента.СчетБанкаПолучателя) Тогда
		ДанныеДокумента.СчетБанкаПолучателя = "0";
	КонецЕсли;
	
	СлужебныеДанные = "ST00012";
	ОбязательныеДанные = "";
	
	Для Каждого Элемент Из ОбязательныеРеквизиты Цикл
		Если Не ЗначениеЗаполнено(ДанныеДокумента[Элемент.Ключ]) Тогда
			ТекстСообщения = Нстр("ru = 'Не заполнен обязательный реквизит: %1'");
			ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(ТекстСообщения, Элемент.Ключ);
			Возврат "";
		КонецЕсли;
		
		ЗначениеСтрокой = СтрЗаменить(СокрЛП(Строка(ДанныеДокумента[Элемент.Ключ])), "|", "");
		
		ОбязательныеДанные = ОбязательныеДанные + "|" + СтруктураПредставленийИРеквизитов[Элемент.Ключ] + "="
		                     + ЗначениеСтрокой;
		
	КонецЦикла;
	
	Если СтрДлина(ОбязательныеДанные) > 300 Тогда
		Шаблон = НСтр("ru = 'Невозможно создать QR-код для документа %1
		                    |Строка обязательных реквизитов должна быть меньше 300 символов:
		                    |""%2""'");
		ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(Шаблон,
		                                                                         ДанныеДокумента.Ссылка,
		                                                                         ОбязательныеДанные);
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстСообщения);
		Возврат "";
	КонецЕсли;
	
	Возврат СлужебныеДанные + ОбязательныеДанные;
	
КонецФункции

Функция СтруктураПредставленийИРеквизитов()
	
	СтруктураВозврата = Новый Структура();
	
	СтруктураВозврата.Вставить("ТекстПолучателя",             "Name");
	СтруктураВозврата.Вставить("НомерСчетаПолучателя",        "PersonalAcc");
	СтруктураВозврата.Вставить("НаименованиеБанкаПолучателя", "BankName");
	СтруктураВозврата.Вставить("БИКБанкаПолучателя",          "BIC");
	СтруктураВозврата.Вставить("СчетБанкаПолучателя",         "CorrespAcc");
	
	СтруктураВозврата.Вставить("СуммаЧислом",         "Sum");
	СтруктураВозврата.Вставить("НазначениеПлатежа",   "Purpose");
	СтруктураВозврата.Вставить("ИННПолучателя",       "PayeeINN");
	СтруктураВозврата.Вставить("ИННПлательщика",      "PayerINN");
	СтруктураВозврата.Вставить("СтатусСоставителя",   "DrawerStatus");
	СтруктураВозврата.Вставить("КПППолучателя",       "KPP");
	СтруктураВозврата.Вставить("КодБК",               "CBC");
	СтруктураВозврата.Вставить("КодОКАТО",            "OKATO");
	СтруктураВозврата.Вставить("ПоказательОснования", "PaytReason");
	СтруктураВозврата.Вставить("ПоказательПериода",   "ТaxPeriod");
	СтруктураВозврата.Вставить("ПоказательНомера",    "DocNo");
	СтруктураВозврата.Вставить("ПоказательДаты",      "DocDate");
	СтруктураВозврата.Вставить("ПоказательТипа",      "TaxPaytKind");
	
	СтруктураВозврата.Вставить("ФамилияПлательщика",               "lastName");
	СтруктураВозврата.Вставить("ИмяПлательщика",                   "firstName");
	СтруктураВозврата.Вставить("ОтчествоПлательщика",              "middleName");
	СтруктураВозврата.Вставить("АдресПлательщика",                 "payerAddress");
	СтруктураВозврата.Вставить("ЛицевойСчетБюджетногоПолучателя",  "personalAccount");
	СтруктураВозврата.Вставить("ИндексПлатежногоДокумента",        "docIdx");
	СтруктураВозврата.Вставить("СНИЛС",                            "pensAcc");
	СтруктураВозврата.Вставить("НомерДоговора",                    "contract");
	СтруктураВозврата.Вставить("НомерЛицевогоСчетаПлательщика",    "persAcc");
	СтруктураВозврата.Вставить("НомерКвартиры",                    "flat");
	СтруктураВозврата.Вставить("НомерТелефона",                    "phone");
	СтруктураВозврата.Вставить("ВидПлательщика",                   "payerIdType");
	СтруктураВозврата.Вставить("НомерПлательщика",                 "payerIdNum");
	СтруктураВозврата.Вставить("ФИОРебенка",                       "childFio");
	СтруктураВозврата.Вставить("ДатаРождения",                     "birthDate");
	СтруктураВозврата.Вставить("СрокПлатежа",                      "paymTerm");
	СтруктураВозврата.Вставить("ПериодОплаты",                     "paymPeriod");
	СтруктураВозврата.Вставить("ВидПлатежа",                       "category");
	СтруктураВозврата.Вставить("КодУслуги",                        "serviceName");
	СтруктураВозврата.Вставить("НомерПрибораУчета",                "counterId");
	СтруктураВозврата.Вставить("ПоказаниеПрибораУчета",            "counterVal");
	СтруктураВозврата.Вставить("НомерИзвещения",                   "quittId");
	СтруктураВозврата.Вставить("ДатаИзвещения",                    "quittDate");
	СтруктураВозврата.Вставить("НомерУчреждения",                  "instNum");
	СтруктураВозврата.Вставить("НомерГруппы",                      "classNum");
	СтруктураВозврата.Вставить("ФИОПреподавателя",                 "specFio");
	СтруктураВозврата.Вставить("СуммаСтраховки",                   "addAmount");
	СтруктураВозврата.Вставить("НомерПостановления",               "ruleId");
	СтруктураВозврата.Вставить("НомерИсполнительногоПроизводства", "execId");
	СтруктураВозврата.Вставить("КодВидаПлатежа",                   "regType");
	СтруктураВозврата.Вставить("ИдентификаторНачисления",          "uin");
	СтруктураВозврата.Вставить("ТехническийКод",                   "TechCode");
	
	Возврат СтруктураВозврата;
	
КонецФункции

Функция КомпонентаФормированияQRКода(Отказ)
	
	СистемнаяИнформация = Новый СистемнаяИнформация;
	Платформа = СистемнаяИнформация.ТипПлатформы;
	
	ТекстОшибки = НСтр("ru = 'Не удалось подключить внешнюю компоненту для генерации QR-кода'");
	
	Попытка
		Если ПодключитьВнешнююКомпоненту("ОбщийМакет.КомпонентаПечатиQRКода", "QR") Тогда
			QRCodeGenerator = Новый("AddIn.QR.QRCodeExtension");
		Иначе
			ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстОшибки, , , , Отказ);
		КонецЕсли
	Исключение
		ПодробноеПредставлениеОшибки = ПодробноеПредставлениеОшибки(ОписаниеОшибки());
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстОшибки + Символы.ПС + ПодробноеПредставлениеОшибки, , , , Отказ);
	КонецПопытки;
	
	Возврат QRCodeGenerator;
	
КонецФункции

Процедура ДобавитьОбязательныеРеквизиты(СтруктураДанных)
	
	СтруктураДанных.Вставить("ТекстПолучателя");
	СтруктураДанных.Вставить("НомерСчетаПолучателя");
	СтруктураДанных.Вставить("НаименованиеБанкаПолучателя");
	СтруктураДанных.Вставить("БИКБанкаПолучателя");
	СтруктураДанных.Вставить("СчетБанкаПолучателя");
	
КонецПроцедуры

Процедура ДобавитьДополнительныеРеквизиты(СтруктураДанных)
	
	СтруктураДанных.Вставить("СуммаЧислом");
	СтруктураДанных.Вставить("НазначениеПлатежа");
	СтруктураДанных.Вставить("ИННПолучателя");
	СтруктураДанных.Вставить("ИННПлательщика");
	СтруктураДанных.Вставить("СтатусСоставителя");
	СтруктураДанных.Вставить("КПППолучателя");
	СтруктураДанных.Вставить("КодБК");
	СтруктураДанных.Вставить("КодОКАТО");
	СтруктураДанных.Вставить("ПоказательОснования");
	СтруктураДанных.Вставить("ПоказательПериода");
	СтруктураДанных.Вставить("ПоказательНомера");
	СтруктураДанных.Вставить("ПоказательДаты");
	СтруктураДанных.Вставить("ПоказательТипа");
	
КонецПроцедуры

Процедура ДобавитьПрочиеДополнительныеРеквизиты(СтруктураДанных)
	
	СтруктураДанных.Вставить("ФамилияПлательщика");
	СтруктураДанных.Вставить("ИмяПлательщика");
	СтруктураДанных.Вставить("ОтчествоПлательщика");
	СтруктураДанных.Вставить("АдресПлательщика");
	СтруктураДанных.Вставить("ЛицевойСчетБюджетногоПолучателя");
	СтруктураДанных.Вставить("ИндексПлатежногоДокумента");
	СтруктураДанных.Вставить("СНИЛС");
	СтруктураДанных.Вставить("НомерДоговора");
	СтруктураДанных.Вставить("НомерЛицевогоСчетаПлательщика");
	СтруктураДанных.Вставить("НомерКвартиры");
	СтруктураДанных.Вставить("НомерТелефона");
	СтруктураДанных.Вставить("ВидПлательщика");
	СтруктураДанных.Вставить("НомерПлательщика");
	СтруктураДанных.Вставить("ФИОРебенка");
	СтруктураДанных.Вставить("ДатаРождения");
	СтруктураДанных.Вставить("СрокПлатежа");
	СтруктураДанных.Вставить("ПериодОплаты");
	СтруктураДанных.Вставить("ВидПлатежа");
	СтруктураДанных.Вставить("КодУслуги");
	СтруктураДанных.Вставить("НомерПрибораУчета");
	СтруктураДанных.Вставить("ПоказаниеПрибораУчета");
	СтруктураДанных.Вставить("НомерИзвещения");
	СтруктураДанных.Вставить("ДатаИзвещения");
	СтруктураДанных.Вставить("НомерУчреждения");
	СтруктураДанных.Вставить("НомерГруппы");
	СтруктураДанных.Вставить("ФИОПреподавателя");
	СтруктураДанных.Вставить("СуммаСтраховки");
	СтруктураДанных.Вставить("НомерПостановления");
	СтруктураДанных.Вставить("НомерИсполнительногоПроизводства");
	СтруктураДанных.Вставить("КодВидаПлатежа");
	СтруктураДанных.Вставить("ИдентификаторНачисления");
	СтруктураДанных.Вставить("ТехническийКод");
	
КонецПроцедуры

////////////////////////////////////////////////////////////­////////////////////

Показать

При возможности поправлю ее и все эти функции вставлю в обработку.
17. Pavel_Vladivostok 58 20.07.18 05:56 Сейчас в теме
Протестировал возможность распознавания штрих-кода сформированного этой обработкой в разных мобильных приложениях и терминалах банков. Так вот терминалы сбербанка, как и мобильное приложение сбера, этот штрих-код не распознают. Но у сбера распознаются только те штрих-коды, в которых указаны получатели платежа заключившие договор со сбером. Таким образом, чтобы клиенты сбербанка могли оплачивать по штрих-коду в терминале или мобильном приложении ваши квитанции вашей организации необходимо обратиться в сбер и заключить с ними какой-то особый договор, тогда для ваших счетов будет работать заполнение по штрих-коду, в противном случае получатель платежа не распознается.
Еще у обработки есть отличие в кодировке, здесь используется UTF8 и это указано в штрихкоде в первой строке ST000012, коммунальщики печатают штрихкод в кодировке windows-1251 и указывают в коде: ST000011, возможно еще по этой причине не распознается штрих-код. В приложении альфа-банка, ШК из этой обработки тоже не распознается.
18. mentozavr 68 20.07.18 10:54 Сейчас в теме
(17) Да он писался как раз для сбера и под наши нужды. но у нас 2 организации дочерние тоже заключили договор со сбером о принятии оплаты, и счета с данным штрихкодом тоже работают. На сколько слышал в новых разработках 1с уже в банках задается кодировка и в обработку должны передаваться данные типа ST000011 - Сбер, ST000012 - Бин банк и т.д.. кодировка и всех банкоматов одинаковая и ПО банкоматов распознает ее сама.
21. snami_ru 208 30.09.20 10:55 Сейчас в теме
(18) А сбер берет комиссию за договор по приему платежей?
Если счет в другом банке.
22. mentozavr 68 30.09.20 11:23 Сейчас в теме
(21)Это надо с ними разговаривать..год назад насколько помню не брал.
19. Koneff 21.03.19 20:21 Сейчас в теме
Возможно ли использование на 1С 8.3 упрощенка?
20. mentozavr 68 22.03.19 08:34 Сейчас в теме
(19)Писался для 8.2 но в принципе под 8.3 переделать ее не проблема будет. главное чтобы модули были. Попробуйте скачайте (13) sm не спишут. Выше в коде указаны модули которые использует форма. Если БП 3.0 (не важно упрощенка или нет) то в ней эти функции есть)) будет время попробую написать ее для 8.3
snami_ru; +1 Ответить
23. Al-77 73 11.05.23 11:25 Сейчас в теме
Добрый день: знает кто как поменять ндс включен в стоимость?
24. mentozavr 68 12.05.23 11:46 Сейчас в теме
(23) Немного непонятен Ваш вопрос но в обработке
Строки 262-268 кода объекта отвечают за вывод НДС в зависимости от значения в шапке

Если СуммаНДС <> 0 Тогда
ОбластьДанных.Параметры.НДС = ?(Шапка.СуммаВключаетНДС, "В том числе НДС:", "Сумма НДС:");
ОбластьСуммы.Параметры.ВсегоНДС = ОбщегоНазначения.ФорматСумм(СуммаНДС);
Иначе
ОбластьДанных.Параметры.НДС = "Без налога (НДС)";
ОбластьСуммы.Параметры.ВсегоНДС = "-";
КонецЕсли;
Оставьте свое сообщение