Импорт справочников из Инфо-Предприятие 1.91 в БП2.0/ЗУП2.5 (из файлов *.db или *.xls/*.xlsx)

Публикация № 565473

Администрирование - Администрирование данных 1С - Обработка справочников

обработка импорт загрузка инфо-предприятие paradox excel

Обработка для импорта справочников Контрагенты, Номенклатура, ОсновныеСредства и ФизическиеЛица из DB-файлов Инфо-Предприятие 1.91 или из DB-файлов, сохранённых как файлы MS Excel (XLS/XLSX-файлы).

Проверялось на: Бухгалтерия Предприятия 2.0.65.3, Зарплата и Управление Персоналом 2.5.98.1.

В рамках проекта по переводу клиента с Инфо-Предприятие 1.91 на 1С:БП2.0+1С:ЗУП2.5 возникла задача по автоматическому переносу основных справочников. Готовое решение не нашёл, поэтому написал данную обработку.

Обработка умеет загружать справочники Контрагенты, Номенклатура, ОсновныеСредства и ФизическиеЛица как из DB-файлов Инфо-Предприятие (СУБД Paradox), так и из DB-файлов, сохранённых в формате MS Excel (XLS/XLSX-файлов).

Чтение DB-файлов работает на порядок быстрее, чем XLS/XLSX, но у меня оно отработало не на всех компьютерах, на которых пробовал запускать обработку. Не знаю точно, действительно ли это оказало влияние, но на тех компьютерах, на которых чтение DB-файлов отработало, был установлен BDE.

Теперь немного про код самой обработки.

Была написана пара универсальных функций для чтения данных: 1) из DB-файла (через ADO) и 2) из файла Excel. Обе функции в качестве параметра получают полное имя файла и возвращают таблицу значений, которая содержит все данные, прочитанные из этого DB-/XLS(X)-файла. Имена колонок возвращаемой таблицы значений совпадают с именами колонок DB-файла. В случае чтения из файла MS Excel, имена колонок берутся из первой строки таблицы.

Функция чтения из DB-файла в таблицу значений:

Функция ПолучитьТаблицуИзФайлаПарадокс(ИмяФайла)
	
	ТЗ = Новый ТаблицаЗначений;
	
	Файл = Новый Файл(ИмяФайла);
	
	СтрокаПодключения = "Driver={Microsoft Paradox Driver (*.db )};DefaultDir=" + Файл.Путь + ";CollatingSequence=ASCII";
	
	ПодключениеАДОДБ = Новый COMОбъект("ADODB.Connection");
	ПодключениеАДОДБ.Open(СтрокаПодключения);
	
	ТекстЗапроса = "SELECT * FROM " + Файл.ИмяБезРасширения;
	ВыборкаАДОДБ = ПодключениеАДОДБ.Execute(ТекстЗапроса);
	
	ВыборкаАДОДБ.MoveFirst();
	
	КолвоКолонок = ВыборкаАДОДБ.Fields.Count;
	
	Если КолвоКолонок = 0 Тогда
		ВызватьИсключение "Ошибка чтения файла " + ИмяФайла + ": таблица не содержит колонок!";
	КонецЕсли; 
	
	СоответствиеКолонок = Новый Соответствие; 
	Для НомКол = 0 По КолвоКолонок - 1 Цикл
		ИмяКолонки = ВыборкаАДОДБ.Fields(НомКол).Name;
		ТЗ.Колонки.Добавить(ИмяКолонки);
		СоответствиеКолонок.Вставить(НомКол, ИмяКолонки);
	КонецЦикла; 

	Пока НЕ ВыборкаАДОДБ.EOF Цикл
		НоваяСтрока = ТЗ.Добавить(); 
		Для НомКол = 0 По КолвоКолонок - 1 Цикл
			НоваяСтрока[СоответствиеКолонок.Получить(НомКол)] = ВыборкаАДОДБ.Fields(НомКол).Value;
		КонецЦикла;
		ВыборкаАДОДБ.MoveNext();
	КонецЦикла; 
	
	Возврат ТЗ; 
	
КонецФункции

Функция чтения из XLS/XLSX-файла в таблицу значений:

Функция ПолучитьТаблицуИзФайлаЕксель(ИмяФайла)
	
	ТЗ = Новый ТаблицаЗначений;
	
	Ексель = Новый COMОбъект("Excel.Application");
	КнигаЕксель = Ексель.Workbooks.Open(ИмяФайла, Ложь, Истина);
	ЛистЕксель = КнигаЕксель.Worksheets(1);
	
	// читаем первую строку с заголовками столбцов
	НомКол = 1;
	СоответствиеКолонок = Новый Соответствие; 
	Пока Истина Цикл
		ТекЗнач = СокрЛП(ЛистЕксель.Cells(1, НомКол).Value);
		Если ПустаяСтрока(ТекЗнач) Тогда
			Прервать;
		КонецЕсли;
		ТЗ.Колонки.Добавить(ТекЗнач);
		СоответствиеКолонок.Вставить(НомКол, ТекЗнач);
		НомКол = НомКол + 1; 
	КонецЦикла;
	
	КолвоКолонок = ТЗ.Колонки.Количество();
	
	Если КолвоКолонок = 0 Тогда
		ВызватьИсключение "Ошибка чтения таблицы Excel " + ИмяФайла + ": в первой строке не найдены заголовки столбцов!";
	КонецЕсли; 
	
	НомСтр = 2;
	Пока Истина Цикл
		ЕстьДанные = Ложь;
		СтруктураДанных = Новый Структура;
		Для НомКол = 1 По КолвоКолонок Цикл
			ИмяКолонки = СоответствиеКолонок.Получить(НомКол);
			ТекЗнач = ЛистЕксель.Cells(НомСтр, НомКол).Value;
			Если НЕ ПустаяСтрока(ТекЗнач) Тогда
				ЕстьДанные = Истина;
			КонецЕсли; 
			СтруктураДанных.Вставить(ИмяКолонки, ТекЗнач);
		КонецЦикла;
		Если НЕ ЕстьДанные Тогда
			Прервать;
		КонецЕсли; 
		НоваяСтрока = ТЗ.Добавить();
		ЗаполнитьЗначенияСвойств(НоваяСтрока, СтруктураДанных);
		НомСтр = НомСтр + 1; 
	КонецЦикла; 
	
	Возврат ТЗ; 
	
КонецФункции

Для унификации вызвова функции чтения данных используется функция ПолучитьТаблицуИзФайла(), которая в зависимости от расширения файла вызывает одну из вышеприведённых функций:

Функция ПолучитьТаблицуИзФайла(ИмяФайла)
	
	Попытка
		Файл = Новый Файл(ИмяФайла);
		Если Лев(ВРег(Файл.Расширение), 4) = ".XLS" Тогда
			Возврат ПолучитьТаблицуИзФайлаЕксель(ИмяФайла);
		ИначеЕсли ВРег(Файл.Расширение) = ".DB" Тогда
			Возврат ПолучитьТаблицуИзФайлаПарадокс(ИмяФайла);
		Иначе 
			Сообщить("ПолучитьТаблицуИзФайла(): загрузка из файла " + ИмяФайла 
				+ " невозможна! Неизвестный тип файла: " + Файл.Расширение + "!", СтатусСообщения.Важное);
		КонецЕсли;
	Исключение
	    Сообщить("Ошибка загрузки данных из файла " + ИмяФайла + ": " + ОписаниеОшибки(), СтатусСообщения.Внимание);
	КонецПопытки; 
	
	Возврат Неопределено;
	
КонецФункции

Далее на основе прочитанных данных создаются необходимые элементы справочников и заполняются данные в регистрах сведений.

Для примера рассмотрим загрузку справочника ФизическиеЛица. При нажатии соответствующей кнопки "Загрузить" (см.скриншот) вызывается процедура-обработчик КнопкаЗагрузитьСотрудникиНажатие():

Процедура КнопкаЗагрузитьСотрудникиНажатие(Элемент)

	ИмяФайла = ИмяФайлаСотрудники;
	НазваниеФайла = "Сотрудники";
	
	Если НЕ ПроверитьИмяФайла(ИмяФайла, НазваниеФайла) Тогда
		Возврат;
	КонецЕсли; 
	
	Сообщить("Начало загрузки: " + ТекущаяДата());
	
	Состояние("Чтение данных из файла...");
	ТаблицаДанных = ПолучитьТаблицуИзФайла(ИмяФайла);
	
	Колво = 0;
	КолвоВсего = ТаблицаДанных.Количество();
	
	Для Каждого СтрокаТаблицы Из ТаблицаДанных Цикл
		ОбработкаПрерыванияПользователя();
		Колво = Колво + 1; 
		ПроцентЗагружено = Цел(Колво / КолвоВсего * 100);
		Состояние("[" + Строка(ПроцентЗагружено) + "%] " + СтрокаТаблицы.famSotr);
		ЗагрузитьФизЛицо(СтрокаТаблицы, ФлагПерезаписыватьСуществующие);
	КонецЦикла; 
	
	Сообщить("Окончание загрузки: " + ТекущаяДата());
	
КонецПроцедуры

В этой процедуре вызывается ранее рассмотренная функция ПолучитьТаблицуИзФайла(ИмяФайла), которая возвращает таблицу значений с данными для загрузки, а затем в цикле по строкам полученной таблицы значений вызывается процедура ЗагрузитьФизЛицо(), которая непосредственно осуществляет создание элемента справочника ФизическиеЛица и сопутствующих ему записей в регистрах сведений (эта процедура работает как в БП2.0, так и в ЗУП2.5):

Процедура ЗагрузитьФизЛицо(Данные, Перезаписывать) Экспорт 
	
	Комментарий = СформироватьКомментарий(Данные, "ID");
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	ФизическиеЛица.Ссылка
	|ИЗ
	|	Справочник.ФизическиеЛица КАК ФизическиеЛица
	|ГДЕ
	|	ФизическиеЛица.Комментарий ПОДОБНО &Комментарий";
	Запрос.УстановитьПараметр("Комментарий", Комментарий);
	РезультатЗапроса = Запрос.Выполнить();
	
	ТекОбъект = Неопределено;
	
	Если НЕ РезультатЗапроса.Пустой() Тогда
		Если НЕ Перезаписывать Тогда
			Возврат;
		КонецЕсли;
		Выборка = РезультатЗапроса.Выбрать();
		Выборка.Следующий();
		ТекОбъект = Выборка.Ссылка.ПолучитьОбъект();
	Иначе 
		ТекОбъект = Справочники.ФизическиеЛица.СоздатьЭлемент();
	КонецЕсли; 
	
	ТекОбъект.Комментарий = Комментарий;
	
	ФамилияФЛ = СПрописной(СокрЛП(Данные.famSotr));
	ИмяФЛ = СПрописной(СокрЛП(Данные.imyaSotr));
	ОтчествоФЛ = СПрописной(СокрЛП(Данные.otchSotr));
	
	ФИО = ФамилияФЛ
		+ ?(ПустаяСтрока(ИмяФЛ), "", " " + ИмяФЛ)
		+ ?(ПустаяСтрока(ОтчествоФЛ), "", " " + ОтчествоФЛ);
	
	ТекОбъект.Наименование = ФИО;
	ТекОбъект.ДатаРождения = ПолучитьДатуИзДанных(Данные.dataR22);
	
	// 1с: МестоРожденияСтрокойПослеРедактирования = ""+СокрЛП(Особое)+","+СокрЛП(Город)+","+СокрЛП(Район)+","+СокрЛП(Область)+","+СокрЛП(Страна);
	ТекОбъект.МестоРождения = "0," + СокрЛП(Данные.gorodJ2) + "," + СокрЛП(Данные.raiionJ2) + "," + СокрЛП(Данные.nazvRegJ2);
		
	ТекОбъект.ИНН = СокрЛП(Данные.innSotr2);
	ТекОбъект.КодИМНС = СокрЛП(Данные.kodGNISotr);
	ТекОбъект.СтраховойНомерПФР = СокрЛП(Данные.regNomerPF);
	КодПола = Лев(ВРег(СокрЛП(Данные.pol)), 1);
	Если КодПола = "Ж" Тогда
		ТекОбъект.Пол = Перечисления.ПолФизическихЛиц.Женский;
	ИначеЕсли КодПола = "М" Тогда
		ТекОбъект.Пол = Перечисления.ПолФизическихЛиц.Мужской;
	Иначе 
		// оно?
		ТекОбъект.Пол = Перечисления.ПолФизическихЛиц.ПустаяСсылка();
	КонецЕсли; 
	
	ТекОбъект.Записать();
	ФизЛицоСсылка = ТекОбъект.Ссылка;
	
	// ФИО физ.лиц
	ПериодЗаписи = ТекОбъект.ДатаРождения;
	НЗ = РегистрыСведений.ФИОФизЛиц.СоздатьНаборЗаписей();
	НЗ.Отбор.ФизЛицо.Установить(ФизЛицоСсылка);
	НЗ.Отбор.Период.Установить(ПериодЗаписи);
	Запись = НЗ.Добавить();
	Запись.ФизЛицо = ФизЛицоСсылка;
	Запись.Период = ПериодЗаписи;
	Запись.Фамилия = ФамилияФЛ;
	Запись.Имя = ИмяФЛ;
	Запись.Отчество = ОтчествоФЛ;
	НЗ.Записать();
	
	// паспортные данные
	ДатаВыдачи = ПолучитьДатуИзДанных(Данные.data_vyidachi);
	ПериодЗаписи = ?(ЗначениеЗаполнено(ДатаВыдачи), ДатаВыдачи, ТекОбъект.ДатаРождения);
	НЗ = РегистрыСведений.ПаспортныеДанныеФизЛиц.СоздатьНаборЗаписей();
	НЗ.Отбор.ФизЛицо.Установить(ФизЛицоСсылка);
	НЗ.Отбор.Период.Установить(ПериодЗаписи);
	Запись = НЗ.Добавить();
	Запись.ФизЛицо = ФизЛицоСсылка;
	Запись.Период = ПериодЗаписи;
	Если ЗначениеЗаполнено(Данные.kodDokumenta) Тогда
		Запись.ДокументВид = Справочники.ДокументыУдостоверяющиеЛичность.НайтиПоРеквизиту("КодИМНС", СокрЛП(Данные.kodDokumenta));
	КонецЕсли; 
	Запись.ДокументНомер = СокрЛП(Данные.seriya);
	Запись.ДокументДатаВыдачи = ДатаВыдачи;
	Запись.ДокументКемВыдан = СокрЛП(Данные.pasportnyie_dannyie);
	НЗ.Записать();
	
	// контактная информация
	СтруктураАдреса = Новый Структура; 
	СтруктураАдреса.Вставить("Индекс"			, СокрЛП(Данные.indeks));
	СтруктураАдреса.Вставить("Регион"			, СокрЛП(Данные.nazvReg));
	СтруктураАдреса.Вставить("Район"			, СокрЛП(Данные.raiion));	
	СтруктураАдреса.Вставить("Город"			, СокрЛП(Данные.gorod));
	СтруктураАдреса.Вставить("НаселенныйПункт"	, СокрЛП(Данные.nasPunkt));
	СтруктураАдреса.Вставить("Улица"			, СокрЛП(Данные.ulica));
	СтруктураАдреса.Вставить("Дом"				, СокрЛП(Данные.dom2));
	СтруктураАдреса.Вставить("Корпус"			, СокрЛП(Данные.korpus));
	СтруктураАдреса.Вставить("Квартира"			, СокрЛП(Данные.kvartira22));
	МЗ = РегистрыСведений.КонтактнаяИнформация.СоздатьМенеджерЗаписи();
	УправлениеКонтактнойИнформацией.ЗаполнитьОбъектРедактированияАдресаПоСтруктуре(МЗ, СтруктураАдреса);
	МЗ.Объект = ФизЛицоСсылка;
	МЗ.Тип = Перечисления.ТипыКонтактнойИнформации.Адрес;
	МЗ.Вид = Справочники.ВидыКонтактнойИнформации.ЮрАдресФизЛица;
	МЗ.Записать();
	
КонецПроцедуры

Проверка существует ли уже такой элемент справочника осуществляется по реквизиту Комментарий. У загружаемых объектов в этом реквизите указывается уникальная строка, возвращаемая функцией СформироватьКомментарий(), которая помимо всего прочего содержит в себе значение ID объекта системы Инфо-предприятие.

Вот код функции СформироватьКомментарий():

Функция СформироватьКомментарий(Данные, ПереченьПолей)
	
	Стр = "#Загружено из Инфо-Предприятие {";
	
	ДанныеКомментария = Новый Структура(ПереченьПолей);
	СписокПолей = Новый СписокЗначений;
	Для Каждого КлючИЗначение Из ДанныеКомментария Цикл
		СписокПолей.Добавить(КлючИЗначение.Ключ);
	КонецЦикла; 
	
	СписокПолей.СортироватьПоЗначению();
	
	ЗаполнитьЗначенияСвойств(ДанныеКомментария, Данные);
	Для Каждого ЭлементСписка Из СписокПолей Цикл
		ИмяПоля = ЭлементСписка.Значение;
		Стр = Стр + ИмяПоля + "=" + ДанныеКомментария[ИмяПоля] + ";";
	КонецЦикла; 
	
	Стр = Стр + "}#";
	
	Возврат Стр;
	
КонецФункции

Вот, собственно, и всё. Процедуры загрузки остальных справочников (Контрагенты, Номенклатура, ОсновныеСредства) аналогичны приведённой здесь процедуре ЗагрузитьФизЛицо(). Если кому-то они будут нужны - пишите, вышлю код.

Весь код под GPLv3.

Скачать файлы

Наименование Файл Версия Размер
ZagruzkaIzInfoPredpriyatie.epf.7z
.7z 12,90Kb
05.12.16
10
.7z 0.1 12,90Kb 10 Скачать

Специальные предложения

Избранное Подписка Сортировка: Древо
В этой теме еще нет сообщений.
Оставьте свое сообщение

См. также

Описание формата внутреннего представления данных 1С в контексте обмена данными

Статья Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных Разработка

Фирма 1С не рекомендует использовать внутреннее представление данных для любых целей, которые отличны от обмена с 1С:Предприятием 7.7. Но сама возможность заглянуть на "внутреннюю кухню" платформы с помощью функций ЗначениеВСтрокуВнутр(), ЗначениеВФайл(), ЗначениеИзСтрокиВнутр() и ЗначениеИзФайла(), дала возможность сообществу программистов 1С разработать новые приемы разработки и анализа. Так, именно на использовании внутреннего представления был построен алгоритм "быстрого массива", который позволяет практически мгновенно создать массив в памяти на основании строки с разделителями. С помощью разбора внутреннего представления можно "на лету" программным кодом выполнить анализ обычной формы и даже сделать редактор графической схемы. Во внутреннем формате сохраняют свои данные между сеансами различные популярные внешние обработки. А еще это возможность сделать быстрый обмен с внешними системами.

1 стартмани

06.09.2019    8247    7    Dementor    27       

Управление ИТ-проектами. Модуль 2: продвинутый онлайн-курс по классическим методам управления проектами. Вебинары проходят с 12 марта по 11 июня 2020 года. Промо

Продвинутый онлайн-курс по классическому управлению ИТ-проектами позволит слушателям освоить инструменты из PMBoK® и 1С:Технологии корпоративного внедрения и научиться их применять для проектов любого масштаба. Курс включает в себя 12 вебинаров и 12 видеолекции, разбор кейсов и рекомендации экспертов по проектам слушателей. Ведущая курса - Мария Темчина.

от 13000 рублей

Шаблон http-сервиса для вашего проекта

Инструменты и обработки Программист Архив с данными v8 v8::Mobile 1cv8.cf Абонемент ($m) Внешние источники данных WEB Мобильная разработка

Http-сервис для обмена данными в формате JSON. Обработчики этого сервиса находятся во внешней обработке, что позволяет дорабатывать его без изменения конфигурации. Также прилагаю пример мобильного приложения для работы с данным сервисом (получает номенклатуру и остатки на складе). Сервис очень быстро разворачивается и масштабируется под ваши задачи.

3 стартмани

04.05.2019    10089    60    MarkoSokolov    47       

1C + Python + Django Rest Framework + Vue.js. Опыт несложной full-stack разработки

Статья Программист Архив с данными v8 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных Обмен через XML WEB Разработка

В этой статье мы рассмотрим путь и основные моменты создания небольшого вэб-сервиса, который мы называем "Онлайн Прайс-лист". Выгрузка из 1С, бэкенд, фронтенд, получение заказов в 1С.

1 стартмани

22.04.2019    20365    21    riposte    63       

Подборка программ для взаимодействия с ЕГАИС Промо

ЕГАИС (Единая государственная автоматизированная информационная система) - автоматизированная система, предназначенная для государственного контроля за объёмом производства и оборота этилового спирта, алкогольной и спиртосодержащей продукции. Инфостарт рекомендует подборку проверенных решений для взаимодействия с системой.

Универсальное расширение 1С для Google Таблиц и Документов

Статья Программист Расширение (cfe) v8 1cv8.cf Абонемент ($m) Внешние источники данных

Эта статья для тех, кто использует G Suite и 1С. Готовое решение для выгрузки отчетов и печатных форм из баз 1С в Google Диск в формате Google Таблиц и Google Документов. Информация по его внедрению. Описание создания и настройки проекта в GCP.

1 стартмани

31.01.2019    9346    22    Maria18    16       

Онлайн-курс «Практические аспекты внедрения регламентированного учета и расчета себестоимости в 1С:ERP на крупных промышленных предприятиях» с 17 февраля по 13 марта 2020 года. Промо

Курс рассчитан для подготовки экспертов по регламентированному учету и учету затрат для внедрения на крупных промышленных предприятиях с «исторически сложившимся» учетом

9000 рублей

Мониторинг показателей систем 1С 8.3 с помощью Zabbix

Инструменты и обработки Системный администратор Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Внешние источники данных Zabbix

Опишу свой опыт мониторинга наших систем 1С с помощью Zabbix и ту пользу, которую можно извлечить из этого.

1 стартмани

05.10.2018    25704    39    akimych    48       

Опыт интеграции мессенджера Telegram c 1C

Статья Программист Нет файла v8 Абонемент ($m) Внешние источники данных

Статья будет полезна всем, кто интересуется возможностями интеграции 1С с мессенджером Telegram. Пустовой Вячеслав в формате короткого мастер-класса рассказывает о создании и настройке бота, позволяющего, к примеру, упростить процессы согласования платежей внутри компании, отгрузки со склада или получение оперативной информации о состоянии дебиторской задолженности.

19.07.2018    14585    475    VachKirp    33       

Открыто голосование за доклады на INFOSTART MEETUP Krasnodar Промо

Выбирайте и голосуйте за самые интересные доклады, лучшие из них попадут в окончательную программу митапа. Голосование продлится до 30 января 2020 года.

Вы больше не будете разбирать Excel как раньше

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Загрузка и выгрузка в Excel

Кому не приходилось разбирать файлы в формате Excel? Все матерятся, плюются, требуют обещаний что "это в последний раз", но таки пишут загрузку из Excel. Потом форматы меняются, строки съезжают, колонки переставляют... Вам это не надоело?

1 стартмани

07.05.2018    21801    64    m-rv    34       

Автоматическое заполнение графиков в ЗУП 3.1

Инструменты и обработки Бухгалтер Архив с данными v8 v8::СПР ЗУП3.x Россия БУ Зарплата Учет рабочего времени Абонемент ($m) Обработка справочников

Данная разработка будет актуальна для организаций с большим количеством графиков (несколько десятков/сотен).

1 стартмани

05.05.2018    12934    19    notserioussam    2       

Программы для исполнения 488-ФЗ: Маркировка товаров Промо

1 января 2019 года вступил в силу ФЗ от 25.12.2018 № 488-ФЗ о единой информационной системе маркировки товаров с использованием контрольных (идентификационных) знаков, который позволяет проследить движение товара от производителя до конечного потребителя. Инфостарт предлагает подборку программ, связанных с применением 488-ФЗ и маркировкой товаров.

Чтение и запись из таблиц гугл (google sheets) в табличный документ 1С (8.3, управляемые формы)

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Внешние источники данных WEB

Внешняя обработка на управляемой форме для 1С версии 8.3 для доступа к сервисам Google Sheets c использованием протокола авторизации OAuth 2.0. Выполняет получение списка листов таблицы гугл, чтение таблицы гугл в табличный документ 1С и запись из табличного документа 1С в таблицу гугл. Тестирование проводилось на платформе 1С:Предприятие 8.3 (8.3.11.2954).

1 стартмани

09.04.2018    25981    179    Ko1t    60       

INFOSTART MEETUP Krasnodar. 14 февраля 2020 г. Промо

Краснодар станет первым в 2020 году местом, где пройдет региональная встреча IT-специалистов сообщества Инфостарт. Тема мероприятия - управление и технологии автоматизации учета на платформе "1С: Предприятие". Стоимость участия - 5000 рублей. Цена действительна до 26.12.2019.

Практикум по созданию обменов данными через протокол oData «за полдня»

Статья Программист Внешняя обработка (ert,epf) v8 1cv8.cf Россия Абонемент ($m) Практика программирования Внешние источники данных

Про oData и 1С было довольно много написано, однако же описания работы и с чтением, и с записью данных через JSON я так и не встретил ни на этом ресурсе ни на других. Попробую раскрыть эту тему.

1 стартмани

20.03.2018    21141    12    timm00    64       

Практика доступа в базу 1С через протокол oData. Изменение данных

Статья Системный администратор Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных

Продолжаем знакомство с протоколом oData и в данной статье мы рассмотрим такие вопросы, как минимально необходимый багаж теоретических знаний, необходимый для работы, способы изменения доступных данных, а также с какими ограничениями можем при этом столкнуться. Осторожно, будет много скриншотов!

1 стартмани

30.12.2017    26332    102    Dementor    26       

PgConf.Russia 2020. 3-5 февраля 2020 г. Москва. Промо

PGConf.Russia – международная техническая конференция по открытой СУБД PostgreSQL, ежегодно собирающая более 700 разработчиков, администраторов баз данных и IT-менеджеров для обмена опытом и профессионального общения. Для участников сообщества infostart.ru скидка 5% на участие в конференции.

от 12350 рублей

Приемы эффективной загрузки данных из Excel в 1С

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Загрузка и выгрузка в Excel

Показаны приемы эффективной работы с Excel для загрузки данных в 1С.

1 стартмани

13.12.2017    33303    78    alexey.kutya    78       

Новый раздел на Инфостарте - Electronic Software Distribution Промо

Инфостарт напоминает: на нашем сайте можно купить не только ПО, связанное с 1С. В нашем арсенале – ESD-лицензии на ПО от ведущих вендоров: Microsoft, Kaspersky, ESET, Dr.Web, Аскон и другие.

  • Низкие цены, без скрытых платежей и наценок
  • Оперативная отгрузка
  • Возможность оплаты с личного счета (кешбек, обмен стартмани на рубли и т.п.)
  • Покупки идут в накопления для получения скидочных карт лояльности Silver (5%) и Gold (10%)

Что такое HMAC и JWT и как это использовать в 1С

Статья Программист Архив с данными v8 1cv8.cf Абонемент ($m) Внешние источники данных

Лёгкая статья про стандарты HMAC и JWT с небольшой теорией и исходным кодом.

1 стартмани

20.04.2017    17103    82    keypax    43       

Онлайн-курс "Подготовка к экзамену 1С:Эксперт и 1С:Профессионал по технологическим вопросам" с 7 по 24 апреля 2020 г. Промо

На курсе вы получите практические навыки решения задач производительности 1С, в том числе характерных для высоконагруженных информационных систем (более 1000 пользователей). Подготовка к экзамену – только одна из составляющих курса. 70% слушателей приходят за знаниями, которые позволят расти и зарабатывать, делать сложные задачи на крупных проектах.

16450 рублей

Загрузка номенклатуры по штрихкоду: Управление Торговлей 11.3; Розница 2.2; Розница для Казахстана 2.2

Инструменты и обработки Системный администратор Программист Бухгалтер Внешняя обработка (ert,epf) v8 v8::ОУ v8::УФ Розница УТ11 Розничная и сетевая торговля (FMCG) Рестораны, кафе и фаст-фуд Россия УУ Оптовая торговля Розничная торговля Ценообразование, анализ цен Абонемент ($m) Обработка справочников Ценообразование, прайсы

Розница 2.2, Управление Торговлей 11.3. Создание номенклатуры из интернета с помощью сканера штрихкодов либо терминала сбора данных. Варианты создания, автовыбор наилучшей позиции, источники, цены, загрузка картинки - всё это очень гибко и просто настраивается. Текущие открытые источники: barcode-list.ru(на текущий момент не работает); goodsmatrix.ru; ean13.info(может не работать капча); barcodes.olegon.ru. Автор программы не несёт ответственность за информацию, предоставляемую перечисленными выше открытыми источниками, так же не отвечает за их работоспособность. Данные источники принадлежат не автору программы. Данная программа нужна лишь для автоматизированного поиска информации на них.

10 стартмани

30.03.2017    45681    51    myALKleon    39       

Процессор вывода результата компоновки данных в JSON. И не только...

Инструменты и обработки Программист Конфигурация (md, cf) v8 Абонемент ($m) Внешние источники данных

У каждого разработчика возникают задачи интеграции решений. Основная масса решений призвана вывести данные из «1С:Предприятие 8» в обусловленном формате. Разработчики используют огромную часть своих драгоценных ресурсов на реализацию определенной структуры вывода и необходимого формата. А что если...

1 стартмани

14.02.2017    20106    42    pbazeliuk    27       

Подборка решений для взаимодействия со ФГИС «Меркурий» Промо

С 1 июля 2019 года все компании, участвующие в обороте товаров животного происхождения, должны перейти на электронную ветеринарную сертификацию (ЭВС) через ФГИС «Меркурий». Инфостарт предлагает подборку программ, связанных с этим изменением.

Что нам стоит Push построить

Инструменты и обработки Программист Архив с данными v8 v8::Mobile Абонемент ($m) Внешние источники данных

Попробовал некоторое время назад, push сообщения, реализованные в платформе. Понравилось, но есть несколько минусов, на примере одной программы сообщений (не буду показывать пальцем), спустя некоторое время, сообщения переставали приходить онлайн, а на компьютере приходили моментально, при этом сами смартфоны звались флагманами. Читал позднее статью, где описывалось, что проблема на стороне смартфонов, что-то вроде технологий энергосбережения, но точно не помню. Также немалый минус доступно только для смартфонов.

1 стартмани

08.09.2016    23525    23    PloAl    8       

INFOSTART MEETUP Kazan. 13 марта 2020 г. Промо

Инфостарт продолжает путешествие по России. Следующая остановка - Казань. Тема мероприятия - управление и технологии автоматизации учета на платформе "1С: Предприятие". Ждем всех: докладчиков и участников! Стоимость участия - 5 500 рублей. Цена действительна до 30.01.2020

5 500

Согласование (подсистема). Для любого справочника и документа в 1С. Встраивается в любые конфигурации

Инструменты и обработки Пользователь Руководитель проекта Архив с данными v8 1cv8.cf БП3.0 КА2 УУ Документооборот и делопроизводство Абонемент ($m) Управление бизнес-процессами (BPM) Обработка документов Обработка справочников

Подсистема для согласования в 1С. Для настройки нового согласования не требуется программировать, все делается в режиме исполнения. Открытый код. Бизнес-процессы. Документооборот. Проект выложен на GitHub.

1 стартмани

25.08.2016    41333    231    BlizD    192       

Сдача регламентированной отчетности из программ 1С Промо

Сдача регламентированной отчетности из программ "1С" во все контролирующие органы без выгрузок и загрузок в другие программы. Для групп компаний действуют специальные предложения.

от 1500 руб.

Подсистема обмена данными с порталом ИМНС по электронным счетам-фактурам (автоматический обмен)

Инструменты и обработки Системный администратор Программист Бухгалтер Конфигурация (md, cf) v8 1cv8.cf Беларусь БУ НДС Абонемент ($m) Внешние источники данных WEB Инструментарий разработчика

Подсистема включает документы и обработки для автоматического обмена данными с порталом ИМНС через web-сервис. Присутствует возможность заполнения данными типовых операций за период, учёта входящих документов, учёта произвольных исходящих документов. Приложены обработки для запуска задания планировщика на автоматический обмен данными.

1 стартмани

28.07.2016    27813    28    c1nil    4       

 Интеграция 1С и C#. Обращение к 1С через COM. Создание номенклатуры и выполнение запроса к 1С из C# на примере интеграции с Союз-PLM (система информационной поддержки жизненного цикла изделий). Обработка «Загрузка заказа на сборку». (ERP)

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 ERP2 Абонемент ($m) Загрузка и выгрузка в Excel Внешние источники данных Интеграция

Союз-PLM представляет собой полнофункциональный программный комплекс для решения  широкого спектра задач управления инженерной технической информацией наукоемких изделий и сложных инженерных объектов в области машиностроения, приборостроения, архитектуры, строительства. На практике, это управление конструкторской документацией, интегрированное с САПР, бизнес-процессы, файловый архив. Все это работает в SQL и шевелится с помощью скриптов на C#. Скрипты свободно  отлаживаются в MS Visual Studio. Подробнее смотрите на их сайте: http://www.programsoyuz.ru/products/system-soyuz-plm.html  Редактирование, конструирование и использование бизнес-процессов на порядок лучше систем на базе 1С из тех, что я изучил.

1 стартмани

25.07.2016    35945    6    milkers    2