Заполнение дополнительных реквизитов при программном открытии формы из другой формы

Публикация № 901654

Разработка - Практика программирования

Дополнительные реквизиты Программное заполнение формы Программное открытие формы Свойства_НаборыДополнительныхРеквизитовОбъекта ДополнительныйРеквизитЗначение Типовые конфигурации ЗУП БП УП УПП ERP 1с 8

19
Дополнительные реквизиты в типовых конфигурациях хранятся у объектов в табличной части ДополнительныеРеквизиты. Но на форме ее нет. Так что же заполнять при программном заполнении формы для открытия? И откуда берется нечто вида "ДополнительныйРеквизитЗначение_ 2C506AEDx453Ax11E8x8130x0050569C309C_ 03D89E6Fx64A2x11E8xBDFBx0022642B037A"?

Дополнительные реквизиты в типовых конфигурациях хранятся у объектов в табличной части ДополнительныеРеквизиты.

Например, есть документ Отпуск. У него есть дополнительный реквизит "Не по графику", тип булево.

Если мы попробуем заполнить программно табличную часть ДополнительныеРеквизиты на форме, т.е. ДанныеФормыКоллекция ДополнительныеРеквизиты Объекта полученной формы ФормаСозданияДокумента (где значение РеквизитыДокумента25.НеПоГрафику = Истина):

&НаСервере
Функция ПолучитьРеквизитыОтпуск25(ИмяДокумента, УИД) Экспорт
  ...
  РеквизитыДокумента25 = Новый Структура;
  РеквизитыДокумента25.Вставить("НеПоГрафику", ТекДокументТам.ФлагОтпускНеПоГрафику);
  РеквизитыДокумента25.Вставить("НеПоГрафикуСвойство", ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию("Не по графику"));

.....
&НаКлиенте
Процедура ЗагрузитьДокумент25(Команда = Неопределено)
  ...
  РеквизитыДокумента25 = ПолучитьРеквизитыОтпуск25(ТекДокумент.ТипДокументаТам, ТекДокумент.УИД);
  ...

  Если РеквизитыДокумента25 <> Неопределено Тогда
				
    Если РеквизитыДокумента25.НеПоГрафику Тогда
      ПараметрыОтбораСтрок = Новый Структура;
      ПараметрыОтбораСтрок.Вставить("Свойство", РеквизитыДокумента25.НеПоГрафикуСвойство);
      ОтобранныеСтроки = ФормаСозданияДокумента.Объект.ДополнительныеРеквизиты.НайтиСтроки(ПараметрыОтбораСтрок);
      Если ОтобранныеСтроки.Количество() > 0 Тогда
        Для каждого Стр Из ОтобранныеСтроки Цикл
          Стр.Значение = РеквизитыДокумента25.НеПоГрафику;
        КонецЦикла;
      Иначе
        Стр = ФормаСозданияДокумента.Объект.ДополнительныеРеквизиты.Добавить();
        Стр.Свойство = РеквизитыДокумента25.НеПоГрафикуСвойство;
        Стр.Значение = РеквизитыДокумента25.НеПоГрафику;
      КонецЕсли;
    КонецЕсли;
  ...
  КонецЕсли;

то при открытии этой формы дополнительный реквизит не будет заполнен.

При изучении состава формы в отладчике находим таинственный реквизит формы ДополнительныйРеквизитЗначение_2C506AEDx453Ax11E8x8130x0050569C309C_03D89E6Fx64A2x11E8xBDFBx0022642B037A.

Начинаем копать код ПриСозданииНаСервере формы и узнаем, что в этот момент, при серверном создании формы, такие синтетические имена и образуются. Есть такая серверная процедура общего модуля УправлениеСвойствами.ЗаполнитьДополнительныеРеквизитыВФорме(УправляемаяФорма) для этих целей.

