Простая выгрузка данных в универсальном формате Enterprise Data

Публикация № 1102730

Разработка - Системная интеграция - Обмен через XML

обработка обмен универсальный формат enterprise data конвертация данных КД БСП xml ED

67
Пошагово разобран текст процедуры, позволяющей выгрузить произвольный набор объектов в формате Enterprise Data (конечно, если это позволяет конфигурация). Приложена обработка, позволяющая выгружать произвольные объекты, в том числе запросом или по данным журнала регистрации.

В процессе изучения КД3 меня не оставляло ощущение, что выгрузка данных в этом формате должна делаться как-то очень просто. Тут же возникла потребность сделать нестандартную "догрузку" множества физлиц с паспортными данными в ЗУП 3. После отсечения всего лишнего получилась короткая процедура. Что же внутри?

Инициализация

1. Инициализация структуры КомпонентыОбмена

	ИмяФайлаПротоколаОбмена="";   // если заполнить - будет писаться лог в файл
	КомпонентыОбмена = ОбменДаннымиXDTOСервер.ИнициализироватьКомпонентыОбмена("Отправка");
	
	КомпонентыОбмена.ВедениеПротоколаДанных.ВыводВПротоколИнформационныхСообщений = Ложь;
	КомпонентыОбмена.КлючСообщенияЖурналаРегистрации = ОбменДаннымиСервер.СобытиеЖурналаРегистрацииОбменДанными();
	КомпонентыОбмена.ЭтоОбменЧерезПланОбмена = Ложь;

2. Определяем версию формата обмена.

Можно просто указать, скажем, "1.6", но в свежих версиях БСП есть соответствующая функция:

	Версии=ОбменДаннымиXDTOСервер.ВерсииФорматаОбменаМассив(ПланыОбмена.СинхронизацияДанныхЧерезУниверсальныйФормат.ЭтотУзел());
	КомпонентыОбмена.ВерсияФорматаОбмена=Версии[0]; // первой будет максимальная версия, которую поддерживает конфигурация
	КомпонентыОбмена.XMLСхема = "http://v8.1c.ru/edi/edi_stnd/EnterpriseData/"+КомпонентыОбмена.ВерсияФорматаОбмена;

3. Заканчиваем инициализацию

	КомпонентыОбмена.МенеджерОбмена = МенеджерОбменаЧерезУниверсальныйФормат;
	ОбменДаннымиXDTOСервер.ИнициализироватьТаблицыПравилОбмена(КомпонентыОбмена);
	ОбменДаннымиXDTOСервер.ИнициализироватьВедениеПротоколаОбмена(КомпонентыОбмена, ИмяФайлаПротоколаОбмена);

4. Разбираемся с файлами

	// Открываем файл обмена. Если вторым параметром файл не указывать - выгрузка будет в строку
	ОбменДаннымиXDTOСервер.ОткрытьФайлВыгрузки(КомпонентыОбмена,"");  	
	Если КомпонентыОбмена.ФлагОшибки Тогда
		КомпонентыОбмена.ФайлОбмена = Неопределено;
		ОбменДаннымиXDTOСервер.ЗавершитьВедениеПротоколаОбмена(КомпонентыОбмена);
		Возврат "";
	КонецЕсли;

Всё готово для собственно выгрузки объектов.

Выгрузка по сценарию

Сценарий выгрузки представляет собой таблицу значений, в строках которой написаны имена правил обработки данных. Выгрузка по сценарию на момент написания работает без отборов.

Пример сценария выгрузки физических лиц и их документов:

	КомпонентыОбмена.СценарийВыгрузки = новый ТаблицаЗначений;
	КомпонентыОбмена.СценарийВыгрузки.Колонки.Добавить("ИмяПОД");

	НоваяСтрока = КомпонентыОбмена.СценарийВыгрузки.Добавить();
	НоваяСтрока.ИмяПОД = "Справочник_ФизическиеЛица_Отправка";
	
	НоваяСтрока = КомпонентыОбмена.СценарийВыгрузки.Добавить();
	НоваяСтрока.ИмяПОД = "Справочник_ДокументыФизическихЛиц_Отправка";

