Планировщик 1С. Настройка расписания повторяющихся событий и перемещение элементов мышью

Публикация № 661739

Разработка - Практика программирования

БСП задачи календарь планировщик

24
Для самописной конфигурации на базе БСП была разработана обработка "Календарь", в которой используется планировщик 1С. В публикации пойдёт речь о реализации с его помощью некоторых задач, таких как перетаскивание элементов календаря мышью или настройка повторения событий по расписанию.

В нашем "Календаре" отображаются стандартные "Задачи исполнителя" и элементы собственного справочника "События".

На основании справочника "События" можно стартовать бизнес-процессы, кроме того, для них доступна настройка повторения по расписанию. Нужно отметить, что повторяются события только в календаре, новые элементы справочника при этом не создаются. А вот бизнес-процессы на основании этих виртуальных повторяемых событий должны создаваться вполне реальные, с реальными датами. Рассмотрим пример реализации данной задачи.

Справочник "События" выглядит следующим образом:

Форма:

В режиме "Предприятие":

Расписание - реквизит формы с типом значения "Произвольный". При его редактировании свойства расписания записываются в реквизиты события, а при создании формы события - наооборот.

&НаКлиенте
Процедура ПослеИзмененияРасписания(РасписаниеРезультат, ДополнительныеПараметры) Экспорт
	
	Если РасписаниеРезультат <> Неопределено Тогда
		
		Модифицированность = Истина;
		Расписание = РасписаниеРезультат;
				
		ЗаполнитьЗначенияСвойств(Объект, Расписание);	
		
		//дни недели
		Объект.ПовторениеПоДнямНедели.Очистить();
		Для Каждого Элемент из Расписание.ДниНедели Цикл
			Строка = Объект.ПовторениеПоДнямНедели.Добавить();
			Строка.День = Элемент;
		КонецЦикла;		
		
		//месяцы
		Объект.ПовторениеПоМесяцам.Очистить();
		Для Каждого Элемент из Расписание.Месяцы Цикл
			Строка = Объект.ПовторениеПоМесяцам.Добавить();
			Строка.Месяц = Элемент;
		КонецЦикла;		
		
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура РасписаниеНажатие(Элемент, СтандартнаяОбработка)
	
	СтандартнаяОбработка = ложь;
	
	Обработчик = Новый ОписаниеОповещения("ПослеИзмененияРасписания", ЭтотОбъект);
	ДиалогРасписания = Новый ДиалогРасписанияЭлементаПланировщика(?(НЕ ТипЗнч(Расписание) = Тип("РасписаниеЭлементаПланировщика"), Новый РасписаниеЭлементаПланировщика, Расписание));
	ДиалогРасписания.Показать(Обработчик);
	
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьРасписание()
	
	Элементы.Расписание.Видимость = Объект.Повторять;
	
	Если Объект.Повторять Тогда
		
		Расписание = Новый РасписаниеЭлементаПланировщика;
		ЗаполнитьЗначенияСвойств(Расписание, Объект);
		Расписание.ДниНедели = Объект.ПовторениеПоДнямНедели.Выгрузить().ВыгрузитьКолонку("День");
		Расписание.Месяцы = Объект.ПовторениеПоМесяцам.Выгрузить().ВыгрузитьКолонку("Месяц");	
		
		Если Расписание.ПериодЛет=0 И Расписание.ПериодМесяцев=0 И Расписание.ПериодНедель=0 И Расписание.ПериодПовтораДней=0 Тогда
			Расписание = "настроить расписание...";
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

При заполнении календаря расписание элементов заполняется сходным образом:

//{Заполняем текст запроса по событиям}

Выборка = Запрос.Выполнить().Выбрать();
	
ДанныеКалендаря.Элементы.Очистить();
	
Пока Выборка.Следующий() Цикл

    Элемент = ДанныеКалендаря.Элементы.Добавить(НачалоДня(Выборка.ДатаНачала), КонецДня(Выборка.ДатаОкончания));			
    Элемент.Текст = Выборка.Наименование;
		
  	Элемент.Значение = Выборка.Ссылка;						
	
  	Если Выборка.Ссылка.Повторять Тогда
    	Элемент.Расписание = Новый РасписаниеЭлементаПланировщика;
	    ЗаполнитьЗначенияСвойств(Элемент.Расписание, Выборка.Ссылка);
	    Элемент.Расписание.ДниНедели = Объект.ПовторениеПоДнямНедели.Выгрузить().ВыгрузитьКолонку("День");
	    Элемент.Расписание.Месяцы = Объект.ПовторениеПоМесяцам.Выгрузить().ВыгрузитьКолонку("Месяц");					
   	КонецЕсли;