Но повторно в нее не залезешь, форма уже получена :-( С клиента на сервер уже управляемую форму не передашь.

Остается переписать ее в свою процедуру (ФормаОбъект - Объект формы передаем по значению, чтобы не выдавались ругательные сообщения о попытке поменять этот Объект):

&НаСервере
Функция ПолучитьСписокДопРеквизитовДляФормы(Знач ФормаОбъект, Свойства_НаборыДополнительныхРеквизитовОбъекта) //из УправлениеСвойствами.ЗаполнитьДополнительныеРеквизитыВФорме(УправляемаяФорма)
	
  СписокДопРеквизитов = Новый СписокЗначений;
  ТаблицаДопРеквизитов = ФормаОбъект.ДополнительныеРеквизиты.Выгрузить();
	
  ОписаниеСвойств = УправлениеСвойствамиСлужебный.ЗначенияСвойств(
		ТаблицаДопРеквизитов,
		Свойства_НаборыДополнительныхРеквизитовОбъекта,
		Ложь);
		
  Для каждого ОписаниеСвойства Из ОписаниеСвойств Цикл
		
    СтруктураДопРеквизитов = Новый Структура;
		
    ИмяУникальнаяЧасть = СтрЗаменить(ВРег(Строка(ОписаниеСвойства.Набор.УникальныйИдентификатор())), "-", "x") + "_" + СтрЗаменить(ВРег(Строка(ОписаниеСвойства.Свойство.УникальныйИдентификатор())), "-", "x");
		
    СтруктураДопРеквизитов.Вставить("ДопРеквизитНаименование", ОписаниеСвойства.Наименование);
    СтруктураДопРеквизитов.Вставить("ДопРеквизитИмяВФорме", "ДополнительныйРеквизитЗначение_" + ИмяУникальнаяЧасть);
    СтруктураДопРеквизитов.Вставить("ДопРеквизитЗначение", ОписаниеСвойства.Значение);
		
    СписокДопРеквизитов.Добавить(СтруктураДопРеквизитов, ОписаниеСвойства.Наименование);
		
  КонецЦикла;
	
  Возврат СписокДопРеквизитов;

КонецФункции

Попутно узнаем о еще одном интересном реквизите формы - Свойства_НаборыДополнительныхРеквизитовОбъекта.
И организовываем, например, такой вызов нашей новой процедуры:

&НаКлиенте
Процедура ЗагрузитьДокумент25(Команда = Неопределено)
  ...
  ФормаСозданияДокумента = ПолучитьФорму("Документ." + ТекДокумент.ТипДокумента + ".Форма.ФормаДокумента", ПараметрыСозданияНовогоДокумента, ЭтотОбъект);
  ...
  РеквизитыДокумента25 = ПолучитьРеквизитыОтпуск25(ТекДокумент.ТипДокументаТам, ТекДокумент.УИД);
  ...

  Если РеквизитыДокумента25 <> Неопределено Тогда
    ...
    //СписокДопРеквизитов - состав: в значении: СтруктураДопРеквизитов, в представлении: имя доп.свойства как в Предприятии
    //СтруктураДопРеквизитов: 
    //ДопРеквизитНаименование - имя доп.свойства как в Предприятии
    //ДопРеквизитИмяВФорме - имя на форме, типа ДополнительныйРеквизитЗначение_2C506AEDx453Ax11E8x8130x0050569C309C_03D89E6Fx64A2x11E8xBDFBx0022642B037A
    //ДопРеквизитЗначение - Булево значение
			
    Свойства_НаборыДополнительныхРеквизитовОбъекта = ФормаСозданияДокумента.Свойства_НаборыДополнительныхРеквизитовОбъекта;
    СписокДопРеквизитов = ПолучитьСписокДопРеквизитовДляФормы(ФормаСозданияДокумента.Объект, Свойства_НаборыДополнительныхРеквизитовОбъекта);
				
    Для каждого СтрДопРекв Из СписокДопРеквизитов Цикл
      СтруктураДопРеквизитов = СтрДопРекв.Значение;
      Если СтрДопРекв.Представление = "Не по графику" Тогда
        ФормаСозданияДокумента[СтруктураДопРеквизитов.ДопРеквизитИмяВФорме] = СтруктураДопРеквизитов.ДопРеквизитЗначение; //РеквизитыДокумента25.НеПоГрафику;
      КонецЕсли; 
    КонецЦикла;
    ...
  КонецЕсли; 

 

И для полноты статьи, текст используемой типовой функции ЗначенияСвойств() общего модуля УправлениеСвойствамиСлужебный (галочки "сервер","внешнее соединение"; галочки "вызов сервера" нет, поэтому ее вызвать с клиента нельзя):

 

// Возвращает заполненную таблицу значений свойств объекта.
Функция ЗначенияСвойств(ДополнительныеСвойстваОбъекта, Наборы, ЭтоДополнительноеСведение) Экспорт
	
	Если ДополнительныеСвойстваОбъекта.Количество() = 0 Тогда
		// Предварительная быстрая проверка использования дополнительных свойств.
		СвойстваНеНайдены = ДополнительныеРеквизитыИСведенияНеНайдены(Наборы, ЭтоДополнительноеСведение);
		
		Если СвойстваНеНайдены Тогда
			ОписаниеСвойств = Новый ТаблицаЗначений;
			ОписаниеСвойств.Колонки.Добавить("Набор");
			ОписаниеСвойств.Колонки.Добавить("Свойство");
			ОписаниеСвойств.Колонки.Добавить("ВладелецДополнительныхЗначений");
			ОписаниеСвойств.Колонки.Добавить("ЗаполнятьОбязательно");
			ОписаниеСвойств.Колонки.Добавить("Наименование");
			ОписаниеСвойств.Колонки.Добавить("ТипЗначения");
			ОписаниеСвойств.Колонки.Добавить("ФорматСвойства");
			ОписаниеСвойств.Колонки.Добавить("МногострочноеПолеВвода");
			ОписаниеСвойств.Колонки.Добавить("Удалено");
			ОписаниеСвойств.Колонки.Добавить("Значение");
			Возврат ОписаниеСвойств;
		КонецЕсли;
	КонецЕсли;
	
	Свойства = ДополнительныеСвойстваОбъекта.ВыгрузитьКолонку("Свойство");
	
	НаборыСвойств = Новый ТаблицаЗначений;
	
	НаборыСвойств.Колонки.Добавить(
		"Набор", Новый ОписаниеТипов("СправочникСсылка.НаборыДополнительныхРеквизитовИСведений"));
	
	НаборыСвойств.Колонки.Добавить(
		"ПорядокНабора", Новый ОписаниеТипов("Число"));
	
	Для каждого ЭлементСписка Из Наборы Цикл
		НоваяСтрока = НаборыСвойств.Добавить();
		НоваяСтрока.Набор         = ЭлементСписка.Значение;
		НоваяСтрока.ПорядокНабора = Наборы.Индекс(ЭлементСписка);
	КонецЦикла;
	
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("Свойства",      Свойства);
	Запрос.УстановитьПараметр("НаборыСвойств", НаборыСвойств);
	Запрос.Текст =
	"ВЫБРАТЬ
	|	НаборыСвойств.Набор,
	|	НаборыСвойств.ПорядокНабора
	|ПОМЕСТИТЬ НаборыСвойств
	|ИЗ
	|	&НаборыСвойств КАК НаборыСвойств
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	НаборыСвойств.Набор,
	|	НаборыСвойств.ПорядокНабора,
	|	СвойстваНаборов.Свойство,
	|	СвойстваНаборов.ПометкаУдаления,
	|	СвойстваНаборов.НомерСтроки КАК ПорядокСвойства
	|ПОМЕСТИТЬ СвойстваНаборов
	|ИЗ
	|	НаборыСвойств КАК НаборыСвойств
	|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.НаборыДополнительныхРеквизитовИСведений.ДополнительныеРеквизиты КАК СвойстваНаборов
	|		ПО (СвойстваНаборов.Ссылка = НаборыСвойств.Набор)
	|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения КАК Свойства
	|		ПО (СвойстваНаборов.Свойство = Свойства.Ссылка)
	|ГДЕ
	|	НЕ СвойстваНаборов.ПометкаУдаления
	|	И НЕ Свойства.ПометкаУдаления
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	Свойства.Ссылка КАК Свойство
	|ПОМЕСТИТЬ ЗаполненныеСвойства
	|ИЗ
	|	ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения КАК Свойства
	|ГДЕ
	|	Свойства.Ссылка В(&Свойства)
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	СвойстваНаборов.Набор,
	|	СвойстваНаборов.ПорядокНабора,
	|	СвойстваНаборов.Свойство,
	|	СвойстваНаборов.ПорядокСвойства,
	|	СвойстваНаборов.ПометкаУдаления КАК Удалено
	|ПОМЕСТИТЬ ВсеСвойства
	|ИЗ
	|	СвойстваНаборов КАК СвойстваНаборов
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	ЗНАЧЕНИЕ(Справочник.НаборыДополнительныхРеквизитовИСведений.ПустаяСсылка),
	|	0,
	|	ЗаполненныеСвойства.Свойство,
	|	0,
	|	ИСТИНА
	|ИЗ
	|	ЗаполненныеСвойства КАК ЗаполненныеСвойства
	|		ЛЕВОЕ СОЕДИНЕНИЕ СвойстваНаборов КАК СвойстваНаборов
	|		ПО ЗаполненныеСвойства.Свойство = СвойстваНаборов.Свойство
	|ГДЕ
	|	СвойстваНаборов.Свойство ЕСТЬ NULL 
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	ВсеСвойства.Набор,
	|	ВсеСвойства.Свойство,
	|	ДополнительныеРеквизитыИСведения.ВладелецДополнительныхЗначений,
	|	ДополнительныеРеквизитыИСведения.ЗаполнятьОбязательно,
	|	ДополнительныеРеквизитыИСведения.Заголовок КАК Наименование,
	|	ДополнительныеРеквизитыИСведения.ТипЗначения,
	|	ДополнительныеРеквизитыИСведения.ФорматСвойства,
	|	ДополнительныеРеквизитыИСведения.МногострочноеПолеВвода,
	|	ВсеСвойства.Удалено КАК Удалено,
	|	ДополнительныеРеквизитыИСведения.Доступен,
	|	ДополнительныеРеквизитыИСведения.Виден,
	|	ДополнительныеРеквизитыИСведения.Подсказка,
	|	ДополнительныеРеквизитыИСведения.ВыводитьВВидеГиперссылки,
	|	ДополнительныеРеквизитыИСведения.ЗависимостиДополнительныхРеквизитов.(
	|		ЗависимоеСвойство,
	|		Реквизит,
	|		Условие,
	|		Значение
	|	)
	|ИЗ
	|	ВсеСвойства КАК ВсеСвойства
	|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения КАК ДополнительныеРеквизитыИСведения
	|		ПО ВсеСвойства.Свойство = ДополнительныеРеквизитыИСведения.Ссылка
	|
	|УПОРЯДОЧИТЬ ПО
	|	Удалено,
	|	ВсеСвойства.ПорядокНабора,
	|	ВсеСвойства.ПорядокСвойства";
	
	Если ЭтоДополнительноеСведение Тогда
		Запрос.Текст = СтрЗаменить(
			Запрос.Текст,
			"Справочник.НаборыДополнительныхРеквизитовИСведений.ДополнительныеРеквизиты",
			"Справочник.НаборыДополнительныхРеквизитовИСведений.ДополнительныеСведения");
	КонецЕсли;
	
	ОписаниеСвойств = Запрос.Выполнить().Выгрузить();
	ОписаниеСвойств.Индексы.Добавить("Свойство");
	ОписаниеСвойств.Колонки.Добавить("Значение");
	
	// Удаление дублей свойств в нижестоящих наборах свойств.
	Если Наборы.Количество() > 1 Тогда
		Индекс = ОписаниеСвойств.Количество()-1;
		
		Пока Индекс >= 0 Цикл
			Строка = ОписаниеСвойств[Индекс];
			НайденнаяСтрока = ОписаниеСвойств.Найти(Строка.Свойство, "Свойство");
			
			Если НайденнаяСтрока <> Неопределено
			   И НайденнаяСтрока <> Строка Тогда
				
				ОписаниеСвойств.Удалить(Индекс);
			КонецЕсли;
			
			Индекс = Индекс-1;
		КонецЦикла;
	КонецЕсли;
	
	// Заполнение значений свойств.
	Для Каждого Строка Из ДополнительныеСвойстваОбъекта Цикл
		ОписаниеСвойства = ОписаниеСвойств.Найти(Строка.Свойство, "Свойство");
		Если ОписаниеСвойства <> Неопределено Тогда
			// Поддержка строк неограниченной длины.
			Если НЕ ЭтоДополнительноеСведение
				И (ИспользоватьНеограниченнуюСтроку(
						ОписаниеСвойства.ТипЗначения,
						ОписаниеСвойства.МногострочноеПолеВвода)
					Или ИспользоватьСтрокуВВидеСсылки(
						ОписаниеСвойства.ТипЗначения,
						ОписаниеСвойства.ВыводитьВВидеГиперссылки,
						ОписаниеСвойства.МногострочноеПолеВвода))
				И НЕ ПустаяСтрока(Строка.ТекстоваяСтрока) Тогда
				
				ОписаниеСвойства.Значение = Строка.ТекстоваяСтрока;
			Иначе
				ОписаниеСвойства.Значение = Строка.Значение;
			КонецЕсли;
		КонецЕсли;
	КонецЦикла;
	
	Возврат ОписаниеСвойств;
	
КонецФункции

 

19

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. ducks01 11.09.18 11:00 Сейчас в теме
(0) это работает примерно так:
ОписаниеОбъекта = Форма.Объект;

ОписаниеСвойств = УправлениеСвойствамиСлужебный.ЗначенияСвойств(
ОписаниеОбъекта.ДополнительныеРеквизиты.Выгрузить(),
Форма.Свойства_НаборыДополнительныхРеквизитовОбъекта,
Ложь,
ОписаниеОбъекта);  

Для каждого ОписаниеСвойства Из ОписаниеСвойств Цикл
	
	ИмяРеквизитаЗначение = "ДополнительныйРеквизитЗначение_" 
	+ СтрЗаменить(ВРег(Строка(ОписаниеСвойства.Набор.УникальныйИдентификатор())), "-", "x")
	+ "_"
	+ СтрЗаменить(ВРег(Строка(ОписаниеСвойства.Свойство.УникальныйИдентификатор())), "-", "x");
	
	Форма[ИмяРеквизитаЗначение] = "тут значение вам необходимое";		
					
КонецЦикла;
Показать
nekit_rdx; +1 Ответить
2. bugtester 298 11.09.18 13:20 Сейчас в теме
(1) Все хорошо, только не пойдет, когда вам нужно из одной формы (некоей обработки)
заполнить доп.реквизит в другой полученной форме (форме документа отпуска, не меняя модуль формы этого документа),
например, как здесь https://infostart.ru/public/901823/
Вы находитесь в форме документа, а я нахожусь в форме обработки,
и там в процедуре ЗагрузитьДокумент25() заполняю полученную форму документа Отпуск

И исполнение вашего кода на клиенте? Этот код весь отрабатывает на клиенте?
3. bugtester 298 12.09.18 04:41 Сейчас в теме
(1) Смотрите, что получается, если ваш код на клиенте (а он на клиенте, т.к. на сервере он может быть только, когда находится в модуле формы объекта и эта форма создается на сервере, иначе управляемую форму на сервер не получится передать):

Переменная не определена (УправлениеСвойствамиСлужебный)
ОписаниеСвойств = <<?>>УправлениеСвойствамиСлужебный.ЗначенияСвойств( (Проверка: Тонкий клиент)
4. ducks01 12.09.18 06:48 Сейчас в теме
(3) на клиенте, я делал это в расширении 1с. по вашей ошибке понятно что у вас нет этого Типового модуля, ищите аналог и используйте.
5. bugtester 298 12.09.18 07:12 Сейчас в теме
(4) Неверные у вас выводы. Этот общий модуль с процедурой есть в конфигурации, используется типовая ЗУП 3.1.
И в моей статье в частности тоже используется УправлениеСвойствамиСлужебный.ЗначенияСвойств()
(у общего модуля УправлениеСвойствамиСлужебный галочки "сервер", "внешнее соединение"),
только УправлениеСвойствамиСлужебный.ЗначенияСвойств() у меня вызывается из серверной процедуры модуля формы обработки. Код моей статьи работает.
С клиента модуля формы обработки процедура этого общего модуля не может вызываться, см. ошибку выше - ваш код не работает.
Ваш код почти по пути получения данных для заполнения и есть мой, только мой с разбивкой что может делаться на сервере, что на клиенте.
И реквизит формы заполняется не тут же, а при возврате на клиент.
Данные, полученные на сервере, заворачиваются в список значений, где строки структуры (по сути все вместе это таблица значений, только ее в параметрах нельзя было передать обратно) и передаются на клиент для заполнения формы.
8. ducks01 12.09.18 07:43 Сейчас в теме
(5) вы спросили откуда берется "нечто вида" я вам ответил, использовал из типового метода. Рабочий код для вашего случая я вам не гарантировал. раз вы его тоже использовали то зачем вопросы задаете.
11. bugtester 298 12.09.18 08:27 Сейчас в теме
(8) Рука-лицо. А то что этот вопрос был в анонсе статьи, как затравка для дальнейшего раскрытия, вас не смутило?)
13. ducks01 12.09.18 08:53 Сейчас в теме
(11) не заметил, на форуме они идут в одном списке только иконки отличаются. Можете очистить ветку если такая возможность есть. А я не пойму что это вы так агрессивно доказываете ) удачи вам!
14. bugtester 298 12.09.18 08:58 Сейчас в теме
12. bugtester 298 12.09.18 08:41 Сейчас в теме
(8) Проблема, решаемая в статье (помимо попутного рассказа что и где заполнять у доп.реквизитов на форме), как раз в том, что управляемую форму, причем полученную программно в другом месте, не передашь на сервер в готовую типовую процедуру.
Это пример рабочего кода, как процедуру УправлениеСвойствами.ЗаполнитьДополнительныеРеквизитыВФорме(УправляемаяФорма) можно модифицировать, если передавать в параметры не форму, а объект формы.