Запускается сценарий совсем просто:

	 //ВЫГРУЗКА ДАННЫХ по сценарию. Работает но без отборов
	Попытка
		ОбменДаннымиXDTOСервер.ПроизвестиВыгрузкуДанных(КомпонентыОбмена);
	Исключение
		ОбменДаннымиXDTOСервер.ЗаписатьВПротоколВыполнения(КомпонентыОбмена, ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
		ОбменДаннымиXDTOСервер.ЗавершитьВедениеПротоколаОбмена(КомпонентыОбмена);
		КомпонентыОбмена.ФайлОбмена = Неопределено;
		Возврат "";
	КонецПопытки;

Произвольная выгрузка данных запросом

Гораздо интереснее самим определить, какие именно данные мы хотим выгрузить и заставить систему их отработать.

Прежде чем выгружать наши объекты, нужно запустить обработчик "ПередКонвертацией". Вдруг разработчики там спрятали что-то жизненно важное?

	Попытка
		КомпонентыОбмена.МенеджерОбмена.ПередКонвертацией(КомпонентыОбмена);
	Исключение
		ТекстОшибки = Символы.ПС + СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(НСтр("ru = 'Событие: %1.
				|Обработчик: ПередКонвертацией.
				|
				|Ошибка выполнения обработчика.
				|%2.'"),
			КомпонентыОбмена.НаправлениеОбмена,
			ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
		ОбменДаннымиXDTOСервер.ЗаписатьВПротоколВыполнения(КомпонентыОбмена, СокрЛП(ТекстОшибки));
	КонецПопытки;

Выгрузка ссылочных объектов запросом, на примере физических лиц:

	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ РАЗЛИЧНЫЕ
		|	ФизическиеЛица.Ссылка КАК Ссылка
		|ИЗ
		|	Справочник.ФизическиеЛица КАК ФизическиеЛица
		|ГДЕ
		|	НЕ ФизическиеЛица.ПометкаУдаления";
	РезультатЗапроса = Запрос.Выполнить();
	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
		ОбменДаннымиXDTOСервер.ВыгрузкаОбъектаВыборки(КомпонентыОбмена, Стр.Ссылка);
	КонецЦикла;

В свежих версиях обмена появились регистры сведений. С ними сложнее, но не намного:

	Запрос.Текст = 
		"ВЫБРАТЬ РАЗЛИЧНЫЕ
		|	ДокументыФизическихЛиц.Период КАК Период,
		|	ДокументыФизическихЛиц.ВидДокумента КАК ВидДокумента,
		|	ДокументыФизическихЛиц.Физлицо КАК Физлицо
		|ИЗ
		|	РегистрСведений.ДокументыФизическихЛиц КАК ДокументыФизическихЛиц
		|ГДЕ
		|	ДокументыФизическихЛиц.Физлицо В(&Физлицо)
		|	И НЕ ДокументыФизическихЛиц.ВидДокумента ЕСТЬ NULL";
	
	
	Рег=РегистрыСведений.ДокументыФизическихЛиц.СоздатьНаборЗаписей();
	Рег.Отбор.Физлицо.Использование=Истина;
	Рег.Отбор.ВидДокумента.Использование=Истина;
	Рег.Отбор.Период.Использование=Истина;
	Запрос.УстановитьПараметр("Физлицо", КомпонентыОбмена.ВыгруженныеОбъекты);
	РезультатЗапроса = Запрос.Выполнить();
	ВыборкаРесурсов=РезультатЗапроса.Выбрать();
	Пока ВыборкаРесурсов.Следующий() Цикл
		Если НЕ ЗначениеЗаполнено(ВыборкаРесурсов.ВидДокумента) Тогда
			Продолжить;
		КонецЕсли;
		Рег.Отбор.Физлицо.Значение=ВыборкаРесурсов.Физлицо;
		Рег.Отбор.ВидДокумента.Значение=ВыборкаРесурсов.ВидДокумента;
		Рег.Отбор.Период.Значение=ВыборкаРесурсов.Период;
		Рег.Прочитать();
		ОбменДаннымиXDTOСервер.ВыгрузкаОбъектаВыборки(КомпонентыОбмена, Рег);
	КонецЦикла;

В качестве отбора для документов в коде использован список ранее выгруженных физлиц из КомпонентыОбмена.ВыгруженныеОбъекты.

Завершение выгрузки

1. Запускаем обработчик "ПослеКонвертации"

	Попытка
		КомпонентыОбмена.МенеджерОбмена.ПослеКонвертации(КомпонентыОбмена);
	Исключение
		ТекстОшибки = Символы.ПС + СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(НСтр("ru = 'Событие: %1.
				|Обработчик: ПослеКонвертации.
				|
				|Ошибка выполнения обработчика.
				|%2.'"),
			КомпонентыОбмена.НаправлениеОбмена,
			ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
		ОбменДаннымиXDTOСервер.ЗаписатьВПротоколВыполнения(КомпонентыОбмена, СокрЛП(ТекстОшибки));
	КонецПопытки;

2. Закрываем теги, протоколы и файлы.

	КомпонентыОбмена.ФайлОбмена.ЗаписатьКонецЭлемента(); // Body
	КомпонентыОбмена.ФайлОбмена.ЗаписатьКонецЭлемента(); // Message
	
	// Фиксация успешного завершения обмена.
	Если КомпонентыОбмена.СостояниеОбменаДанными.РезультатВыполненияОбмена = Неопределено Тогда
		КомпонентыОбмена.СостояниеОбменаДанными.РезультатВыполненияОбмена = Перечисления.РезультатыВыполненияОбмена.Выполнено;
	КонецЕсли;
	
	ДанныеВыгрузкиXML=КомпонентыОбмена.ФайлОбмена.Закрыть();
	ОбменДаннымиXDTOСервер.ЗавершитьВедениеПротоколаОбмена(КомпонентыОбмена);

Переменная ДанныеВыгрузкиXML содержит строку с данными, которыми дальше можно распорядиться как угодно.

Обработка

В результате вокруг вышеописанной процедуры образовалась обработка.

Функционал её заимствован у бестселлера Универсальная выгрузка/загрузка данных для отличающихся конфигураций (JSON, Такси+ОФ), за что отдельное спасибо ее автору.

Обработка умеет подбирать объекты для выгрузки:

  • вручную
  • запросом (результат должен содержать колонку "ссылка")
  • по выбранному периоду журнала регистрации

И выгружать их в выбранный файл.

Файл можно загрузить в любую базу (в том числе в облаке), командой:

Загрузка данных EnterpriseData

Обработка содержит полный текст описанной здесь процедуры. Код открыт.

Тестировалась на Бухгалтерия предприятия, редакция 3.0 (3.0.71.69).
Будет работать в любой конфигурации на БСП от 3.0.2.300.

P.S.

Собственно механизм и все правила выгрузки в универсальном формате содержаться в коде конфигурации. Обработка лишь предоставляет простой доступ к ним. Поэтому, все обращения типа "почему не выгружается..." следует направлять непосредственно разработчикам.

P.P.S.

Конечно, в составе конфигураций есть универсальная обработка "ВыгрузкаЗагрузкаEnterpriseData", которая делает то же самое. Но мне показалось более изящным решением реализовать программный доступ к самому механизму обмена, чем городить обертку для универсальной обработки.

67

Скачать файлы

Наименование Файл Версия Размер
Файл обработки
.epf 19,94Kb
26.08.19
7
.epf 1.0 19,94Kb 7 Скачать

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. ids79 4112 26.08.19 18:05 Сейчас в теме
Спасибо, очень хороший пример работы с выгрузкой данных в ED. Я в своих по статьях по выгрузке и загрузке больше теорию описываю, а у Вас практический пример, это интересно.
user598128_able123; jif; +2 Ответить
2. Iyar 143 27.08.19 07:30 Сейчас в теме
(1) Спасибо на добром слове!
3. A_Max 17 30.08.19 10:21 Сейчас в теме
Лайк! Только на этой неделе сделал тоже самое для передачи одиночного объекта "сериализованного" по правилам КД3 и "десериализация" в объект при получении в другой ИБ опять же по правилам КД3. Делалось для онлайн отправки в МДМ систему через ВебСервис.

Думал причесать и тоже опубликовать. Но теперь не уверен в необходимости.

На самом деле КД 2 и 3 достаточно простые внутри и хорошо структурированы. Недостаток в реализации КД3, что не все необходимые процедуры объявлены экспортными в модуле ОбменДаннымиXDTOСервер :(
Iyar; acanta; +2 Ответить
Оставьте свое сообщение

См. также

Ошибка при вызове метода контекста (Записать): Не удалось записать: "Реестр документов"! 0

Инструменты и обработки Программист Расширение (cfe) v8::УФ УТ11 Россия Windows Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

Моё решение проблемы, связанной с обменом данными между УТ 10.3 и УТ 11.4 (перенос не только остатков, но и документов).

1 стартмани

25.09.2019    782    Kitri    0       

Преобразование XML файла в переменную структура, Загрузка в дерево значений 28

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Обмен через XML

Обработка, демонстрирующая работу процедур и функций по преобразованию XML файла в дерево значений, а также в переменную типа структура.

1 стартмани

14.09.2019    2500    5    vik070777    18       

Сериализация в XML 3

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Обмен через XML

Управляемые формы. Выгрузка/загрузка объекта в xml файл с использованием XML Сериализации.

1 стартмани

28.08.2019    881    3    gdu199    3       

Выгрузка сведений об оплате труда из ЗиКГУ 3.1 в АХД Минздрав (ЕГИСЗ) 0

Инструменты и обработки Бухгалтер Внешняя обработка (ert,epf) v8::СПР v8::УФ ЗКГУ3.0 Здравоохранение, медицина, стоматология Россия Госбюджет Зарплата Абонемент ($m) Внешние источники данных Обмен через XML

Внешняя обработка для подготовки и выгрузки данных об оплате труда из конфигурации "Зарплата и кадры государственного учреждения 3.1" в АХД Минздрав , через *.xml файл.

1 стартмани

26.06.2019    1259    3    Rtyt    0       

Документы и Справочники в JSON 58

Инструменты и обработки Системный администратор Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Обмен через XML

Пример выгрузки всех данных Документа или Справочника в JSON

1 стартмани

20.06.2019    4298    12    darkmessiahan    15       

Импорт и экспорт настроек пользователей через XML (УФ, тонкий клиент) 8

Инструменты и обработки Системный администратор Программист Расширение (cfe) v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Обмен через XML

Расширение функционала БСП типовых конфигураций по управлению настройками пользователей. Позволяет выгружать любые выбранные настройки в XML-файл, и загружать их в ту же или иную базу, с привязкой к нужному пользователю.

1 стартмани

12.06.2019    1781    20    maljaev    8       

Универсальный обмен данными XML (2.1.8) 8.3 (управляемые формы) и 8.2 (обычные формы) с возможностью подключения самописных правил и добавлением во внешние обработки 3

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Обмен через XML

Если у вас есть самописные правила, которые нужно выполнять периодически вручную (касательно документов за нужный период). Достаточно в эту обработку загрузить ваши правила в макет "ПравилаОбмена" и после подключения во внешние обработки добавить в нужный интерфейс, чтобы им могли пользоваться пользователи.

2 стартмани

07.06.2019    1669    5    Dadriel619960    0       

XDTO для чайников 110

Статья Программист Архив с данными v8 1cv8.cf Абонемент ($m) Обмен через XML

Пример использования XDTO пакетов для выгрузки документа с табличной частью.

1 стартмани

29.05.2019    9819    12    HAMMER_59    33       

Универсальный обмен данными XML (с гибкими отборами и сохранением вариантов настроек) 27

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Обмен через XML

Обработка предназначена для загрузки и выгрузки данных по правилам обмена в любых конфигурациях, реализованных на платформе 1С:Предприятие 8.3. Преимуществом перед типовой обработкой является добавленный функционал: #1. Установка произвольных фильтров на выгружаемые объекты при помощи механизма системы компоновки данных #2. Сохранение различных вариантов настроек (сохраняются правила обмена, фильтры выгрузки, параметры, настройки обработки) - что позволяет гибко настроить в базе-источнике фильтры для выгрузки объектов по различным правилам обмена для различных баз-приемников, сохранить выполненные настройки и в будущем уже пользоваться этими вариантами настроек. Проверялась на 1С:ERP Управление предприятием 2.4.7.141.

1 стартмани

29.04.2019    2963    47    sapervodichka    17       

Выгрузка и загрузка данных XML 8.3 (в полной мере возможности реализованы для версии 1С:Предприятия 8.3 выше версии 8.3.5) 18

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Обмен через XML

В этой форме всегда не хватало конструктора запросов для удобной выгрузки уникальных элементов по ссылке. Теперь он здесь есть. Как только стало возможным создавать конструктор запроса в управляемых формах, я добавил её в стандартную обработку. Необходимо напомнить, что обработка функционирует полноценно только с версии 8.3.5 1С:Предприятия 8.3.

1 стартмани

24.04.2019    2453    24    AlexandrSmith    1       

1C + Python + Django Rest Framework + Vue.js. Опыт несложной full-stack разработки 121

Статья Программист Архив с данными v8 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных Обмен через XML WEB Разработка

В этой статье мы рассмотрим путь и основные моменты создания небольшого вэб-сервиса, который мы называем "Онлайн Прайс-лист". Выгрузка из 1С, бэкенд, фронтенд, получение заказов в 1С.

1 стартмани

22.04.2019    15974    14    riposte    63       

Перенос данных с использованием XDTO 33

Статья Программист Архив с данными v8 Россия Абонемент ($m) Обмен через XML

Использование объекта типа "ОбъектXDTO" для переноса данных из одной конфигурации в другую

1 стартмани

21.04.2019    4051    4    axae    8       

Выгрузка и загрузка данных XML с гибкими отборами 34

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

Обработка выгрузки и загрузки данных через XML между идентичными конфигурациями с возможностью установки произвольных отборов на выгружаемые объекты.

1 стартмани

07.04.2019    4206    108    sapervodichka    7       

Перенос физических лиц из ЗУП 3.1 в ЗУП 3.1 4

Инструменты и обработки Программист Бухгалтер Внешняя обработка (ert,epf) v8::СПР v8::УФ ЗУП3.x Россия БУ Управление персоналом (HRM) Абонемент ($m) Обмен через XML Обработка справочников

Обработка переноса Физических лиц из ЗУП 3.1 в ЗУП 3.1. Позволяет перенести физических лиц из базы в базу со всеми учетными данными (Воинский учет, Семья и т.д.). Теперь можно переносить множество объектов. Тестировал на Зарплата и управление персоналом, редакция 3.1 (3.1.9.108).

1 стартмани

18.03.2019    2031    19    MihasMSK    23       

Универсальный обмен данными XML (2.1.8) с отбором в управляемых формах для 1С: Предприятие 8.3 5

Инструменты и обработки Системный администратор Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

Данная обработка предназначена для переноса данных из конфигурации на платформе 1С8 в другую конфигурацию на платформе 1С8, по правилам обмена. Для конфигураций, которые используют управляемые формы. Сделана на базе типовой обработки Универсальный обмен данными XML (2.1.8). Добавлена возможность отбора объектов при выгрузке.

1 стартмани

15.03.2019    3206    48    aapost    0       

Перенос настроек пользователей между базами через XML (УФ) 3

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ УТ11 Россия Windows Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

Возникла необходимость переноса настроек пользователей в другую базу. Была найдена обработка https://infostart.ru/public/685815/, но в ней не было возможности интерактивного выбора каталога. Эта функция и была добавлена.

1 стартмани

13.03.2019    1846    11    ch_igor    0       

Обработка для выгрузки и загрузки данных XML 8.3. С отбором, предпросмотром данных и сохранением настроек 10

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Универсальные обработки Обмен через XML

Обработка Выгрузки и загрузки данных XML 8.3 на управляемых формах. Универсальная обработка "Выгрузка и загрузка данных XML" производит полную или частичную выгрузку данных информационной базы в файл в формате XML. Впоследствии этот файл может быть загружен в информационную базу с помощью этой же обработки. Формат файла выгрузки отличается от формата файла, создаваемого при выгрузке по плану обмена, заголовочной частью. (Описание взято с ИТС)

1 стартмани

07.03.2019    4069    56    Gmix    1       

Обработка регистрации объектов по не найденным ("битым") ссылкам в базе приемнике через COM подключение 2

Инструменты и обработки Системный администратор Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Универсальные обработки Обмен через XML Перенос данных из 1C8 в 1C8

Обработка позволяет регистрировать в выбранном узле плана обмена объекты, которые не найдены в базе приемнике ("Объект не найден"). Управляемые формы. 1С 8.3

1 стартмани

02.03.2019    1942    3    vowg    0       

Пакетное чтение выписок из Росреестра (в виде архивов) и перевод их в формат EXCEL 0

Инструменты и обработки Программист Бизнес-аналитик Пользователь Внешняя обработка (ert,epf) v8::УФ УУ Абонемент ($m) Загрузка и выгрузка в Excel Обмен через XML

Обработка позволит массово читать архивы выписок Росреестра из формата XML, преобразовывать их в формат EXCEL, Может быть использована для получения информации о собственниках.

1 стартмани

17.02.2019    2331    4    solutioncp24    8       

Ручная выгрузка и загрузка данных через универсальный обмен данными с настройками (расширение, платформа 8.3+) 46

Инструменты и обработки Программист Архив с данными v8 Розница УНФ ERP2 БП3.0 УТ11 КА2 ЗУП3.x Абонемент ($m) Обработка документов Обработка справочников Обмен через XML Перенос данных из 1C8 в 1C8

Данное расширение (не требует изменения конфигураций) служит как надстройка для конфигураций, у которых обмен между базами происходит через универсальный формат (EnterpriseData), с использованием стандартных правил конвертации, которые уже есть в конфигурации. Интерфейс адаптирован для простых пользователей, сделан общий отбор по Организации для всех документов, имеется пару настроек для передачи в параметры конвертации, которые расположены в общем модуле конфигураций, а так же есть возможность выбора запуска - в фоне или в текущем сеансе. Теперь не нужно настраивать обмен между базами, для того чтоб просто перенести нужные документы. Подходит точно для УТ 11.4, БП 3.0.67, КА 2.4.5, Розница 2.2.9 (Обновление 1.2 от 02.03.2019)

2 стартмани

19.01.2019    7220    84    hakerxp    8       

Универсальный обмен данными в формате XML (2.1.8) 8.3 УФ с отбором и без модальности 16

Инструменты и обработки Системный администратор Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Обмен через XML

К типовой обработке "Универсальный обмен данными в формате XML" добавлены отбор и возможность работать в конфигурациях с отключенным режимом модальности.

1 стартмани

07.11.2018    10133    215    nicxxx    5       

SOAP для чайников 86

Инструменты и обработки Программист Конфигурация (md, cf) v8 1cv8.cf Абонемент ($m) Обмен через XML WEB

Немножко про SOAP сервис. И пример работы с подключением и получением данных по SOAP за 5 минут.

1 стартмани

05.09.2018    18542    25    dusha0020    18       

Обработка для выгрузки из 1С:Розница 2.2 для кассового сервера Меркурий ККТ 0

Инструменты и обработки Системный администратор Бухгалтер Внешняя обработка (ert,epf) v8 v8::УФ Розница Россия БУ УУ Кассовые операции Розничная торговля Абонемент ($m) Обмен через XML ККМ

Данная обработка будет полезна всем пользователям ККТ Меркурий с подключенным облачным кассовым сервером. Обработка производит выгрузку номенклатуры из 1с:Розница 2.2 в файл формата XML для последующей загрузки в облачный сервер Меркурий.

1 стартмани

30.07.2018    4873    6    tara84    10       

Анализ XDTO пакетов: вывод свойств и их параметров 7

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Инструментарий разработчика Универсальные обработки Обмен через XML WEB

Вывод информации о свойствах любого объекта из пакета XDTO в таблицу с выделением обязательных полей.

1 стартмани

04.06.2018    4978    2    s_vidyakin    7       

Обработки (Формата обмена) для загрузки платежных поручений в 1С 8.3 Бухгалтерия для Украины 2.0 (DBF, XML, CSV) 9

Инструменты и обработки Бухгалтер Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Украина БУ Банковские операции Абонемент ($m) Файловые протоколы обмена, FTP Обмен с банком Обмен через XML

Обработки формата обмена, которые производят чтение файлов выгрузки из КБ, через основную обработку от АББИ Украина для БУ 2.0 Обработка тестировалась на "Бухгалтерия для Украины, редакция 2.0. релиз (2.0.8.2)".

1 стартмани

09.05.2018    14897    94    zVORTEXz    24       

Простой эмулятор вызова веб-сервиса 1С с просмотром результата 24

Инструменты и обработки Системный администратор Программист Внешняя обработка (ert,epf) v8 1cv8.cf Россия Абонемент ($m) Обмен через XML WEB

Последнее время все чаще сталкиваюсь с разработкой веб-сервисов средствами 1С. Для ускорения разработки и отладки написал внешнюю обработку. На какой-то сверх-крутой функционал она не претендует, но, может, кому-то пригодится.

1 стартмани

24.04.2018    7371    17    anvolkov1cbit    9       

Выгрузка сотрудников, их должностей и подразделений ЗУП 3.х -> БП 3.0 (в т.ч. по расписанию регламентно) 5

Инструменты и обработки Системный администратор Бухгалтер Внешняя обработка (ert,epf) v8::БУ v8::СПР v8::УФ БП3.0 ЗУП3.x БУ Управление персоналом (HRM) Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

В штатном обмене Зарплата и управление персоналом, редакция 3.1 -> Бухгалтерия предприятия, редакция 3.0 при выгрузке данных по зарплате сводно не проходит информация по должностям и подразделениям сотрудников. Результат - в бухгалтерии не распечатать например авансовый отчет с данными сотрудника. Когда ко мне обратилась третья дружественная организация с этой проблемой, то стало понятно - для методистов 1С это не баг, а фича. Думаю под напором бухгалтеров 1С допилит обмен или может я чего не знаю, а пока прошу под кат...

4 стартмани

12.04.2018    12673    128    capitan    16       

Выгрузка и загрузка данных XML (по выбранным организациям) 2

Инструменты и обработки Системный администратор Внешняя обработка (ert,epf) v8::УФ 1cv8.cf Россия Абонемент ($m) Обмен через XML

Стандартная обработка БСП - выгрузка / загрузка идентичных конфигураций через xml в управляемом интерфейсе - с возможностью группового отбора данных по организациям.

1 стартмани

27.03.2018    7548    51    beardlyhich    11       

Выгрузка начисленных/удержанных алиментов для банка в текстовом и XML формате Сбербанка 3

Инструменты и обработки Бухгалтер Внешняя обработка (ert,epf) v8::СПР v8::УФ ЗУП3.x Россия БУ Банковские операции Зарплата Абонемент ($m) Обмен с банком Обмен через XML

Обработка позволяет быстро сформировать файл для перечисления полагающихся алиментов на карточку получателя алиментов.

1 стартмани

20.03.2018    7038    58    Mirage78    19       

Правила конвертации документов ЗУП 2.5 - ЗУП 3.1 44

Инструменты и обработки Системный администратор Программист Бухгалтер Документ XML v8 v8::СПР ЗУП2.5 ЗУП3.x Россия БУ Зарплата Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

Правила конвертации документов ЗУП 2.5 - ЗУП 3.1. Позволяют вести параллельную работу в базах ЗУП редакций 2,5 и 3.1.

10 стартмани

06.03.2018    24369    123    kostya_whiskas    23       

Организация обмена с базой филиала (розничного магазина) в торговой сети через XML (универсальный обмен) 70

Статья Программист Архив с данными v8 КД УТ11 Розничная и сетевая торговля (FMCG) Розничная торговля Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

В статье по шагам рассматривается создание обмена между центральной базой и базами филиалов на базе конфигурации УТ 11. Для решения поставленной задачи было решено не использовать РИБ, т.к. требуется односторонний обмен ограниченным набором данных, к тому же по определенным условиям. Обмен реализован на основе типовой синхронизации на основе универсального обмена в формате EnterpriseData. Данная публикация может быть полезна внедренцам, которые работают с торговыми сетями, в том числе по модели франчайзинга.

1 стартмани

26.02.2018    25019    14    Kutuzov    18       

Создание в 1С 7.7 XML в формате EnterpriseData (универсальный формат обмена), версия 1.5. Инструкции и примеры переноса данных из устаревшей конфигурации 1С 7.7 в любую современную 1С 8.3, поддерживающую EnterpriseData, через Конвертацию данных 3 31

Инструменты и обработки Программист Внешняя обработка (ert,epf) v7.7 v8 1cv7.md Россия Абонемент ($m) Перенос данных из 1С7.7 в 1C8.X Обмен через XML

Воспользоваться современным средством переноса данных "Конвертация данных 3.0.5.3" можно только выгрузив из системы - источника данных XML в формате обмена данными EnterpriseData. В этой публикации можно скачать приемы выгрузки из 1С 7.7 универсального формата обмена для Конвертации данных 3. Выполняем перенос данных из «1С:Предприятие 7.7» в «1С:Предприятие 8.3». Используем Конвертацию данных КД 3.0 из 1c 7.7 --> 1С 8.3. На первой стадии еще не опубликовано иного способа подложить файл для Конвертации данных 3 кроме как сформировать его вручную, постараемся решить данную проблему.

1 стартмани

26.02.2018    25996    45    ksnik    3       

Загрузка Показателя в документ Данные для расчета зарплаты 4

Инструменты и обработки Бухгалтер Внешняя обработка (ert,epf) v8::СПР v8::УФ ЗУП3.x БУ Зарплата Абонемент ($m) Обработка документов Обмен через XML

Обработка позволяет загрузить значения разовых показателей по сотрудникам из xml файла.

1 стартмани

15.02.2018    6078    10    ivNatalika    1       

Пример заполнения/создания файла XML из XSD схемы, используя XDTO 128

Статья Программист Документ XML v8 1cv8.cf Абонемент ($m) Обмен через XML WEB

Добрый день, коллеги! Наконец-то дошли руки написать сию статью. Хочу поделиться своим опытом по разбору xsd схемы используя Фабрику XDTO, а также связанным с этим XML файлом. Думаю, наверняка кому-то понадобится.

1 стартмани

21.12.2017    28642    40    sandybaev    23       

Правила переноса документов из ЗУП 2.5 в ЗУП 3.1 33

Инструменты и обработки Программист Документ XML v8 v8::СПР ЗУП3.x Россия БУ Windows Зарплата Управление персоналом (HRM) Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

Перенос документов из ЗУП 2.5 в ЗУП 3.1 - позволяет снизить объем работ при опытной эксплуатации ЗУП 3.1 параллельно с ЗУП 2.5.

1 стартмани

04.12.2017    23280    486    AntonH851    38       

Обработка загрузки данных по инвентарной картотеке из xml файла, экспортированного из ПО Парус 7.х, в справочник Основные Средства для Бухгалтерии Государственного Учреждения версии 2.0.x.х 1

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ БГУ Россия БУ Учет ОС и НМА Абонемент ($m) Обмен через XML

Обработка загружает данные из XML файла, выгруженного в системе Парус 7, и визуально представляет иерархию полученных данных в виде дерева значений. Позволяет получить в табличные формы данные по позициям Инвентарной картотеки и значения сопутствующих справочников. В Бухгалтерии Государственного Учреждения версии 2.0.х.х создать: элементы справочника Основные Средства, документы Ввод Начальных Остатков ОС.

1 стартмани

03.12.2017    6715    10    vagipov    0       

Выгрузка декларации в МосКомСтройИнвест (МКСИ) 3

Инструменты и обработки Программист Бухгалтер Внешняя обработка (ert,epf) v8::УФ 1cv8.cf Недвижимость, риэлторская деятельность Россия Абонемент ($m) Загрузка и выгрузка в Excel Обмен через XML

Данная обработка позволяет выгрузить самую бОльшую часть декларации в МосКомСтройИнвест (по помещениям) из Excel если он заполнен в соответствии с представленным форматом. Что позволит значительно сэкономить время при заполнении.

10 стартмани

30.11.2017    5668    3    tristarr1    0       

Настройка синхронизации подразделений для БП 3.0 и ЗУП 3.1 6

Инструменты и обработки Системный администратор Программист Внешняя обработка (ert,epf) v8::УФ 1cv8.cf ЗКГУ3.0 БП3.0 Зарплата Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

Настройка синхронизации для сложной организационной структуры. Например, в разных базах есть одинаковые наименования подразделений и подчинены разным родителям.

1 стартмани

14.11.2017    14681    59    grinder    24       

Загрузка справочников из XML 6

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Обработка справочников Обмен через XML

При разработке новой базы была поставлена задача - выгрузить из файла xml данные в самописный справочник. Справочник содержит табличные части и возможность выбора типа объекта (в моём случае это были "Физ.лицо" и "Организация"). Тестировалось на 8.3, управляемые формы, конфигурация не важна, так как используются метаданные. Разработано для управляемых форм.

1 стартмани

09.11.2017    7321    19    PanKir    4       

Механизмы и транспорт обмена данными. Пример создания в КД 2.1 правил обмена данными ЗУП 2.5 -> БП 3.0. Выгрузка ведомостей и банковских счетов. Передача параметров обмена из Источника в Приемник. ВыгрузитьПоПравилу(). ПередатьОдинПараметрВПриемник(). 37

Статья Программист Документ XML v8 ЗУП2.5 КД БП3.0 Абонемент ($m) Обмен через XML Перенос данных из 1C8 в 1C8

В статье рассказываю: 1) о механизмах и транспорте обмена данными, где одной из сторон обмена выступает конфигурация на базе 1С, и о том, какой транспорт и в каких случаях лучше использовать 2) о решении задачи выгрузки данных документа «Зарплата к выплате организаций» (с выгрузкой банковский счетов физ лиц документа) из ЗУП 2.5.123.1 (далее Источник) в БП КОРП 3.0.52.39 (далее Приемник) путем создания правил обмена данными с использованием конфигурации «Конвертация данных» (далее просто КД) ред. 2.1.8.2. для (далее ЗкВО) 3) о тестирование полученных правил обмена данными.

1 стартмани

03.11.2017    20783    7    RailMen    5