КонецЦикла;

Планировщик 1С обрабатывает элементы с заполненным расписанием следующим образом: на каждый период повтора создаётся элемент планировщика с датами начала и окончания, соответствующими периоду повтора, и значением единственного реального элемента, который мы добавили при обходе выборки.

Выглядит это так:

Обработка "ПередНачаломРедактирования" элемента планировщика у нас нестандартная и вызывает открытие формы задачи/события в зависимости от типа значения. Но какой бы элемент из повторяющихся мы не открывали, даты начала и окончания в форме будут исходные, в данном случае 18.08.2017 и 19.08.2017. 

Значит, из календаря будем открывать форму с параметрами, и обрабатывать их при создании на сервере.

&НаСервере
Функция ПолучитьПараметрыФормыСобытия(Событие, Начало, Конец)
	
	ПараметрыФормы = Новый Структура("Ключ, ПовторяемыйЭлемент, ДатаНачалаЭлементаПовторения, ДатаОкончанияЭлементаПовторения", Событие, Событие.Повторять, Начало, Конец);
	
	Возврат ПараметрыФормы;
	
КонецФункции

&НаКлиенте
Процедура ДанныеКалендаряПередНачаломРедактирования(Элемент, НовыйЭлемент, СтандартнаяОбработка)
	
	СтандартнаяОбработка = ложь;	
	
	Если НЕ НовыйЭлемент Тогда
		
		ВыбранныйЭлемент = Элемент.ВыделенныеЭлементы[0];
		ЗначениеЭлемента = ВыбранныйЭлемент.Значение;
		
		Если ТипЗнч(ЗначениеЭлемента) = Тип("ЗадачаСсылка.ЗадачаИсполнителя") Тогда
			ПоказатьЗначение(,ЗначениеЭлемента);
		ИначеЕсли ТипЗнч(ЗначениеЭлемента) = Тип("СправочникСсылка.События") Тогда
			ПараметрыФормы = ПолучитьПараметрыФормыСобытия(ЗначениеЭлемента, ВыбранныйЭлемент.Начало, ВыбранныйЭлемент.Конец);
			ОткрытьФорму("Справочник.События.ФормаОбъекта", ПараметрыФормы);
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

Обработчик при создании формы события:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ЗаполнитьРасписание();
	
	ДатаНачалаЭлементаПовторения = Параметры.ДатаНачалаЭлементаПовторения;
	ДатаОкончанияЭлементаПовторения = Параметры.ДатаОкончанияЭлементаПовторения;
	ПовторяемыйЭлемент = Параметры.ПовторяемыйЭлемент;

КонецПроцедуры

Если присмотреться, на размещённом в начале статьи скриншоте с формой события по два элемента с заголовками "Дата начала" и "Дата окончания". В зависимости от того, повторяемый это элемент или основной, видны либо реальные "Дата начала" и "Дата окончания", либо реквизиты формы "Дата начала элемента повторения" и "Дата окончания элемента повторения".

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	
	Элементы.ДатаНачала.Видимость = НЕ ПовторяемыйЭлемент;
	Элементы.ДатаНачалаЭлементаПовторения.Видимость = ПовторяемыйЭлемент;
	
	Элементы.ДатаОкончания.Видимость = НЕ ПовторяемыйЭлемент;
	Элементы.ДатаОкончанияЭлементаПовторения.Видимость = ПовторяемыйЭлемент;
	
	Элементы.ФормаКоманднаяПанель.ПодчиненныеЭлементы["ФормаСоздатьНаОсновании"].Видимость = НЕ ПовторяемыйЭлемент;
	Элементы.ФормаГруппаСоздатьНаОсновании.Видимость = ПовторяемыйЭлемент;
	
КонецПроцедуры

Стандартный ввод на основании для повторяемых элементов тоже пришлось переписать:

&НаКлиенте
Процедура ВводНаОсновании(Команда)
	
	Основание = Новый Структура("Ссылка, Начало, Конец", Объект.Ссылка, ДатаНачалаЭлементаПовторения, ДатаОкончанияЭлементаПовторения);
	ПараметрыФормы = Новый Структура("Основание", Основание);
	ОткрытьФорму("БизнесПроцесс.СложноеЗадание.ФормаОбъекта", ПараметрыФормы);
	
КонецПроцедуры

Разумеется, все запущенные на основании повторяемых элементов бизнес-процессы будут подчинены единственному реальному событию.

А теперь о реализации так полюбившейся пользователям функции - перемещения элементов календаря мышкой с сохранением изменений. Планировщик позволяет перемещать элементы и изменять их границы мышью "из коробки". При этом у элементов планировщика меняются даты начала и окончания. Осталось только записать их в реальные объекты.

&НаКлиенте
Процедура ДанныеКалендаряПриОкончанииРедактирования(Элемент, НовыйЭлемент, ОтменаРедактирования)
	
	Для Каждого ВыделенныйЭлемент Из Элемент.ВыделенныеЭлементы Цикл
		ОбновитьДатыЗаписиКалендаря(ВыделенныйЭлемент.Значение, ВыделенныйЭлемент.Начало, ВыделенныйЭлемент.Конец);
	КонецЦикла;
		
КонецПроцедуры

&НаСервере
Процедура ОбновитьДатыЗаписиКалендаря(ЗаписьКалендаря, ДатаНачала, ДатаОкончания)
	
	ЗаписьКалендаряОбъект = ЗаписьКалендаря.ПолучитьОбъект();
	
	Если ТипЗнч(ЗаписьКалендаря) = Тип("СправочникСсылка.События") Тогда
		
		ЗаписьКалендаряОбъект.ДатаНачала = ДатаНачала;
		ЗаписьКалендаряОбъект.ДатаОкончания = ДатаОкончания;		
		
	ИначеЕсли ТипЗнч(ЗаписьКалендаря) = Тип("ЗадачаСсылка.ЗадачаИсполнителя") Тогда
		
		Если ЗначениеЗаполнено(ЗаписьКалендаряОбъект.ДатаПринятияКИсполнению) Тогда
			ЗаписьКалендаряОбъект.ДатаПринятияКИсполнению = ДатаНачала;
		ИначеЕсли ЗначениеЗаполнено(ЗаписьКалендаряОбъект.ДатаНачала) Тогда
			ЗаписьКалендаряОбъект.ДатаНачала = ДатаНачала;
		Иначе
			ЗаписьКалендаряОбъект.Дата = ДатаНачала;
		КонецЕсли;
			
		ЗаписьКалендаряОбъект.СрокИсполнения = ДатаОкончания;
		
	КонецЕсли;		
	
	ЗаписьКалендаряОбъект.Записать();
			
КонецПроцедуры

Удобно выделять элементы планировщика разных видов цветом. У элемента есть свойства "ЦветФона", "ЦветТекста" и "ЦветРамки". В зависимости от тех или иных условий можно выбирать какие угодно их сочетания. Планировщик сам позаботится о том, чтобы элементы остались видимыми. В нашей конфигурации задачи, не принятые к исполнению, выделяются одним цветом, принятые - другим, а для каждого события цвет выбирается пользователем и сохраняется в справочнике в реквизите типа "ХранилищеЗначений". При заполнении планировщика данными цвет события устанавливается так:

//получим цвет события
СобытиеОбъект = Выборка.Ссылка.ПолучитьОбъект();
СохранённыйЦвет = СобытиеОбъект.Цвет.Получить();
Если Не СохранённыйЦвет = неопределено Тогда
	ЦветСобытия = СохранённыйЦвет;
Иначе
	ЦветСобытия = ЦветаСтиля.СобытиеКалендаря;
КонецЕсли;	
Элемент.ЦветФона = ЦветСобытия;	

Вот и всё самое интересное, что мне удалось выяснить в процессе работы с планировщиком. Возможно, кому-нибудь эта информация будет полезна.

24

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. user878162 20.06.18 11:10 Сейчас в теме
Добрый день.
Подскажите пожалуйста, а как реализовали сам запуск по расписанию процессов? Именно с учетом периодичности. Как определяете что наступило время выполнить нужное действие?