PS У Павла Чистова есть хороший текст про существование формы на клиенте и на сервере http://goo.gl/oMYBcM
6. bugtester 298 12.09.18 07:14 Сейчас в теме
(4) в каком месте расширения 1С вы использовали этот код?
9. ducks01 12.09.18 07:44 Сейчас в теме
(6) ввел в заблуждение, использовал в новом серверном общем модуле
10. bugtester 298 12.09.18 08:21 Сейчас в теме
(9) А форма как попадает в процедуру на серверном общем модуле?
Из ПриСозданииНаСервере же в модуле той формы?

В том то и проблема была, что нельзя для готовой типовой процедуры на серверном общем модуле передать управляемую форму как параметр, если она была получена где-то программно. В статье написано, как сделать то же самое по сути, что и в типовой конфигурации, но через передачу Объекта формы в качестве параметра.

у Павла Чистова есть хороший текст про существование формы на сервере и на клиенте http://goo.gl/oMYBcM
7. bugtester 298 12.09.18 07:34 Сейчас в теме
(4) у серверного общего модуля УправлениеСвойствамиСлужебный нет галочки "вызов сервера",
поэтому очень интересно как у вас эта процедура с клиента вызывается

https://infostart.ru/public/86838/

со стороны клиента можно вызывать

1) клиентские процедуры данного модуля, с директивой &НаКлиенте;
2) серверные процедуры данного модуля, с директивой &НаСервере;
3) клиентские процедуры общего модуля, с директивой &НаКлиенте(при условии наличия в свойствах доступности в нескольких контекстах, «Клиент» обязателен и др.);
4) все процедуры клиентского общего модуля , в свойствах общего модуля должно быть только свойство «Клиент(управляемое приложение)». Директиву &НаКлиенте в общем модуле в этом случае не пишут;
5) процедуры серверного общего модуля, но с дополнительным свойством «Вызов сервера», причем важно чтобы общий модуль имел только свойство компиляции на сервере.
Оставьте свое сообщение

