На момент сдачи отчетности, начиная с релиза 3.1.8.216 были выявлены ошибки заполнения отчета СЗВ-СТАЖ.
1. Не всегда корректно рассчитываются периоды стажа.
Например у сотрудника разъездной характер работы. Сотрудник постоянно находится в командировках. На первом скриншоте видно, как у сотрудника при расчете из стажа выпали 7 месяцев, при том, что сотрудник постоянно работал и никаких явных причин прерывания отпуска не было. Анализ документов также не дал никакого результата.
2. При расчете появляется данные ДЛОТПУСК отдельно - ДЛОТПУСК должен входит в общий стаж.
Причиной неверного расчета являются ошибки в запросах формирующих периоды стажа.
Для верного расчета необходимо:
1. Поправить процедуру СоздатьВТДанныеУчетаСтажаПФР() в общем модуле УчетСтажаПФР. Измененный блок в запросе выделен комментарием "Исправление ошибки СЗВ-СТАЖ"
Процедура СоздатьВТДанныеУчетаСтажаПФР(МенеджерВременныхТаблиц, ПараметрыОтбора, ИмяВТРезультат = "ВТДанныеУчетаСтажаПФР") Экспорт
Если ПараметрыОтбора.НачалоПериода = Неопределено Тогда
НачалоПериода = '20100101';
Иначе
НачалоПериода = ПараметрыОтбора.НачалоПериода;
КонецЕсли;
Если ПараметрыОтбора.ОкончаниеПериода = Неопределено Тогда
ДатаСеанса = ТекущаяДатаСеанса();
ТекущийПериод = ?(ДатаСеанса >= '20170101', НачалоГода(ДатаСеанса), НачалоКвартала(ДатаСеанса));
ОкончаниеПериода = ПерсонифицированныйУчетКлиентСервер.ПредшествующийОтчетныйПериодСтажаПерсУчета(ТекущийПериод);
Иначе
ОкончаниеПериода = ПараметрыОтбора.ОкончаниеПериода;
КонецЕсли;
Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
СоздатьВТСоответствиеВидовСтажаПараметрамИсчисления2013(Запрос.МенеджерВременныхТаблиц);
СоздатьВТСоответствиеВидовСтажаПараметрамИсчисления2014(Запрос.МенеджерВременныхТаблиц);
СоздатьВТОтчетныеПериоды(Запрос.МенеджерВременныхТаблиц, НачалоПериода, ОкончаниеПериода);
ПерсонифицированныйУчет.СоздатьВТЗамещениеГосударственныхДолжностей(Запрос.МенеджерВременныхТаблиц);
ЗарплатаКадрыОбщиеНаборыДанных.СоздатьВТПериоды(
Запрос.МенеджерВременныхТаблиц,
НачалоПериода,
ОкончаниеПериода,
"МЕСЯЦ");
Запрос.УстановитьПараметр("Организация", ПараметрыОтбора.Организация);
Запрос.УстановитьПараметр("НачалоПериода", НачалоПериода);
Запрос.УстановитьПараметр("ОкончаниеПериода", НачалоДня(ОкончаниеПериода));
Запрос.УстановитьПараметр("ПараметрыСтажаСПравомНаДосрочнуюПенсию2014", ПараметрыИсчисляемогоСтажаПредусматривающиеПравоНаДосрочнуюПенсию2014());
Запрос.УстановитьПараметр("ПараметрыСтажаСПравомНаДосрочнуюПенсию2013", ПараметрыИсчисляемогоСтажаПредусматривающиеПравоНаДосрочнуюПенсию2013());
Запрос.УстановитьПараметр("ИсключаемыеТерриториальныеУсловия", ПерсонифицированныйУчет.ИсключаемыеТерриториальныеУсловияПФР());
Запрос.Текст =
"ВЫБРАТЬ
| ПериодыСтажаПФР.ГоловнаяОрганизация КАК ГоловнаяОрганизация,
| ПериодыСтажаПФР.ФизическоеЛицо КАК ФизическоеЛицо,
| ПериодыСтажаПФР.ТипДоговора КАК ТипДоговора,
| ОтчетныеПериоды.ОтчетныйПериод КАК ОтчетныйПериод,
| ВЫБОР
| КОГДА ПериодыСтажаПФР.Начало < ОтчетныеПериоды.ОтчетныйПериод
| ТОГДА ОтчетныеПериоды.ОтчетныйПериод
| ИНАЧЕ ПериодыСтажаПФР.Начало
| КОНЕЦ КАК Начало,
| ВЫБОР
| КОГДА ПериодыСтажаПФР.Окончание = ДАТАВРЕМЯ(1, 1, 1)
| ИЛИ ПериодыСтажаПФР.Окончание > ОтчетныеПериоды.ОкончаниеПериода
| ТОГДА ОтчетныеПериоды.ОкончаниеПериода
| ИНАЧЕ ПериодыСтажаПФР.Окончание
| КОНЕЦ КАК Окончание,
| ПериодыСтажаПФР.ВидСтажаПФР КАК ВидСтажаПФР,
| ПериодыСтажаПФР.Организация КАК Организация,
| ВЫБОР
| КОГДА ОтчетныеПериоды.ИспользоватьПараметрыСтажа2014
| И ПериодыСтажаПФР.ТипДоговора = ЗНАЧЕНИЕ(Перечисление.ТипыДоговоровСЗВ63.ГражданскоПравовой)
| ТОГДА ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ДОГОВОР)
| КОГДА ОтчетныеПериоды.ИспользоватьПараметрыСтажа2014
| ТОГДА СоответствиеВидовСтажаПараметрамИсчисления2014.ПараметрИсчисляемогоСтажа
| ИНАЧЕ СоответствиеВидовСтажаПараметрамИсчисления2013.ПараметрИсчисляемогоСтажа
| КОНЕЦ КАК ТретийПараметрИсчисляемогоСтажа,
| ВЫБОР
| КОГДА ОтчетныеПериоды.ИспользоватьПараметрыСтажа2014
| И СоответствиеВидовСтажаПараметрамИсчисления2014.ПараметрИсчисляемогоСтажа В (&ПараметрыСтажаСПравомНаДосрочнуюПенсию2014)
| И ПериодыСтажаПФР.ВидСтажаПФР <> ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ВключаетсяВСтраховойСтаж)
| ТОГДА ИСТИНА
| КОГДА ОтчетныеПериоды.ИспользоватьПараметрыСтажа2013
| И СоответствиеВидовСтажаПараметрамИсчисления2013.ПараметрИсчисляемогоСтажа В (&ПараметрыСтажаСПравомНаДосрочнуюПенсию2013)
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК ЕстьПравоНаЛьготныйСтаж,
| ЕСТЬNULL(ЗамещениеГосударственныхДолжностей.ЗамещениеГосударственныхМуниципальныхДолжностей, ЗНАЧЕНИЕ(Справочник.ЗамещениеГосударственныхМуниципальныхДолжностейПФР.ПустаяСсылка)) КАК ЗамещениеГосударственныхМуниципальныхДолжностей,
| NULL КАК СтруктурнаяЕдиница,
| NULL КАК Должность,
| NULL КАК КоличествоСтавок,
| NULL КАК НеполныйРабочийДень,
| NULL КАК ОснованиеДосрочногоНазначенияПенсии,
| NULL КАК КодПозицииСписка,
| NULL КАК ТерриториальныеУсловия,
| NULL КАК ТерриториальныеУсловияДополнительные,
| NULL КАК ОсобыеУсловияТруда,
| NULL КАК ВладелецДопТерриторий,
| NULL КАК ЗарегистрированоЗначениеТерриториальныеУсловия,
| NULL КАК ЗарегистрированоЗначениеОснованиеВыслугиЛет,
| NULL КАК ЗарегистрированоЗначениеОсобыеУсловияТруда,
| NULL КАК ЗарегистрированоЗначениеТерриториальныеУсловияДополнительные
|ПОМЕСТИТЬ ВТИсходныеДанныеУчетаСтажа
|ИЗ
| РегистрСведений.ПериодыСтажаПФР КАК ПериодыСтажаПФР
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТФильтр КАК Фильтр
| ПО (&УсловияСвязиПоИзмерениям)
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТОтчетныеПериоды КАК ОтчетныеПериоды
| ПО ПериодыСтажаПФР.Начало <= ОтчетныеПериоды.ОкончаниеПериода
| И (ПериодыСтажаПФР.Окончание = ДАТАВРЕМЯ(1, 1, 1)
| ИЛИ ПериодыСтажаПФР.Окончание >= ОтчетныеПериоды.ОтчетныйПериод)
| И (ПериодыСтажаПФР.ВидСтажаПФР <> ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.НеВключаетсяВСтраховойСтаж))
| И (&УсловиеОрганизация)
| ЛЕВОЕ СОЕДИНЕНИЕ ВТСоответствиеВидовСтажаПараметрамИсчисления2014 КАК СоответствиеВидовСтажаПараметрамИсчисления2014
| ПО ПериодыСтажаПФР.ВидСтажаПФР = СоответствиеВидовСтажаПараметрамИсчисления2014.ВидСтажа
| И (ОтчетныеПериоды.ИспользоватьПараметрыСтажа2014)
| ЛЕВОЕ СОЕДИНЕНИЕ ВТСоответствиеВидовСтажаПараметрамИсчисления2013 КАК СоответствиеВидовСтажаПараметрамИсчисления2013
| ПО ПериодыСтажаПФР.ВидСтажаПФР = СоответствиеВидовСтажаПараметрамИсчисления2013.ВидСтажа
| И (ОтчетныеПериоды.ИспользоватьПараметрыСтажа2013)
| ЛЕВОЕ СОЕДИНЕНИЕ ВТЗамещениеГосударственныхДолжностей КАК ЗамещениеГосударственныхДолжностей
| ПО ПериодыСтажаПФР.Должность = ЗамещениеГосударственныхДолжностей.Должность";
ТекстыДополнительныхПолейЗапроса = ТекстДополнительныхПолейЗапросаВТДанныеУчетаСтажаПФР();
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "КоличествоСтавок", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "НеполныйРабочийДень", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ОснованиеДосрочногоНазначенияПенсии", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "КодПозицииСписка", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ТерриториальныеУсловия", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ТерриториальныеУсловияДополнительные", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ЗарегистрированоЗначениеТерриториальныеУсловияДополнительные", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ОсобыеУсловияТруда", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ЗарегистрированоЗначениеТерриториальныеУсловия", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ЗарегистрированоЗначениеОснованиеВыслугиЛет", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ЗарегистрированоЗначениеОсобыеУсловияТруда", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "СтруктурнаяЕдиница", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "Должность", ТекстыДополнительныхПолейЗапроса);
УстановитьТекстПоляЗапросаВТДанныеУчетаСтажаПФР(Запрос, "ВладелецДопТерриторий", ТекстыДополнительныхПолейЗапроса);
Если ПараметрыОтбора.ИмяВТОтбор = Неопределено Тогда
ПодстрокаЗамены = "ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТФильтр КАК Фильтр
| ПО (&УсловияСвязиПоИзмерениям)";
Запрос.Текст = СтрЗаменить(Запрос.Текст, ПодстрокаЗамены, "");
Иначе
Запрос.Текст = СтрЗаменить(Запрос.Текст, "ВТФильтр", ПараметрыОтбора.ИмяВТОтбор);
УсловиеСвязи = "";
Для Каждого ИзмерениеФильтра Из ПараметрыОтбора.ИзмеренияОтбора Цикл
УсловиеСвязи = УсловиеСвязи + "
| И ПериодыСтажаПФР." + ИзмерениеФильтра + " = Фильтр." + ИзмерениеФильтра;
КонецЦикла;
УсловиеСвязи = Сред(УсловиеСвязи, 4);
Запрос.Текст = СтрЗаменить(Запрос.Текст, "&УсловияСвязиПоИзмерениям", УсловиеСвязи);
КонецЕсли;
Если ПараметрыОтбора.Организация = Неопределено Тогда
ТекстУсловияОрганизация = "ИСТИНА";
Иначе
ТекстУсловияОрганизация = "ПериодыСтажаПФР.Организация = &Организация";
КонецЕсли;
Запрос.Текст = СтрЗаменить(Запрос.Текст, "&УсловиеОрганизация", ТекстУсловияОрганизация);
Если НачалоПериода < '20170101' Тогда
Запрос.Текст = СтрЗаменить(Запрос.Текст, "ЕСТЬNULL(ЗамещениеГосударственныхДолжностей.ЗамещениеГосударственныхМуниципальныхДолжностей, ЗНАЧЕНИЕ(Справочник.ЗамещениеГосударственныхМуниципальныхДолжностейПФР.ПустаяСсылка))", "ЗНАЧЕНИЕ(Справочник.ЗамещениеГосударственныхМуниципальныхДолжностейПФР.ПустаяСсылка)");
КонецЕсли;
УстановитьПривилегированныйРежим(Истина);
Запрос.Выполнить();
УстановитьПривилегированныйРежим(Ложь);
Запрос.Текст =
"ВЫБРАТЬ РАЗЛИЧНЫЕ
| ИсходныеДанныеУчетаСтажа.СтруктурнаяЕдиница КАК СтруктурнаяЕдиница,
| &НачалоПериода КАК ДатаНачала,
| &ОкончаниеПериода КАК ДатаОкончания
|ПОМЕСТИТЬ ВТПодразделения
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ИсходныеДанныеУчетаСтажа
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ РАЗЛИЧНЫЕ
| ВТИсходныеДанныеУчетаСтажа.Должность КАК Должность,
| &НачалоПериода КАК ДатаНачала,
| &ОкончаниеПериода КАК ДатаОкончания
|ПОМЕСТИТЬ ВТДолжности
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ВТИсходныеДанныеУчетаСтажа
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ РАЗЛИЧНЫЕ
| ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация КАК ГоловнаяОрганизация,
| ИсходныеДанныеУчетаСтажа.ФизическоеЛицо КАК ФизическоеЛицо,
| Периоды.Период КАК Период
|ПОМЕСТИТЬ ВТФизическиеЛицаПериоды
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ИсходныеДанныеУчетаСтажа,
| ВТПериоды КАК Периоды
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТСоответствиеВидовСтажаПараметрамИсчисления2013
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТСоответствиеВидовСтажаПараметрамИсчисления2014
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТПериоды
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТЗамещениеГосударственныхДолжностей";
Запрос.Выполнить();
УчетСтраховыхВзносов.СформироватьВТДанныеОПравахНаСтрахование(
Запрос.МенеджерВременныхТаблиц,
"ВТФизическиеЛицаПериоды",
Ложь);
ПараметрыПолученияДанных = ЗарплатаКадрыОбщиеНаборыДанных.ПараметрыПостроенияДляСоздатьВТИмяРегистра();
ПараметрыПолученияДанных.ВключатьЗаписиНаНачалоПериода = Истина;
ОписаниеФильтра = ЗарплатаКадрыОбщиеНаборыДанных.ОписаниеФильтраДляСоздатьВТИмяРегистра(
"ВТПодразделения",
"СтруктурнаяЕдиница");
ЗарплатаКадрыОбщиеНаборыДанных.СоздатьВТИмяРегистра(
"ТерриториальныеУсловияПФР",
Запрос.МенеджерВременныхТаблиц,
Ложь,
ОписаниеФильтра,
ПараметрыПолученияДанных);
ОписаниеФильтра = ЗарплатаКадрыОбщиеНаборыДанных.ОписаниеФильтраДляСоздатьВТИмяРегистра(
"ВТДолжности",
"Должность");
ЗарплатаКадрыОбщиеНаборыДанных.СоздатьВТИмяРегистра(
"КлассыУсловийТрудаПоДолжностям",
Запрос.МенеджерВременныхТаблиц,
Ложь,
ОписаниеФильтра,
ПараметрыПолученияДанных);
ПерсонифицированныйУчет.СоздатьВТИнтервалыПоТаблицеДат(
Запрос.МенеджерВременныхТаблиц,
"ВТДанныеОПравахНаСтрахование",
"МЕСЯЦ",
"ФизическоеЛицо, ЗастрахованПФР, ГоловнаяОрганизация",
"ВТПраваНаСтрахованиеИнтервалы");
Запрос.Текст =
"ВЫБРАТЬ
| ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация,
| ИсходныеДанныеУчетаСтажа.ФизическоеЛицо,
| ТерриториальныеУсловияПФРПоПериодам.Период
|ПОМЕСТИТЬ ВТПериодыИзмененияДанных
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ИсходныеДанныеУчетаСтажа
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТТерриториальныеУсловияПФР КАК ТерриториальныеУсловияПФРПоПериодам
| ПО ИсходныеДанныеУчетаСтажа.Начало <= ТерриториальныеУсловияПФРПоПериодам.Период
| И ИсходныеДанныеУчетаСтажа.Окончание >= ТерриториальныеУсловияПФРПоПериодам.Период
|
|ОБЪЕДИНИТЬ
|
|ВЫБРАТЬ
| ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация,
| ИсходныеДанныеУчетаСтажа.ФизическоеЛицо,
| КлассыУсловийТрудаПоДолжностям.Период
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ИсходныеДанныеУчетаСтажа
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТКлассыУсловийТрудаПоДолжностям КАК КлассыУсловийТрудаПоДолжностям
| ПО (КлассыУсловийТрудаПоДолжностям.Должность = ИсходныеДанныеУчетаСтажа.Должность)
| И (КлассыУсловийТрудаПоДолжностям.Период >= ИсходныеДанныеУчетаСтажа.Начало)
| И (КлассыУсловийТрудаПоДолжностям.Период <= ИсходныеДанныеУчетаСтажа.Окончание)
|
|ОБЪЕДИНИТЬ
|
|ВЫБРАТЬ
| ПраваНаСтрахованиеИнтервалы.ГоловнаяОрганизация,
| ПраваНаСтрахованиеИнтервалы.ФизическоеЛицо,
| ПраваНаСтрахованиеИнтервалы.ДатаНачалаИнтервала
|ИЗ
| ВТПраваНаСтрахованиеИнтервалы КАК ПраваНаСтрахованиеИнтервалы
|
|ОБЪЕДИНИТЬ
|
|ВЫБРАТЬ
| ПраваНаСтрахованиеИнтервалы.ГоловнаяОрганизация,
| ПраваНаСтрахованиеИнтервалы.ФизическоеЛицо,
| ПраваНаСтрахованиеИнтервалы.ДатаОкончанияИнтервала
|ИЗ
| ВТПраваНаСтрахованиеИнтервалы КАК ПраваНаСтрахованиеИнтервалы
|ГДЕ
| ПраваНаСтрахованиеИнтервалы.ДатаОкончанияИнтервала < &ОкончаниеПериода
|
|ОБЪЕДИНИТЬ
|
|ВЫБРАТЬ
| ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация,
| ИсходныеДанныеУчетаСтажа.ФизическоеЛицо,
| ИсходныеДанныеУчетаСтажа.Начало
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ИсходныеДанныеУчетаСтажа
|";
Запрос.Выполнить();
Запрос.Текст =
"ВЫБРАТЬ
| ПериодыИзмененияДанных.ГоловнаяОрганизация,
| ПериодыИзмененияДанных.ФизическоеЛицо,
| ПериодыИзмененияДанных.Период,
| ИсходныеДанныеУчетаСтажа.Начало,
| ИсходныеДанныеУчетаСтажа.СтруктурнаяЕдиница,
| ИсходныеДанныеУчетаСтажа.Должность,
| ИсходныеДанныеУчетаСтажа.Окончание
|ПОМЕСТИТЬ ВТКлючиДляСрезаПериодическихДанных
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ИсходныеДанныеУчетаСтажа
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТПериодыИзмененияДанных КАК ПериодыИзмененияДанных
| ПО ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация = ПериодыИзмененияДанных.ГоловнаяОрганизация
| И ИсходныеДанныеУчетаСтажа.ФизическоеЛицо = ПериодыИзмененияДанных.ФизическоеЛицо
| И ИсходныеДанныеУчетаСтажа.Начало <= ПериодыИзмененияДанных.Период
| И ИсходныеДанныеУчетаСтажа.Окончание >= ПериодыИзмененияДанных.Период
|";
Запрос.Выполнить();
Запрос.Текст =
"ВЫБРАТЬ
| КлючиДляСрезаПериодическихДанных.ГоловнаяОрганизация,
| КлючиДляСрезаПериодическихДанных.ФизическоеЛицо,
| КлючиДляСрезаПериодическихДанных.Период,
| КлючиДляСрезаПериодическихДанных.Начало,
| КлючиДляСрезаПериодическихДанных.СтруктурнаяЕдиница,
| КлючиДляСрезаПериодическихДанных.Должность,
| МАКСИМУМ(ТерриториальныеУсловия.Период) КАК ДатаСрезаТерриториальныхУсловий,
| МАКСИМУМ(КлассыУсловийТрудаПоДолжностям.Период) КАК ДатаСрезаКлассаУсловийТруда,
| КлючиДляСрезаПериодическихДанных.Окончание
|ПОМЕСТИТЬ ВТДатыСрезаПериодическихДанных
|ИЗ
| ВТКлючиДляСрезаПериодическихДанных КАК КлючиДляСрезаПериодическихДанных
| ЛЕВОЕ СОЕДИНЕНИЕ ВТТерриториальныеУсловияПФР КАК ТерриториальныеУсловия
| ПО КлючиДляСрезаПериодическихДанных.СтруктурнаяЕдиница = ТерриториальныеУсловия.СтруктурнаяЕдиница
| И КлючиДляСрезаПериодическихДанных.Период >= ТерриториальныеУсловия.Период
| ЛЕВОЕ СОЕДИНЕНИЕ ВТКлассыУсловийТрудаПоДолжностям КАК КлассыУсловийТрудаПоДолжностям
| ПО КлючиДляСрезаПериодическихДанных.Должность = КлассыУсловийТрудаПоДолжностям.Должность
| И КлючиДляСрезаПериодическихДанных.Период >= КлассыУсловийТрудаПоДолжностям.Период
|
|СГРУППИРОВАТЬ ПО
| КлючиДляСрезаПериодическихДанных.ГоловнаяОрганизация,
| КлючиДляСрезаПериодическихДанных.ФизическоеЛицо,
| КлючиДляСрезаПериодическихДанных.Период,
| КлючиДляСрезаПериодическихДанных.СтруктурнаяЕдиница,
| КлючиДляСрезаПериодическихДанных.Должность,
| КлючиДляСрезаПериодическихДанных.Начало,
| КлючиДляСрезаПериодическихДанных.Окончание
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТКлючиДляСрезаПериодическихДанных
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТФизическиеЛицаПериоды
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТПодразделения
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТДолжности
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТПериодыИзмененияДанных";
Запрос.Выполнить();
Запрос.Текст =
"ВЫБРАТЬ
| ДатыСрезаПериодическихДанных.ГоловнаяОрганизация,
| ВЫБОР
| КОГДА ТерриториальныеУсловияПоПериодам.ТерриториальныеУсловияПФР В (&ИсключаемыеТерриториальныеУсловия)
| ТОГДА ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка)
| ИНАЧЕ ТерриториальныеУсловияПоПериодам.ТерриториальныеУсловияПФР
| КОНЕЦ КАК ТерриториальныеУсловияПФР,
| КлассыУсловийТрудаПоДолжностям.КлассУсловийТруда,
| ДанныеОПравахНаСтрахование.ЗастрахованПФР,
| ДатыСрезаПериодическихДанных.ФизическоеЛицо,
| ДатыСрезаПериодическихДанных.Период,
| ДатыСрезаПериодическихДанных.Начало,
| ДатыСрезаПериодическихДанных.Окончание,
| ДатыСрезаПериодическихДанных.СтруктурнаяЕдиница,
| ДатыСрезаПериодическихДанных.Должность
|ПОМЕСТИТЬ ВТЗначениеПериодическихПараметровСтажа
|ИЗ
| ВТДатыСрезаПериодическихДанных КАК ДатыСрезаПериодическихДанных
| ЛЕВОЕ СОЕДИНЕНИЕ ВТПраваНаСтрахованиеИнтервалы КАК ДанныеОПравахНаСтрахование
| ПО ДатыСрезаПериодическихДанных.ГоловнаяОрганизация = ДанныеОПравахНаСтрахование.ГоловнаяОрганизация
| И ДатыСрезаПериодическихДанных.ФизическоеЛицо = ДанныеОПравахНаСтрахование.ФизическоеЛицо
| И (ДатыСрезаПериодическихДанных.Период МЕЖДУ ДанныеОПравахНаСтрахование.ДатаНачалаИнтервала И ДанныеОПравахНаСтрахование.ДатаОкончанияИнтервала)
| ЛЕВОЕ СОЕДИНЕНИЕ ВТКлассыУсловийТрудаПоДолжностям КАК КлассыУсловийТрудаПоДолжностям
| ПО ДатыСрезаПериодическихДанных.Должность = КлассыУсловийТрудаПоДолжностям.Должность
| И ДатыСрезаПериодическихДанных.ДатаСрезаКлассаУсловийТруда = КлассыУсловийТрудаПоДолжностям.Период
| ЛЕВОЕ СОЕДИНЕНИЕ ВТТерриториальныеУсловияПФР КАК ТерриториальныеУсловияПоПериодам
| ПО ДатыСрезаПериодическихДанных.ДатаСрезаТерриториальныхУсловий = ТерриториальныеУсловияПоПериодам.Период
| И ДатыСрезаПериодическихДанных.СтруктурнаяЕдиница = ТерриториальныеУсловияПоПериодам.СтруктурнаяЕдиница
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТДатыСрезаПериодическихДанных
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТПраваНаСтрахованиеИнтервалы
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТКлассыУсловийТрудаПоДолжностям
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТТерриториальныеУсловияПФР
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТДанныеОПравахНаСтрахование";
Запрос.Выполнить();
Запрос.Текст =
"ВЫБРАТЬ
| ЗначениеПериодическихПараметровСтажа.ГоловнаяОрганизация,
| ЗначениеПериодическихПараметровСтажа.ФизическоеЛицо,
| ЗначениеПериодическихПараметровСтажа.ТерриториальныеУсловияПФР,
| ЗначениеПериодическихПараметровСтажа.КлассУсловийТруда,
| ЗначениеПериодическихПараметровСтажа.ЗастрахованПФР,
| ЗначениеПериодическихПараметровСтажа.Период КАК ДатаНачалаПериода,
| ЗначениеПериодическихПараметровСтажа.СтруктурнаяЕдиница,
| ЗначениеПериодическихПараметровСтажа.Начало КАК НачалоИсходногоПериода,
| МИНИМУМ(ВЫБОР
| КОГДА ЗначениеПериодическихПараметровСтажаСлед.Период ЕСТЬ NULL
| ТОГДА ЗначениеПериодическихПараметровСтажа.Окончание
| ИНАЧЕ ДОБАВИТЬКДАТЕ(ЗначениеПериодическихПараметровСтажаСлед.Период, ДЕНЬ, -1)
| КОНЕЦ) КАК ДатаОкончанияПериода,
| ЗначениеПериодическихПараметровСтажа.Должность
|ПОМЕСТИТЬ ВТПериодическиеПараметрыСтажаИнтервалы
|ИЗ
| ВТЗначениеПериодическихПараметровСтажа КАК ЗначениеПериодическихПараметровСтажа
| ЛЕВОЕ СОЕДИНЕНИЕ ВТЗначениеПериодическихПараметровСтажа КАК ЗначениеПериодическихПараметровСтажаСлед
| ПО ЗначениеПериодическихПараметровСтажа.ГоловнаяОрганизация = ЗначениеПериодическихПараметровСтажаСлед.ГоловнаяОрганизация
| И ЗначениеПериодическихПараметровСтажа.ФизическоеЛицо = ЗначениеПериодическихПараметровСтажаСлед.ФизическоеЛицо
| И ЗначениеПериодическихПараметровСтажа.Начало = ЗначениеПериодическихПараметровСтажаСлед.Начало
| И ЗначениеПериодическихПараметровСтажа.Окончание = ЗначениеПериодическихПараметровСтажаСлед.Окончание
| И ЗначениеПериодическихПараметровСтажа.Период < ЗначениеПериодическихПараметровСтажаСлед.Период
|ГДЕ
| ЗначениеПериодическихПараметровСтажа.ЗастрахованПФР
|
|СГРУППИРОВАТЬ ПО
| ЗначениеПериодическихПараметровСтажа.ГоловнаяОрганизация,
| ЗначениеПериодическихПараметровСтажа.ФизическоеЛицо,
| ЗначениеПериодическихПараметровСтажа.ТерриториальныеУсловияПФР,
| ЗначениеПериодическихПараметровСтажа.КлассУсловийТруда,
| ЗначениеПериодическихПараметровСтажа.ЗастрахованПФР,
| ЗначениеПериодическихПараметровСтажа.Период,
| ЗначениеПериодическихПараметровСтажа.СтруктурнаяЕдиница,
| ЗначениеПериодическихПараметровСтажа.Начало,
| ЗначениеПериодическихПараметровСтажа.Должность
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТЗначениеПериодическихПараметровСтажа
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТОтчетныеПериоды";
Запрос.Выполнить();
Запрос.Текст =
"ВЫБРАТЬ
| ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация КАК ГоловнаяОрганизация,
| ИсходныеДанныеУчетаСтажа.Организация КАК Организация,
| ИсходныеДанныеУчетаСтажа.ОтчетныйПериод КАК ОтчетныйПериод,
| ИсходныеДанныеУчетаСтажа.ФизическоеЛицо КАК ФизическоеЛицо,
| ИсходныеДанныеУчетаСтажа.ТипДоговора КАК ТипДоговора,
| ПериодическиеПараметрыСтажаИнтервалы.ДатаНачалаПериода КАК ДатаНачалаПериода,
| ПериодическиеПараметрыСтажаИнтервалы.ДатаОкончанияПериода КАК ДатаОкончанияПериода,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеОснованиеВыслугиЛет
| И ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии
| КОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии В (ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_11ВП), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_11ГР), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_12), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_14), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_15), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_СП), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.САМОЛЕТ))
| И ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.КлассУсловийТруда, ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.ПустаяСсылка)) В (ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Оптимальный), ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Допустимый))
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.ПустаяСсылка)
| КОНЕЦ КАК ОснованиеВыслугиЛет,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеОсобыеУсловияТруда
| И ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда
| КОГДА ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.КлассУсловийТруда, ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.ПустаяСсылка)) В (ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Оптимальный), ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Допустимый))
| И ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда <> ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.Ст28_СЕВ)
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда В (ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.Ст27_3), ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.Ст27_4))
| И ИсходныеДанныеУчетаСтажа.ФизическоеЛицо.Пол = ЗНАЧЕНИЕ(Перечисление.ПолФизическогоЛица.Мужской)
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОНЕЦ КАК ОсобыеУсловияТруда,
| ВЫБОР
| КОГДА ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.КлассУсловийТруда, ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.ПустаяСсылка)) В (ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Оптимальный), ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Допустимый))
| ТОГДА ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| ТОГДА ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии = ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.ПустаяСсылка)
| И ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда = ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| ТОГДА ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.КодПозицииСписка
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОНЕЦ КАК КодПозицииСписка,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| И ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеТерриториальныеУсловия
| ТОГДА ИсходныеДанныеУчетаСтажа.ТерриториальныеУсловия
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.ТерриториальныеУсловияПФР, ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка))
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка)
| КОНЕЦ КАК ТерриториальныеУсловия,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| И ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеТерриториальныеУсловияДополнительные
| ТОГДА ИсходныеДанныеУчетаСтажа.ТерриториальныеУсловияДополнительные
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ЕСТЬNULL(ТерриториальныеУсловияДополнительныеПФР.ТерриториальныеУсловияПФР, ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка))
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка)
| КОНЕЦ КАК ТерриториальныеУсловияДополнительные,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеТерриториальныеУсловия
| И ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| И ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| И ИсходныеДанныеУчетаСтажа.ТерриториальныеУсловия В (ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКСР), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКСМ))
| ТОГДА ИсходныеДанныеУчетаСтажа.КоличествоСтавок
| КОГДА НЕ ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| ТОГДА 0
| КОГДА НЕ ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА 0
| КОГДА ПериодическиеПараметрыСтажаИнтервалы.ТерриториальныеУсловияПФР В (ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКСР), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКСМ))
| ТОГДА ИсходныеДанныеУчетаСтажа.КоличествоСтавок
| ИНАЧЕ 0
| КОНЕЦ КАК ПараметрТерриториальныхУсловий,
| ВЫБОР
| КОГДА НЕ ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА 0
| КОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии В (ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_ПД), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_ГДХР), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_СМ), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_СМХР), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_ГД))
| ТОГДА ИсходныеДанныеУчетаСтажа.КоличествоСтавок
| ИНАЧЕ 0
| КОНЕЦ КАК ТретийПараметрВыслугиЛет,
| ИсходныеДанныеУчетаСтажа.ТретийПараметрИсчисляемогоСтажа КАК ТретийПараметрИсчисляемогоСтажа,
| ИсходныеДанныеУчетаСтажа.ЗамещениеГосударственныхМуниципальныхДолжностей КАК ЗамещениеГосударственныхМуниципальныхДолжностей
|ПОМЕСТИТЬ ВТДанныеУчетаСтажаПФРНеСгруппированные
|ИЗ
| ВТИсходныеДанныеУчетаСтажа КАК ИсходныеДанныеУчетаСтажа
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТПериодическиеПараметрыСтажаИнтервалы КАК ПериодическиеПараметрыСтажаИнтервалы
| ПО ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация = ПериодическиеПараметрыСтажаИнтервалы.ГоловнаяОрганизация
| И ИсходныеДанныеУчетаСтажа.ФизическоеЛицо = ПериодическиеПараметрыСтажаИнтервалы.ФизическоеЛицо
| И ИсходныеДанныеУчетаСтажа.Начало = ПериодическиеПараметрыСтажаИнтервалы.НачалоИсходногоПериода
| И ИсходныеДанныеУчетаСтажа.СтруктурнаяЕдиница = ПериодическиеПараметрыСтажаИнтервалы.СтруктурнаяЕдиница
| И ИсходныеДанныеУчетаСтажа.Должность = ПериодическиеПараметрыСтажаИнтервалы.Должность
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ТерриториальныеУсловияДополнительныеПФР КАК ТерриториальныеУсловияДополнительныеПФР
| ПО ИсходныеДанныеУчетаСтажа.ВладелецДопТерриторий = ТерриториальныеУсловияДополнительныеПФР.СтруктурнаяЕдиница
// Исправление ошибки СЗВ-СТАЖ ->
|
|СГРУППИРОВАТЬ ПО
| ИсходныеДанныеУчетаСтажа.ГоловнаяОрганизация,
| ИсходныеДанныеУчетаСтажа.Организация,
| ИсходныеДанныеУчетаСтажа.ОтчетныйПериод,
| ИсходныеДанныеУчетаСтажа.ФизическоеЛицо,
| ИсходныеДанныеУчетаСтажа.ТипДоговора,
| ПериодическиеПараметрыСтажаИнтервалы.ДатаНачалаПериода,
| ПериодическиеПараметрыСтажаИнтервалы.ДатаОкончанияПериода,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеОснованиеВыслугиЛет
| И ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии
| КОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии В (ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_11ВП), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_11ГР), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_12), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_14), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_15), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_СП), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.САМОЛЕТ))
| И ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.КлассУсловийТруда, ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.ПустаяСсылка)) В (ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Оптимальный), ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Допустимый))
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.ПустаяСсылка)
| КОНЕЦ,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеОсобыеУсловияТруда
| И ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда
| КОГДА ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.КлассУсловийТруда, ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.ПустаяСсылка)) В (ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Оптимальный), ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Допустимый))
| И ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда <> ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.Ст28_СЕВ)
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда В (ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.Ст27_3), ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.Ст27_4))
| И ИсходныеДанныеУчетаСтажа.ФизическоеЛицо.Пол = ЗНАЧЕНИЕ(Перечисление.ПолФизическогоЛица.Мужской)
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| ТОГДА ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| КОНЕЦ,
| ВЫБОР
| КОГДА ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.КлассУсловийТруда, ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.ПустаяСсылка)) В (ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Оптимальный), ЗНАЧЕНИЕ(Перечисление.КлассыУсловийТрудаПоРезультатамСпециальнойОценки.Допустимый))
| ТОГДА ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| ТОГДА ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии = ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.ПустаяСсылка)
| И ИсходныеДанныеУчетаСтажа.ОсобыеУсловияТруда = ЗНАЧЕНИЕ(Справочник.ОсобыеУсловияТрудаПФР.ПустаяСсылка)
| ТОГДА ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ИсходныеДанныеУчетаСтажа.КодПозицииСписка
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.СпискиПрофессийДолжностейЛьготногоПенсионногоОбеспечения.ПустаяСсылка)
| КОНЕЦ,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| И ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеТерриториальныеУсловия
| ТОГДА ИсходныеДанныеУчетаСтажа.ТерриториальныеУсловия
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ЕСТЬNULL(ПериодическиеПараметрыСтажаИнтервалы.ТерриториальныеУсловияПФР, ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка))
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка)
| КОНЕЦ,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| И ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеТерриториальныеУсловияДополнительные
| ТОГДА ИсходныеДанныеУчетаСтажа.ТерриториальныеУсловияДополнительные
| КОГДА ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА ЕСТЬNULL(ТерриториальныеУсловияДополнительныеПФР.ТерриториальныеУсловияПФР, ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка))
| ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.ПустаяСсылка)
| КОНЕЦ,
| ВЫБОР
| КОГДА ИсходныеДанныеУчетаСтажа.ЗарегистрированоЗначениеТерриториальныеУсловия
| И ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| И ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| И ИсходныеДанныеУчетаСтажа.ТерриториальныеУсловия В (ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКСР), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКСМ))
| ТОГДА ИсходныеДанныеУчетаСтажа.КоличествоСтавок
| КОГДА НЕ ИсходныеДанныеУчетаСтажа.НеполныйРабочийДень
| ТОГДА 0
| КОГДА НЕ ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА 0
| КОГДА ПериодическиеПараметрыСтажаИнтервалы.ТерриториальныеУсловияПФР В (ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.МКСР), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКС), ЗНАЧЕНИЕ(Справочник.ТерриториальныеУсловияПФР.РКСМ))
| ТОГДА ИсходныеДанныеУчетаСтажа.КоличествоСтавок
| ИНАЧЕ 0
| КОНЕЦ,
| ВЫБОР
| КОГДА НЕ ИсходныеДанныеУчетаСтажа.ЕстьПравоНаЛьготныйСтаж
| ТОГДА 0
| КОГДА ИсходныеДанныеУчетаСтажа.ОснованиеДосрочногоНазначенияПенсии В (ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_ПД), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_ГДХР), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_СМ), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_СМХР), ЗНАЧЕНИЕ(Справочник.ОснованияДосрочногоНазначенияПенсии.Ст27_ГД))
| ТОГДА ИсходныеДанныеУчетаСтажа.КоличествоСтавок
| ИНАЧЕ 0
| КОНЕЦ,
| ИсходныеДанныеУчетаСтажа.ТретийПараметрИсчисляемогоСтажа,
| ИсходныеДанныеУчетаСтажа.ЗамещениеГосударственныхМуниципальныхДолжностей
|
// <- Исправление ошибки СЗВ-СТАЖ
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| НачалоПериодовСтажа.ГоловнаяОрганизация КАК ГоловнаяОрганизация,
| НачалоПериодовСтажа.Организация КАК Организация,
| НачалоПериодовСтажа.ОтчетныйПериод КАК ОтчетныйПериод,
| НачалоПериодовСтажа.ФизическоеЛицо КАК ФизическоеЛицо,
| НачалоПериодовСтажа.ТипДоговора КАК ТипДоговора,
| НачалоПериодовСтажа.ДатаНачалаПериода КАК ГраницаПериода,
| НачалоПериодовСтажа.ОснованиеВыслугиЛет КАК ОснованиеВыслугиЛет,
| НачалоПериодовСтажа.ОсобыеУсловияТруда КАК ОсобыеУсловияТруда,
| НачалоПериодовСтажа.КодПозицииСписка КАК КодПозицииСписка,
| НачалоПериодовСтажа.ТерриториальныеУсловия КАК ТерриториальныеУсловия,
| НачалоПериодовСтажа.ТерриториальныеУсловияДополнительные КАК ТерриториальныеУсловияДополнительные,
| НачалоПериодовСтажа.ПараметрТерриториальныхУсловий КАК ПараметрТерриториальныхУсловий,
| НачалоПериодовСтажа.ТретийПараметрВыслугиЛет КАК ТретийПараметрВыслугиЛет,
| НачалоПериодовСтажа.ТретийПараметрИсчисляемогоСтажа КАК ТретийПараметрИсчисляемогоСтажа,
| НачалоПериодовСтажа.ЗамещениеГосударственныхМуниципальныхДолжностей КАК ЗамещениеГосударственныхМуниципальныхДолжностей,
| СУММА(НачалоПериодовСтажа.ПризнакГраницыПериодов) КАК ПризнакГраницыПериодов
|ПОМЕСТИТЬ ВТГраницыПериодов
|ИЗ
| (ВЫБРАТЬ
| ДанныеУчетаСтажаПФР.ГоловнаяОрганизация КАК ГоловнаяОрганизация,
| ДанныеУчетаСтажаПФР.Организация КАК Организация,
| ДанныеУчетаСтажаПФР.ОтчетныйПериод КАК ОтчетныйПериод,
| ДанныеУчетаСтажаПФР.ФизическоеЛицо КАК ФизическоеЛицо,
| ДанныеУчетаСтажаПФР.ТипДоговора КАК ТипДоговора,
| ДанныеУчетаСтажаПФР.ДатаНачалаПериода КАК ДатаНачалаПериода,
| ДанныеУчетаСтажаПФР.ОснованиеВыслугиЛет КАК ОснованиеВыслугиЛет,
| ДанныеУчетаСтажаПФР.ОсобыеУсловияТруда КАК ОсобыеУсловияТруда,
| ДанныеУчетаСтажаПФР.КодПозицииСписка КАК КодПозицииСписка,
| ДанныеУчетаСтажаПФР.ТерриториальныеУсловия КАК ТерриториальныеУсловия,
| ДанныеУчетаСтажаПФР.ТерриториальныеУсловияДополнительные КАК ТерриториальныеУсловияДополнительные,
| ДанныеУчетаСтажаПФР.ПараметрТерриториальныхУсловий КАК ПараметрТерриториальныхУсловий,
| ДанныеУчетаСтажаПФР.ТретийПараметрВыслугиЛет КАК ТретийПараметрВыслугиЛет,
| ДанныеУчетаСтажаПФР.ТретийПараметрИсчисляемогоСтажа КАК ТретийПараметрИсчисляемогоСтажа,
| ДанныеУчетаСтажаПФР.ЗамещениеГосударственныхМуниципальныхДолжностей КАК ЗамещениеГосударственныхМуниципальныхДолжностей,
| 1 КАК ПризнакГраницыПериодов
| ИЗ
| ВТДанныеУчетаСтажаПФРНеСгруппированные КАК ДанныеУчетаСтажаПФР
|
| ОБЪЕДИНИТЬ ВСЕ
|
| ВЫБРАТЬ
| ДанныеУчетаСтажаПФР.ГоловнаяОрганизация,
| ДанныеУчетаСтажаПФР.Организация,
| ДанныеУчетаСтажаПФР.ОтчетныйПериод,
| ДанныеУчетаСтажаПФР.ФизическоеЛицо,
| ДанныеУчетаСтажаПФР.ТипДоговора,
| ДОБАВИТЬКДАТЕ(ДанныеУчетаСтажаПФР.ДатаОкончанияПериода, ДЕНЬ, 1),
| ДанныеУчетаСтажаПФР.ОснованиеВыслугиЛет,
| ДанныеУчетаСтажаПФР.ОсобыеУсловияТруда,
| ДанныеУчетаСтажаПФР.КодПозицииСписка,
| ДанныеУчетаСтажаПФР.ТерриториальныеУсловия,
| ДанныеУчетаСтажаПФР.ТерриториальныеУсловияДополнительные,
| ДанныеУчетаСтажаПФР.ПараметрТерриториальныхУсловий,
| ДанныеУчетаСтажаПФР.ТретийПараметрВыслугиЛет,
| ДанныеУчетаСтажаПФР.ТретийПараметрИсчисляемогоСтажа,
| ДанныеУчетаСтажаПФР.ЗамещениеГосударственныхМуниципальныхДолжностей,
| -1
| ИЗ
| ВТДанныеУчетаСтажаПФРНеСгруппированные КАК ДанныеУчетаСтажаПФР) КАК НачалоПериодовСтажа
|
|СГРУППИРОВАТЬ ПО
| НачалоПериодовСтажа.ГоловнаяОрганизация,
| НачалоПериодовСтажа.ОсобыеУсловияТруда,
| НачалоПериодовСтажа.КодПозицииСписка,
| НачалоПериодовСтажа.ТипДоговора,
| НачалоПериодовСтажа.ОснованиеВыслугиЛет,
| НачалоПериодовСтажа.Организация,
| НачалоПериодовСтажа.ОтчетныйПериод,
| НачалоПериодовСтажа.ФизическоеЛицо,
| НачалоПериодовСтажа.ДатаНачалаПериода,
| НачалоПериодовСтажа.ТерриториальныеУсловия,
| НачалоПериодовСтажа.ПараметрТерриториальныхУсловий,
| НачалоПериодовСтажа.ТретийПараметрВыслугиЛет,
| НачалоПериодовСтажа.ТретийПараметрИсчисляемогоСтажа,
| НачалоПериодовСтажа.ЗамещениеГосударственныхМуниципальныхДолжностей,
| НачалоПериодовСтажа.ТерриториальныеУсловияДополнительные
|
|ИМЕЮЩИЕ
| СУММА(НачалоПериодовСтажа.ПризнакГраницыПериодов) <> 0
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| НачалоПериодов.ГоловнаяОрганизация КАК ГоловнаяОрганизация,
| НачалоПериодов.Организация КАК Организация,
| НачалоПериодов.ОтчетныйПериод КАК ОтчетныйПериод,
| НачалоПериодов.ФизическоеЛицо КАК ФизическоеЛицо,
| НачалоПериодов.ТипДоговора КАК ТипДоговора,
| НачалоПериодов.ГраницаПериода КАК ДатаНачалаПериода,
| НачалоПериодов.ОснованиеВыслугиЛет КАК ОснованиеВыслугиЛет,
| НачалоПериодов.ОсобыеУсловияТруда КАК ОсобыеУсловияТруда,
| НачалоПериодов.КодПозицииСписка КАК КодПозицииСписка,
| НачалоПериодов.ТерриториальныеУсловия КАК ТерриториальныеУсловия,
| НачалоПериодов.ТерриториальныеУсловияДополнительные КАК ТерриториальныеУсловияДополнительные,
| НачалоПериодов.ПараметрТерриториальныхУсловий КАК ПараметрТерриториальныхУсловий,
| НачалоПериодов.ТретийПараметрВыслугиЛет КАК ТретийПараметрВыслугиЛет,
| НачалоПериодов.ЗамещениеГосударственныхМуниципальныхДолжностей КАК ЗамещениеГосударственныхМуниципальныхДолжностей,
| МИНИМУМ(ДОБАВИТЬКДАТЕ(ОкончаниеПериодов.ГраницаПериода, ДЕНЬ, -1)) КАК ДатаОкончанияПериода,
| НачалоПериодов.ТретийПараметрИсчисляемогоСтажа КАК ТретийПараметрИсчисляемогоСтажа,
| ЗНАЧЕНИЕ(Справочник.ОснованияИсчисляемогоСтраховогоСтажа.ПустаяСсылка) КАК ОснованиеИсчисляемогоСтажа,
| """" КАК ПервыйПараметрИсчисляемогоСтажа,
| """" КАК ВторойПараметрИсчисляемогоСтажа,
| """" КАК ПервыйПараметрВыслугиЛет,
| """" КАК ВторойПараметрВыслугиЛет,
| ЛОЖЬ КАК ФиксСтаж,
| ИСТИНА КАК СложныйСтаж
|ПОМЕСТИТЬ ВТДанныеУчетаСтажаПФР
|ИЗ
| ВТГраницыПериодов КАК НачалоПериодов
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТГраницыПериодов КАК ОкончаниеПериодов
| ПО НачалоПериодов.ГоловнаяОрганизация = ОкончаниеПериодов.ГоловнаяОрганизация
| И НачалоПериодов.Организация = ОкончаниеПериодов.Организация
| И НачалоПериодов.ОтчетныйПериод = ОкончаниеПериодов.ОтчетныйПериод
| И НачалоПериодов.ФизическоеЛицо = ОкончаниеПериодов.ФизическоеЛицо
| И НачалоПериодов.ТипДоговора = ОкончаниеПериодов.ТипДоговора
| И (НачалоПериодов.ПризнакГраницыПериодов = 1)
| И (ОкончаниеПериодов.ПризнакГраницыПериодов = -1)
| И НачалоПериодов.ГраницаПериода < ОкончаниеПериодов.ГраницаПериода
|
|СГРУППИРОВАТЬ ПО
| НачалоПериодов.Организация,
| НачалоПериодов.ТерриториальныеУсловия,
| НачалоПериодов.ФизическоеЛицо,
| НачалоПериодов.ГраницаПериода,
| НачалоПериодов.ГоловнаяОрганизация,
| НачалоПериодов.ОсобыеУсловияТруда,
| НачалоПериодов.ОтчетныйПериод,
| НачалоПериодов.КодПозицииСписка,
| НачалоПериодов.ОснованиеВыслугиЛет,
| НачалоПериодов.ТипДоговора,
| НачалоПериодов.ПараметрТерриториальныхУсловий,
| НачалоПериодов.ТретийПараметрВыслугиЛет,
| НачалоПериодов.ТретийПараметрИсчисляемогоСтажа,
| НачалоПериодов.ЗамещениеГосударственныхМуниципальныхДолжностей,
| НачалоПериодов.ТерриториальныеУсловияДополнительные";
Запрос.Текст = СтрЗаменить(Запрос.Текст, "ВТДанныеУчетаСтажаПФР", ИмяВТРезультат);
Запрос.Выполнить();
ИменаВТ = Новый Массив;
ИменаВТ.Добавить("ВТИсходныеДанныеУчетаСтажа");
ИменаВТ.Добавить(СтрЗаменить("ВТДанныеУчетаСтажаПФРНеСгруппированные", "ВТДанныеУчетаСтажаПФР", ИмяВТРезультат));
ИменаВТ.Добавить("ВТГраницыПериодов");
ИменаВТ.Добавить("ВТПериодическиеПараметрыСтажаИнтервалы");
ЗарплатаКадры.УничтожитьВТ(Запрос.МенеджерВременныхТаблиц, ИменаВТ);
КонецПроцедуры
2. Поправить процедуру СоздатьВТСоответствиеВидовСтажаПараметрамИсчисления2014() в общем модуле УчетСтажаПФРРасширенный. Измененный блок в запросе выделен комментарием "Исправление ошибки СЗВ-СТАЖ"
Процедура СоздатьВТСоответствиеВидовСтажаПараметрамИсчисления2014(МенеджерВременныхТаблиц) Экспорт
Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
Запрос.Текст =
"ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.Декрет) КАК ВидСтажа,
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ДЕКРЕТ) КАК ПараметрИсчисляемогоСтажа
|ПОМЕСТИТЬ ВТСоответствиеВидовСтажаПараметрамИсчисления2014
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.Дети),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ДЕТИ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ВременнаяНетрудоспособность),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ВРНЕТРУД)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ДЛОТПУСК),
// Исправление ошибки СЗВ-СТАЖ->
//| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ДЛОТПУСК)
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ПустаяСсылка)
// <- Исправление ошибки СЗВ-СТАЖ
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ВАХТА),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ВАХТА)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.КВАЛИФ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.КВАЛИФ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.МЕДНЕТРУД),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.МЕДНЕТРУД)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.МЕСЯЦ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.МЕСЯЦ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ОБЩЕСТ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ОБЩЕСТ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ПРОСТОЙ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ПРОСТОЙ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.СДКРОВ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.СДКРОВ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.УЧОТПУСК),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.УЧОТПУСК)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ДОПВЫХ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ДОПВЫХ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ДЛДЕТИ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ДЛДЕТИ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ОТСТРАН),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ОТСТРАН)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ОтпускБезСохраненияЗарплаты),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.НЕОПЛ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ЧАЭС),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ЧАЭС)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.НЕОПЛ),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.НЕОПЛ)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ВключаетсяВСтажДляДосрочногоНазначенияПенсии),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ПустаяСсылка)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыСтажаПФР2014.ВключаетсяВСтраховойСтаж),
| ЗНАЧЕНИЕ(Справочник.ПараметрыИсчисляемогоСтраховогоСтажа.ПустаяСсылка)";
Запрос.Выполнить();
КонецПроцедуры