Разбираюсь с подобной задачей, планировщик просто отрисовывает элементы с установленной периодичностью, но у него нет методов для проверки входит ли конкретная дата в этот диапазон. Подскажите в какую сторону смотреть и как проверить принадлежность определенной даты периодичности установленной в задании. Надеюсь понятно сформулировал :-)
2. WhiteOwl 300 20.06.18 17:27 Сейчас в теме
(1) а это уже совершенно другая история))) При завершении бизнес-процесса смотрим в его расписание и вручную анализируем - если повтор по дням, то ищем следующий подходящий день, если еженедельно - то через неделю и т.п. Определив дату, стартуем следующий бизнес процесс. Подробностей я, к сожалению, уже не помню. Можно посмотреть как реализован типовой повтор регламентных заданий. Также, возможно, что-то подобное есть в конфигурации "Документооборот" от 1С.
nlvhome; user878162; +2 Ответить
3. user878162 21.06.18 04:41 Сейчас в теме
4. mrcamomile 9 13.12.18 17:45 Сейчас в теме
(1) Можно вот так выкрутиться

РасписаниеЭП - расписание элемента планировщика
Функция ПолучитьДатыПоРасписанию(Знач ДатаНачала, Знач ДатаОкончания, РасписаниеЭП = Неопределено) Экспорт 
	
	Результат = Новый Массив;
	
	ДатаМаксимум = '21000101';
	ДатаНачала = НачалоДня(ДатаНачала);
	ДатаОкончания = НачалоДня(ДатаОкончания);
	Результат.Добавить(ДатаНачала);
	
	Если РасписаниеЭП = Неопределено Тогда 
		Возврат Результат;
	КонецЕсли;
		
	РРЗ = Новый РасписаниеРегламентногоЗадания;
	ЗаполнитьЗначенияСвойств(РРЗ, РасписаниеЭП);
	ДатаНачалаПоследнегоЗапуска = Результат[0];
	Пока 
		(ДатаОкончания = '00010101' И ДатаНачала < ДатаМаксимум)
		ИЛИ (ДатаОкончания > '00010101' И ДатаНачала < ДатаОкончания)
	Цикл
		ДатаНачала = ДатаНачала + 86400;
		ТребуетсяВыполнение = РРЗ.ТребуетсяВыполнение(ДатаНачала, ДатаНачалаПоследнегоЗапуска);
		Если ТребуетсяВыполнение Тогда
			Результат.Добавить(ДатаНачала);
			ДатаНачалаПоследнегоЗапуска = ДатаНачала;
		КонецЕсли;
	КонецЦикла; 
	
	Возврат Результат;
	
КонецФункции
Показать
5. mrcamomile 9 13.12.18 18:09 Сейчас в теме
(4) вот отличия между "РасписаниеРегламентногоЗадания" / "РасписаниеЭлементаПланировщика"
Прикрепленные файлы:
6. TheDemonHrono 24.02.19 19:50 Сейчас в теме
А как скачать, чтобы посмотреть по ближе?
7. WhiteOwl 300 24.02.19 21:56 Сейчас в теме
(6) к сожалению, никак. Это часть нетиповой конфигурации.
Оставьте свое сообщение

См. также

Агрегатные функции СКД, о которых мало кто знает 315

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    9368    ids79    42       

Три костыля. Сказ про фокусы в коде 121

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    7524    YPermitin    67       

Отслеживание выполнения фонового задания 133

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    7831    ids79    14       

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 239

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    9718    ids79    22       

Фоновое выполнение кода в 1С - это просто 117

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    9540    avalakh    21       

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты 125

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    8790    ids79    6       

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 134

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования Разработка

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    8292    ids79    24       

"Меньше копипаста!", или как Вася универсальную процедуру писал 170

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    6088    SeiOkami    48       

Создание отчетов с помощью СКД - основные понятия и элементы 188

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    16892    ids79    16       

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 174

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    11269    dmurk    134       

Регистры накопления. Структура хранения в базе данных 173

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    16877    YPermitin    27       

Выполнение внешней обработки в фоновом задании 147

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    9524    Eret1k    22       

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    4658    m-rv    2       

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    7171    m-rv    16       