См. также

Агрегатные функции СКД, о которых мало кто знает 318

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    10028    ids79    42       

Три костыля. Сказ про фокусы в коде 122

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    7799    YPermitin    68       

Отслеживание выполнения фонового задания 133

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    8285    ids79    14       

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 242

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    10406    ids79    24       

Фоновое выполнение кода в 1С - это просто 117

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    9826    avalakh    21       

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты 126

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    9313    ids79    6       

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 135

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования Разработка

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    8727    ids79    24       

"Меньше копипаста!", или как Вася универсальную процедуру писал 170

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    6228    SeiOkami    48       

Создание отчетов с помощью СКД - основные понятия и элементы 192

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    17446    ids79    16       

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 176

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    11539    dmurk    134       

Регистры накопления. Структура хранения в базе данных 174

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    17245    YPermitin    27       

Выполнение внешней обработки в фоновом задании 147

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    9852    Eret1k    22       

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    4833    m-rv    2       

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    7369    m-rv    16       

О расширениях замолвите слово... 191

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    16350    ellavs    122       

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 200

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    12735    ellavs    83       

Трюки с внешними источниками данных 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    12828    YPermitin    52       

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS) 163

Статья Программист Нет файла v8 v8::Права Бесплатно (free) Практика программирования БСП (Библиотека стандартных подсистем) Роли и права

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    15472    ids79    9       

