Простой отчет позволяет быстро сверить взаиморасчеты межу организациями холдинга.
Суммы - остатки на всех счетах с субконто "Контрагенты", "Договоры".
Тестировался на Управление производственным предприятием, редакция 1.3 (1.3.101.2)
26.03.2018: исправлена ошибка, при наложении отборов не определялась сумма по данным контрагента.
Параметры из схемы компоновки:
- Период - тип: Дата - выражение: ДобавитьКДате(КонецПериода(&Период,"День"),"Секунда",1)
- ВидСубконто - тип: ПланВидовХарактеристикСсылка.ВидыСубконтоХозрасчетные - Значение: Контрагенты, Договоры.
Запрос из схемы компоновки:
ВЫБРАТЬ РАЗРЕШЕННЫЕ
ХозрасчетныйОстатки.Организация КАК Организация,
ХозрасчетныйОстатки.Субконто1 КАК Контрагент,
ХозрасчетныйОстатки.СуммаОстаток КАК СуммаПоДаннымОрганизации
ПОМЕСТИТЬ ВТ_Взаиморасчеты
ИЗ
РегистрБухгалтерии.Хозрасчетный.Остатки(
&Период,
,
&ВидСубконто,
Субконто1 В
(ВЫБРАТЬ РАЗЛИЧНЫЕ
РегистрСведений.СобственныеКонтрагенты.Контрагент
ИЗ
РегистрСведений.СобственныеКонтрагенты) {(Организация).* КАК Организация, (Субконто1).* КАК Контрагент}) КАК ХозрасчетныйОстатки
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
ВТ_Взаиморасчеты.Организация,
ВТ_Взаиморасчеты.Контрагент,
ВТ_Взаиморасчеты.СуммаПоДаннымОрганизации,
СобственныеКонтрагенты.Объект КАК ОрганизацияКонтрагента,
СобственныеКонтрагенты1.Контрагент КАК КонтрагентОрганизации
ПОМЕСТИТЬ ВТ_ВзаиморасчетыДополн
ИЗ
ВТ_Взаиморасчеты КАК ВТ_Взаиморасчеты
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СобственныеКонтрагенты КАК СобственныеКонтрагенты
ПО ВТ_Взаиморасчеты.Контрагент = СобственныеКонтрагенты.Контрагент
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СобственныеКонтрагенты КАК СобственныеКонтрагенты1
ПО ВТ_Взаиморасчеты.Организация = СобственныеКонтрагенты1.Объект
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
ВТ_ВзаиморасчетыДополн.Организация КАК Организация,
ВТ_ВзаиморасчетыДополн.Контрагент КАК Контрагент,
ВТ_ВзаиморасчетыДополн.СуммаПоДаннымОрганизации КАК СуммаПоДаннымОрганизации,
ЕСТЬNULL(ХозрасчетныйОстатки.СуммаОстаток, 0) КАК СуммаПоДаннымКонтрагента,
ВТ_ВзаиморасчетыДополн.СуммаПоДаннымОрганизации + ЕСТЬNULL(ХозрасчетныйОстатки.СуммаОстаток, 0) КАК Разница
{ВЫБРАТЬ
Организация.*,
Контрагент.*,
СуммаПоДаннымОрганизации,
СуммаПоДаннымКонтрагента,
Разница}
ИЗ
ВТ_ВзаиморасчетыДополн КАК ВТ_ВзаиморасчетыДополн
ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Остатки(
&Период,
,
&ВидСубконто,
(Организация, Субконто1) В
(ВЫБРАТЬ РАЗЛИЧНЫЕ
ВТ_ВзаиморасчетыДополн.ОрганизацияКонтрагента,
ВТ_ВзаиморасчетыДополн.КонтрагентОрганизации
ИЗ
ВТ_ВзаиморасчетыДополн КАК ВТ_ВзаиморасчетыДополн)) КАК ХозрасчетныйОстатки
ПО ВТ_ВзаиморасчетыДополн.ОрганизацияКонтрагента = ХозрасчетныйОстатки.Организация
И ВТ_ВзаиморасчетыДополн.КонтрагентОрганизации = ХозрасчетныйОстатки.Субконто1
{ГДЕ
ВТ_ВзаиморасчетыДополн.СуммаПоДаннымОрганизации,
(ЕСТЬNULL(ХозрасчетныйОстатки.СуммаОстаток, 0)) КАК СуммаПоДаннымКонтрагента,
(ВТ_ВзаиморасчетыДополн.СуммаПоДаннымОрганизации + ЕСТЬNULL(ХозрасчетныйОстатки.СуммаОстаток, 0)) КАК Разница}