О расширениях замолвите слово... 193

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    16045    ellavs    122       

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 199

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    12488    ellavs    83       

Трюки с внешними источниками данных 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    12588    YPermitin    52       

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS) 162

Статья Программист Нет файла v8 v8::Права Бесплатно (free) Практика программирования БСП (Библиотека стандартных подсистем) Роли и права

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    15088    ids79    9       

EnterpriseData – часть 2. Процесс выгрузки данных 126

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Основные этапы выгрузки данных через ED, обработчики событий выгрузки, правила обработки данных, правила конвертации объектов, конвертация свойств первого и второго этапов, процедуры БСП, используемые при выгрузке данных, структура «КомпонентыОбмена».

26.12.2018    12473    ids79    27       

Новый подход к обмену данными EnterpriseData 202

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    20992    ids79    72       

EnterpriseData - пример доработки правил конвертации без использования КД 3.0 в расширении конфигурации 117

Статья Программист Нет файла v8 v8::УФ БП3.0 УТ11 Россия Windows Бесплатно (free) Практика программирования Обмен через XML

В статье подробно описан реальный пример доработки обмена данными через EnterpriseData (универсальный формат обмена) между конфигурациями УТ 11.4 и Бухгалтерия 3.0

16.11.2018    18511    ids79    20       

Программное заполнение пользовательских параметров и отборов СКД 135

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Публикация представляет из себя краткие примеры того, как можно заполнять параметры СКД программно так, чтобы все параметры и отборы были доступны в быстрых настройках и в обычных (типовых) настройках параметров и отборов СКД.

13.11.2018    19135    Unk92    18       

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С 125

Статья Программист Нет файла v8 v8::blocking 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    20576    ids79    40       

Вспомогательные инструкции в коде 1С 104

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    20232    tormozit    100       

Произвольный код в фоновом режиме 163

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Задача: реализовать выполнение произвольного кода в фоновом режиме без изменения конфигурации, т.е. во внешней обработке.

03.09.2018    14396    nikita0832    41       

Основные понятия и механизмы оптимизации клиент-серверного взаимодействия в 1C 144

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы Практика программирования

У многих начинающих 1С программистов часто возникают вопросы про клиент-серверное взаимодействие в 1С и чтобы разобраться в непростых механизмах платформы, необходимо понять, что же такое контекст, для чего предназначены директивы компиляции, что представляют собой контекстные/внеконтекстные вызовы и как наиболее оптимально описывать прикладные задачи в модулях управляемых форм.

23.08.2018    20891    Rain88    42       

Повышаем эффективность разработки правил обмена 122

Статья Программист Нет файла v8 КД ОС Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8

Как повысить скорость и качество разработки правил обмена? Как вести групповую разработку правил обмена? Как облегчить сопровождение правил обмена после передачи в эксплуатацию? Об этом и многом другом вы можете узнать из этой статьи.

25.06.2018    19126    olegtymko    43       

Введение в механизм представлений в ЗУП ред. 3 152

Статья Программист Нет файла v8 v8::СПР ЗУП3.x Бесплатно (free) Практика программирования

В нашей организации на первом же телефонном собеседовании на должность разработчика по ЗУП ред. 3 вас обязательно спросят о том, что такое "Представления".

04.06.2018    24099    xrrg    82       

Как сделать запрос на изменение данных 75

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    21028    m-rv    21       

Строим графы средствами 1С (без GraphViz) 42

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Множество статей на Инфостарте описывают, как работать с компонентой GraphViz, чтобы построить ориентированный граф. Но практически нет материалов, как работать с такими графами средствами 1С. Сегодня я расскажу, как красиво строить графы с минимальным пересечением. Нам этот метод пригодился для отрисовки алгоритмов в БИТ.Финансе, т.к. типовой механизм не устраивал. Еще это может быть полезно для визуализации различных зависимостей: расчета себестоимости, графы аффилированности компаний и т.д. Надеюсь, эта статья поможет сделать мир 1С красивее и гармоничней:) Итак, поехали...

23.05.2018    16803    slozhenikin_com    19       

Распределение расходов пропорционально продажам 9

Статья Программист Пользователь Нет файла v8 v8::ОУ УТ10 УУ Финансовый учет и бюджетирование (FRP) Учет доходов и расходов Бесплатно (free) Практика программирования