EnterpriseData – часть 2. Процесс выгрузки данных 127

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Основные этапы выгрузки данных через ED, обработчики событий выгрузки, правила обработки данных, правила конвертации объектов, конвертация свойств первого и второго этапов, процедуры БСП, используемые при выгрузке данных, структура «КомпонентыОбмена».

26.12.2018    12708    ids79    27       

Новый подход к обмену данными EnterpriseData 203

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    21421    ids79    72       

EnterpriseData - пример доработки правил конвертации без использования КД 3.0 в расширении конфигурации 118

Статья Программист Нет файла v8 v8::УФ БП3.0 УТ11 Россия Windows Бесплатно (free) Практика программирования Обмен через XML

В статье подробно описан реальный пример доработки обмена данными через EnterpriseData (универсальный формат обмена) между конфигурациями УТ 11.4 и Бухгалтерия 3.0

16.11.2018    18896    ids79    20       

Программное заполнение пользовательских параметров и отборов СКД 135

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Публикация представляет из себя краткие примеры того, как можно заполнять параметры СКД программно так, чтобы все параметры и отборы были доступны в быстрых настройках и в обычных (типовых) настройках параметров и отборов СКД.

13.11.2018    19634    Unk92    18       

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С 126

Статья Программист Нет файла v8 v8::blocking 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    20850    ids79    40       