Финансовая модель. Распределение административных расходов по подразделениям пропорционально продажам за месяц. Дополнительные реквизиты против бизнес-процессов!

13.05.2018    11206    Rustig    9       

Просмотр временных таблиц запроса в отладчике без изменения кода 126

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

Данный способ можно использовать для просмотра содержимого временных таблиц запросов (менеджеров временных таблиц) без внесения изменений в код.

24.04.2018    23959    avfed@rambler.ru    19       

Минимализмы 3 350

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    35270    ildarovich    44       

Этюды по программированию. Взаимодействие с Microsoft Word 108

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Часто приходится заниматься созданием сложных документов Word с таблицами, вложенными фрагментами, хитрым оформлением и прочими радостями жизни. Это - попытка как-то структурировать полученный опыт, чтобы не приходилось перерывать ворох старых обработок в поисках крупиц истины. Надеюсь, эта статья будет полезна и Вам.

11.12.2017    25682    milkers    23       

Метод формирования движений в типовых регистрах нетиповыми регистраторами 31

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    21167    itriot11    34       

1С: Конвертация данных 3. Инструкции и примеры. EnterpriseData (универсальный формат обмена) 717

Статья Программист Нет файла v8 КД Бесплатно (free) Перенос данных из 1C8 в 1C8 Практика программирования Обмен через XML

Что такое КД3? Как начать использовать? Полезные дополнения к документации. Что нужно исправить в типовых обработках и конфигурации. Как изменить правила обмена не снимая конфигурацию с поддержки. Как отлаживать правила обмена?

19.11.2017    136441    MaxS    251       

Заполнение данных по ИНН контрагента с помощью альтернативного сервиса огрн.онлайн 131

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Код для заполнения данных по ИНН контрагента из ЕГРЮЛ с сайта огрн.онлайн.

01.11.2017    22481    slava_1c    49       

Программные перечисления, ч.2: приемы кэширования при разработке 65

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Все знают, что такое кэш, и зачем он нужен. Но в 1С разработчик обычно использует кэширование только на уровне конфигурации, а в какой-нибудь обработке скорее ломает голову над запросом - как получить все данные за один заход... Хочется рассказать о том, как можно добиться хороших результатов с стратегией "разделяй и властвуй".

30.10.2017    20911    unichkin    17       

Разбираемся с настройками компоновки данных 159

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Краткая шпаргалка по программной работе с настройками СКД

29.10.2017    23857    json    9       

Работа с Excel 287

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Загрузка и выгрузка в Excel

Собрал различные полезности для работы с Excel из 1С. Иногда приходится форматировать документ Excel программно из 1С. Так вот, чтобы не искать постоянно на просторах интернета как сделать левое выравнивание в ячейке Excel из 1С и т.п. решил опубликовать это...

23.10.2017    24277    arakelyan    39       

Добавление команд печати в конфигурациях на БСП 2.4.3 (в частности, в самописных документах в Бухгалтерии 3.0 после релиза 3.0.52.35) 143

Статья Программист Нет файла v8 v8::БУ БП3.0 Россия Бесплатно (free) Печатные формы документов Практика программирования БСП (Библиотека стандартных подсистем)

В статье https://infostart.ru/public/237013/ пользователя nick max рассматривался список действий для подключения команд печати в Бухгалтерии 3.0, работающей на БСП 2.3.6. В новом релизе Бухгалтерии 3.0.52.35 от 15.09.2017г. стала использоваться БСП 2.4.3, из-за чего произошли изменения в процедурах общих модулей, связанных с механизмом печати, и в процедурах их вызова в формах документов и в формах списков. Рассмотрим их.

18.09.2017    46333    bugtester    43       

Отказ от работы с временными файлами при работе с двоичными данными или Потоки как простая замена ADODB.Stream и временным файлам 126

Статья Программист Нет файла v8 Россия Бесплатно (free) Практика программирования

В платформе начиная с версии 3.8.9 (как я понял по документации) появился расширенный функционал средств работы с двоичными данными. Если раньше простой и очевидный способ преобразования данных строился на использовании временных файлов, то теперь благодаря новым средствам можно уйти от их использования.

12.09.2017    18057    vardeg    31