Вспомогательные инструкции в коде 1С 104

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    20454    tormozit    100       

Дозагрузка кадровых документов в ЗУП 3.1 из ЗУП 2.5 в интерактивном режиме (загрузка в документы списком) 14

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::СПР ЗУП3.x Россия БУ Управление персоналом (HRM) Абонемент ($m) Перенос данных из 1C8 в 1C8

При переходе с ЗУП 2.5 на ЗУП 3.1, иногда по тем или иным причинам требуется ручной перенос кадровых документов за период. Это помощник ручного создания кадровых документов в ЗУП 3.1, который пытается по максимуму заполнить открываемую форму данными из ЗУП 2.5 (через COM-соединение), попутно создает сотрудников и физлиц, если их нет. Основано на публикации rilmir https://infostart.ru/public/793479/ , которое было местами переписано заново, почищено, отлажено, и все равно там еще есть что переделать и оптимизировать, и которое в свою очередь было когда то чьим-то еще творением, видимо для более глобальных целей.

1 стартмани

11.09.2018    6525    126    bugtester    14       

Произвольный код в фоновом режиме 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Задача: реализовать выполнение произвольного кода в фоновом режиме без изменения конфигурации, т.е. во внешней обработке.

03.09.2018    14583    nikita0832    41       

Основные понятия и механизмы оптимизации клиент-серверного взаимодействия в 1C 144

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы Практика программирования

У многих начинающих 1С программистов часто возникают вопросы про клиент-серверное взаимодействие в 1С и чтобы разобраться в непростых механизмах платформы, необходимо понять, что же такое контекст, для чего предназначены директивы компиляции, что представляют собой контекстные/внеконтекстные вызовы и как наиболее оптимально описывать прикладные задачи в модулях управляемых форм.

23.08.2018    21259    Rain88    42       

Повышаем эффективность разработки правил обмена 123

Статья Программист Нет файла v8 КД ОС Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8

Как повысить скорость и качество разработки правил обмена? Как вести групповую разработку правил обмена? Как облегчить сопровождение правил обмена после передачи в эксплуатацию? Об этом и многом другом вы можете узнать из этой статьи.

25.06.2018    19312    olegtymko    47       

Введение в механизм представлений в ЗУП ред. 3 153

Статья Программист Нет файла v8 v8::СПР ЗУП3.x Бесплатно (free) Практика программирования

В нашей организации на первом же телефонном собеседовании на должность разработчика по ЗУП ред. 3 вас обязательно спросят о том, что такое "Представления".

04.06.2018    24376    xrrg    82       

Как сделать запрос на изменение данных 75

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    21186    m-rv    21       

Строим графы средствами 1С (без GraphViz) 42

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Множество статей на Инфостарте описывают, как работать с компонентой GraphViz, чтобы построить ориентированный граф. Но практически нет материалов, как работать с такими графами средствами 1С. Сегодня я расскажу, как красиво строить графы с минимальным пересечением. Нам этот метод пригодился для отрисовки алгоритмов в БИТ.Финансе, т.к. типовой механизм не устраивал. Еще это может быть полезно для визуализации различных зависимостей: расчета себестоимости, графы аффилированности компаний и т.д. Надеюсь, эта статья поможет сделать мир 1С красивее и гармоничней:) Итак, поехали...

23.05.2018    16960    slozhenikin_com    19       

Распределение расходов пропорционально продажам 9

Статья Программист Пользователь Нет файла v8 v8::ОУ УТ10 УУ Финансовый учет и бюджетирование (FRP) Учет доходов и расходов Бесплатно (free) Практика программирования

Финансовая модель. Распределение административных расходов по подразделениям пропорционально продажам за месяц. Дополнительные реквизиты против бизнес-процессов!

13.05.2018    11342    Rustig    9       

Просмотр временных таблиц запроса в отладчике без изменения кода 126

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

Данный способ можно использовать для просмотра содержимого временных таблиц запросов (менеджеров временных таблиц) без внесения изменений в код.

24.04.2018    24359    avfed@rambler.ru    19       

Минимализмы 3 351

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    35568    ildarovich    44       

Этюды по программированию. Взаимодействие с Microsoft Word 109

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Часто приходится заниматься созданием сложных документов Word с таблицами, вложенными фрагментами, хитрым оформлением и прочими радостями жизни. Это - попытка как-то структурировать полученный опыт, чтобы не приходилось перерывать ворох старых обработок в поисках крупиц истины. Надеюсь, эта статья будет полезна и Вам.

11.12.2017    25844    milkers    23       

Метод формирования движений в типовых регистрах нетиповыми регистраторами 31

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    21317    itriot11    34       

1С: Конвертация данных 3. Инструкции и примеры. EnterpriseData (универсальный формат обмена) 720

Статья Программист Нет файла v8 КД Бесплатно (free) Перенос данных из 1C8 в 1C8 Практика программирования Обмен через XML

Что такое КД3? Как начать использовать? Полезные дополнения к документации. Что нужно исправить в типовых обработках и конфигурации. Как изменить правила обмена не снимая конфигурацию с поддержки. Как отлаживать правила обмена?

19.11.2017    137562    MaxS    251       

Заполнение данных по ИНН контрагента с помощью альтернативного сервиса огрн.онлайн 131

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Код для заполнения данных по ИНН контрагента из ЕГРЮЛ с сайта огрн.онлайн.

01.11.2017    22684    slava_1c    49       

Программные перечисления, ч.2: приемы кэширования при разработке 66

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Все знают, что такое кэш, и зачем он нужен. Но в 1С разработчик обычно использует кэширование только на уровне конфигурации, а в какой-нибудь обработке скорее ломает голову над запросом - как получить все данные за один заход... Хочется рассказать о том, как можно добиться хороших результатов с стратегией "разделяй и властвуй".

30.10.2017    21068    unichkin    17       

Разбираемся с настройками компоновки данных 159

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Краткая шпаргалка по программной работе с настройками СКД

29.10.2017    24033    json    9       

Работа с Excel 289

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Загрузка и выгрузка в Excel

Собрал различные полезности для работы с Excel из 1С. Иногда приходится форматировать документ Excel программно из 1С. Так вот, чтобы не искать постоянно на просторах интернета как сделать левое выравнивание в ячейке Excel из 1С и т.п. решил опубликовать это...

23.10.2017    24705    arakelyan    39       

Добавление команд печати в конфигурациях на БСП 2.4.3 (в частности, в самописных документах в Бухгалтерии 3.0 после релиза 3.0.52.35) 143

Статья Программист Нет файла v8 v8::БУ БП3.0 Россия Бесплатно (free) Печатные формы документов Практика программирования БСП (Библиотека стандартных подсистем)

В статье https://infostart.ru/public/237013/ пользователя nick max рассматривался список действий для подключения команд печати в Бухгалтерии 3.0, работающей на БСП 2.3.6. В новом релизе Бухгалтерии 3.0.52.35 от 15.09.2017г. стала использоваться БСП 2.4.3, из-за чего произошли изменения в процедурах общих модулей, связанных с механизмом печати, и в процедурах их вызова в формах документов и в формах списков. Рассмотрим их.

18.09.2017    46768    bugtester    43