Внешние печатные формы для нетиповой конфигурации (управляемое приложение)

09.04.13

Учетные задачи - Печатные формы

Возникла необходимость использования в не типовой конфигурации (управляемое приложение) механизма внешних печатных форм.

Сразу оговорюсь, что статья начального уровня и далее последует “изобретение велосипеда”, который не подойдет для типовых конфигураций.

Скачать файлы

Наименование Файл Версия Размер
Выгрузка каркасной конфигурации (*.dt)
.dt 54,91Kb
33
.dt 54,91Kb 33 Скачать

Варианты решения задачи:

  1. реализовать механизм работы с внешними печатными формами самостоятельно;
  2. включить в собственную разработку некоторые подсистемы конфигурации «Библиотека стандартных подсистем».

 

1)      Попробуем реализовать работу с внешними печатными формами самостоятельно

 Введем ограничения:

  • - поддерживаем только печатные формы;
  • - автоматическая отправка печати на принтер не поддерживается;
  • - объекты печати — справочники и документы;
  • - команды вызова печати дополнительно не настраиваются;
  • - используется только безопасный режим работы;
  • - механизм создания внешних печатных форм будет упрощен относительно методики создания внешних печатных форм для типовых конфигураций.

Для такого варианта реализации нам понадобятся:

  • - справочник для хранения внешних печатных форм и установки соответствия объектам;
  • - общая команда для вызова списка печатных форм;
  • - общая форма, для выбора печатных форм;
  • - набор модулей для обеспечения функционирования механизма;
  • - описание создания обработки внешней печатной формы.

 

Создаем справочник ДополнительныеПечатныеФормы

Реквизиты:

-        ХранилищеПечатнойФормы, тип ХранилищеЗначения;

-        ДатаЗагрузки, тип дата;

-        Комментарий, тип строка;

-        КомментарийКФайлу, тип строка;

-        Табличная часть ОбъектыПечати:

-         Представление, тип строка;

-        СсылкаОбъекта, составной тип ДокументСсылка, СправочникСсылка.

В справочнике необходимо указать типы объектов метаданных, для которых будет доступна печатная форма, и загрузить обработку внешней печатной формы в справочник.

 

Выбор типов объектов для печати:

 Добавим реквизит формы спОбъектовПечати типа СписокЗначений.

В обработчике формы ПриСозданииНаСервере заполним список:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	СпОбъектыПечати = ПолучитьСписокОбъектов();
	АдресВнешнейПечатнойФормы = ""; 
КонецПроцедуры

&НаСервереБезКонтекста
Функция ПолучитьСписокОбъектов()
	СписокОбъектов = Новый СписокЗначений;
	Для каждого спр из Метаданные.Справочники Цикл
		СписокОбъектов.Добавить(Справочники[спр.Имя].ПустаяСсылка(), спр.ПолноеИмя());
	КонецЦикла;
	Для каждого спр из Метаданные.Документы Цикл
		СписокОбъектов.Добавить(Документы[спр.Имя].ПустаяСсылка(), спр.ПолноеИмя());
	КонецЦикла;
	Возврат СписокОбъектов;
КонецФункции

Импорт внешней печатной формы в справочник:

Добавим реквизит формы АдресВнешнейПечатнойФормы, тип - строка.

Организуем выбор файла внешней печатной формы и помещаем его во временное хранилище.

&НаКлиенте
Процедура ИмпортПечатнойФормы(Команда)
	ЗначениеВозврата = ВыбратьФайл("открыть");
	Если ЗначениеВозврата = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	ИмяФайлаВнешнейОбработки = ЗначениеВозврата.ПолноеИмяФайлаОбработки;
	
	Если НЕ ЗначениеЗаполнено(Объект.Наименование) Тогда
		Объект.Наименование = СокрЛП(ЗначениеВозврата.ИмяФайлаОбработки);
	КонецЕсли;
	
	Объект.КомментарийКФайлу = ЗначениеВозврата.КомментарийКФайлу;
	Объект.ДатаЗагрузки = ЗначениеВозврата.ДатаЗагрузки;
	
	Если НЕ ПоместитьФайл(АдресВнешнейПечатнойФормы, ИмяФайлаВнешнейОбработки, , Ложь, УникальныйИдентификатор) Тогда		
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Ошибка импорта внешней печатной формы!";
		Сообщение.Поле = "КомментарийКФайлу";
		Сообщение.УстановитьДанные(Объект);
		Сообщение.Сообщить();
		Возврат;
	КонецЕсли;
КонецПроцедуры
 

Запись в справочник:

Получаем из временного хранилища данные обработки и записываем их в справочник в обработчике ПередЗаписьюНаСервере():

&НаСервере
Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
	Если АдресВнешнейПечатнойФормы <> "" Тогда
		ДанныеПечатнойФормы = ПолучитьИзВременногоХранилища(АдресВнешнейПечатнойФормы);
		ТекущийОбъект.ХранилищеПечатнойФормы = Новый ХранилищеЗначения(ДанныеПечатнойФормы , Новый СжатиеДанных(9));
	КонецЕсли; 
КонецПроцедуры


Создаем общую команду

В конфигураторе создаем новую общую команду  ДополнительныеПечатныеФормы. Устанавливаем свойства:

  • группа = Командная панель формы.Важное;
  • тип параметра команды = составной тип, отмечаем справочники и документы, для которых будет доступна данная команда;
  • режим использования параметра = множественный (устанавливаем для возможности печати для списка объектов).

Также создался модуль команды, в котором будем вызывать выбора печатных форм:

&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
	ДополнительныеПечатныеФормыКлиент.ОткрытьФормуКомандДополнительныхПечатныхФорм(ПараметрКоманды, ПараметрыВыполненияКоманды);
КонецПроцедуры

В методе ОткрытьФормуКомандДополнительныхПечатныхФорм() подготовим параметры, и откроем форму со списком печатных форм:

Функция ОткрытьФормуКомандДополнительныхПечатныхФорм(ПараметрыКоманды, ПараметрыВыполненияКоманды) Экспорт
	ПараметрыКомандыСписок = Новый СписокЗначений;
	
	Если ТипЗнч(ПараметрыКоманды) = Тип("Массив") Тогда 
		ПараметрыКомандыСписок.ЗагрузитьЗначения(ПараметрыКоманды);
		СсылкаОбъекта = ДополнительныеПечатныеФормы.ПолучитьПустуюСсылкуОбъекта(ПараметрыКоманды[0]);
	Иначе
		ПараметрыКомандыСписок.Добавить(ПараметрыКоманды);
		СсылкаОбъекта = ДополнительныеПечатныеФормы.ПолучитьПустуюСсылкуОбъекта(ПараметрыКоманды);
	КонецЕсли;
	
	Параметры = Новый Структура("ОбъектыПечати, СсылкаОбъекта", ПараметрыКомандыСписок, СсылкаОбъекта);
		
	ОткрытьФормуМодально("ОбщаяФорма.ДополнительныеПечатныеФормы", Параметры, ПараметрыВыполненияКоманды.Источник); 
КонецФункции


Создаем общую форму

Создаем новую общую форму типа «произвольная форма». Форма будет принимать параметры: СсылкаОбъекта (будет содержать тип объекта, выводимого на печать) и ОбъектыПечати (список объектов для печати).

Добавляем реквизиты формы:

  • - СсылкаОбъекта, составной тип СправочникСсылка, ДокументСсылка;
  • - ОбъектыПечати, тип СписокЗначений;
  • - ПечатныеФормы, тип таблица значений, таблица с перечнем печатных форм

В таблицу ПечатныеФормы будем выводить список встроенных и внешних печатных форм для данного типа объектов. Также предоставим возможность выбирать необходимые формы для печати установкой флагов в строках таблицы.

Таблица будет содержать колонки:

  • - Ссылка, тип СправочникСсылка.ДополнительныеПечатныеФормы;
  • - Представление, тип строка;
  • - Отметка, тип булево;
  • - ДопФормы, тип булево, будет показывать, что в строке дополнительная (внешняя) печатная форма;
  • - Макет, строка, будет содержать имя встроенного макета.

При создании на сервере заполним таблицу печатных форм:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
СсылкаОбъекта = Параметры.СсылкаОбъекта;
ОбъектыПечати.ЗагрузитьЗначения(Параметры.ОбъектыПечати.ВыгрузитьЗначения());
	Если СсылкаОбъекта <> Неопределено Тогда
	    ЗначениеВРеквизитФормы(ОбычныеПечатныеФормы.ДополнитьТаблицуЗаполненияМакетамиМетаданныхОбъекта(
ДополнительныеПечатныеФормы.ПолучитьСписок(СсылкаОбъекта), СсылкаОбъекта), "ПечатныеФормы"); КонецЕсли; КонецПроцедуры

Также можно добавить на форму команды «Отметить все» и «Снять отметки» для группового выделения всех печатных форм и снятия всех отметок.

Теперь реализуем обработку печати выбранных печатных форм для переданных объектов.

Получим из таблицы отмеченные флажками печатные формы. Далее, обходя в цикле выбранные печатные формы, будем выполнять на сервере печать списка объектов. В качестве результата получим массив табличных документов, для которого и организуем вывод на экран.

&НаКлиенте
Процедура ЗапуститьНаПечать(Команда)
	МассивПФ = ПечатныеФормы.НайтиСтроки(Новый Структура("Отметка", Истина));
	Если МассивПФ.Количество() = 0 Тогда
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Печатные формы не выбраны!";
		Сообщение.Сообщить();
	КонецЕсли;
	
	ОбъектыПечатиМассив = ОбъектыПечати.ВыгрузитьЗначения();
	
	Для каждого текПФ из МассивПФ Цикл
		Если текПФ.ДопФорма Тогда
			МассивТабДок = ДополнительныеПечатныеФормы.ЗапуститьПечать(текПФ.Ссылка, ОбъектыПечатиМассив);
		Иначе
			МассивТабДок = ОбычныеПечатныеФормы.ЗапуститьПечать(текПФ.Макет, ОбъектыПечатиМассив);
		КонецЕсли;		

                ВывестиТабличныеДокументы(МассивТабДок);
	КонецЦикла;
	
	Закрыть();
КонецПроцедуры

&НаКлиенте
Процедура ВывестиТабличныеДокументы(МассивТД)
	Для каждого тд из МассивТД Цикл
		тд.Показать(тд.ИмяПараметровПечати, , Ложь);
	КонецЦикла;
КонецПроцедуры

 

Общие модули

Создаем общие модули: ОбычныеПечатныеФормы (сервер, вызов сервера), ДополнительныеПечатныеФормы (сервер, вызов сервера) и ДополнительныеПечатныеФормыКлиент (клиент).

Опишем методы ЗапуститьПечать() модулей обычных и дополнительных печатных форм. Более детально с модулями можно ознакомиться в конфигурации.

Модуль ОбычныеПечатныеФормы:

Функция ЗапуститьПечать(ИмяМакета, ОбъектыПечатиМассив) Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	
	МассивТабДок = Новый Массив;
	Для каждого СсылкаОбъектаНазначения из ОбъектыПечатиМассив Цикл
		Попытка
			МетаданныеОбъекта = СсылкаОбъектаНазначения.Метаданные();		
				
			Если Метаданные.Документы.Содержит(МетаданныеОбъекта) Тогда
				новыйТабДок = Документы[МетаданныеОбъекта.Имя].Печать(СсылкаОбъектаНазначения, ИмяМакета);
			ИначеЕсли Метаданные.Справочники.Содержит(МетаданныеОбъекта) Тогда
				новыйТабДок = Справочники[МетаданныеОбъекта.Имя].Печать(СсылкаОбъектаНазначения, ИмяМакета);
			Иначе
				новыйТабДок = Новый ТабличныйДокумент;
			КонецЕсли;
		Исключение
			ТекстОшибки = "Ошибка вывода <" + Строка(СсылкаОбъектаНазначения) 
				+ "> в макет <" + ИмяМакета + ">: " + Символы.ПС + ОписаниеОшибки();
			
			новыйТабДок = ВыводОшибкиВМакет(ТекстОшибки);
		КонецПопытки;
		
		МассивТабДок.Добавить(новыйТабДок);
	КонецЦикла;
	
	Возврат МассивТабДок;
КонецФункции

Функция ВыводОшибкиВМакет(ТекстОшибки) Экспорт
	ТабДок = Новый ТабличныйДокумент;
	
	Макет = ПолучитьОбщийМакет("ВыводОшибкиВыполнения");
	Область = Макет.ПолучитьОбласть("ВыводОшибки");
	Область.Параметры.ТекстОшибки = ТекстОшибки;
	
	ТабДок.Вывести(Область);
	
	Возврат ТабДок;
КонецФункции

Модуль ДополнительныеПечатныеФормы:

Функция ЗапуститьПечать(ДополнительнаяПечатнаяФорма, ОбъектыПечатиМассив) Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	
	ВнешняяОбработка = ПолучитьОбъектВнешнейПечатнойФормы(ДополнительнаяПечатнаяФорма);
	
	Попытка
		МассивТабДок = ВнешняяОбработка.Печать(ОбъектыПечатиМассив);
	Исключение
		ТекстОшибки = "Ошибка вывода дополнительной печатной формы <" + Строка(ДополнительнаяПечатнаяФорма) 
			+ ">: " + Символы.ПС + ОписаниеОшибки();
			
		новыйТабДок = Новый ТабличныйДокумент;
		МассивТабДок = Новый Массив;
		МассивТабДок.Добавить(ОбычныеПечатныеФормы.ВыводОшибкиВМакет(новыйТабДок));
	КонецПопытки;
	
	Возврат МассивТабДок;
КонецФункции

Функция ПолучитьОбъектВнешнейПечатнойФормы(ДополнительнаяПечатнаяФормаСсылка) Экспорт
	
	ДополнительнаяПечатнаяФорма = ДополнительнаяПечатнаяФормаСсылка.ПолучитьОбъект();
	
	ДвоичныеДанныеПФ = ДополнительнаяПечатнаяФорма.ХранилищеПечатнойФормы.Получить();
	
	ИмяВременногоФайла = ПолучитьИмяВременногоФайла("epf");
	
	ДвоичныеДанныеПФ.Записать(ИмяВременногоФайла);
	
	Возврат ВнешниеОбработки.Создать(ИмяВременногоФайла);
КонецФункции

Замечание: в случае возникновения ошибок печати, сообщения выводятся в табличный документ.

 

Описание создания внешней печатной формы

Важно: подготовка внешних печатных форм для типовых конфигураций отличается от приводимого упрощенного примера.

Внешняя печатная форма будет представлять собой внешнюю обработку *.epf, содержащую макет и экспортную функцию Печать(МассивСсылок) в модуле объекта.

Функция Печать() вызывается из метода ЗапуститьПечать() модуля ДополнительныеПечатныеФормы. Она принимает массив ссылок на объекты, для которых необходимо получить печатные формы.

Схема работы: новый табличный документ создается для каждой ссылки, область печати заполняется данными объекта и добавляется в табличный документ. В качестве результата возвращается массив готовых печатных форм (табличных документов).

Функция Печать(МассивСсылокНаОбъекты) Экспорт
	МассивТабДок = Новый Массив;

	Для каждого СсылкаОбъекта из МассивСсылокНаОбъекты Цикл
		табДок = Новый ТабличныйДокумент;
		МакетДляПечати 	= ЭтотОбъект.ПолучитьМакет("Макет");
		СтруктураДанных = ЗаполнитьСтруктуруДанных(СсылкаОбъекта);
	
		ОбластьПечати = МакетДляПечати.ПолучитьОбласть("Строка");
		Если СтруктураДанных <> Неопределено Тогда
			ЗаполнитьЗначенияСвойств(ОбластьПечати.Параметры, СтруктураДанных);
		КонецЕсли;
	
		табДок.Вывести(ОбластьПечати);
		
		табДок.Защита = Истина;
		табДок.ОтображатьСетку = Ложь;
		табДок.ОтображатьЗаголовки = Ложь;
		табДок.ИмяПараметровПечати = ЭтотОбъект.Метаданные().Синоним;
		табДок.ОриентацияСтраницы = ОриентацияСтраницы.Ландшафт;
		
		МассивТабДок.Добавить(табДок);
	КонецЦикла;
	
	Возврат МассивТабДок;
КонецФункции

Пример:

В тестовой конфигурации создан документ Письмо, для которого подготовлены несколько печатных форм для печати конвертов. Каждая печатная форма соответствует одному стандартному размеру конверта.

Таким образом, воспользовавшись пакетной печатью, можно получить сразу несколько печатных форм для разных типов конвертов как для одного, так и для нескольких писем одновременно.

 

2)     Интеграция БСП

 

Подробно процесс внедрения БСП можно найти обратившись к документации http://its.1c.ru/db/bspdoc.

Замечу только, что нам понадобится подсистема ДополнительныеОтчетыИОбработки из группы стандартных подсистем.

Также обязательными, для включения в собственную конфигурацию, будут подсистемы:

  • - базовая функциональность;
  • - контактная информация;
  • - настройка порядка элементов;
  • - обновление версии ИБ;
  • - получение файлов из интернет;
  • - пользователи.

 

Описание создания типовой внешней печатной формы

 Как и в приведенном выше примере, нам потребуется создать внешнюю обработку *.epf.

Общая структура модуля обработки:

  • * обязательная сервисная экспортная функция СведенияОВнешнейОбработке(). Вызывается в основной программе при регистрации обработки в информационной базе. В этой функции необходимо указать, для каких объектов предназначена данная обработка, указать ее вид (печатная форма, обработка и т.д.), определить команды для вызова печати и указать дополнительную информацию.

Функция возвращает структуру параметров регистрации:

  • -        Вид – определяет вид регистрируемой обработки, например, "ПечатнаяФорма";
  • -        Назначение – массив, определяет набор объектов, для которых предназначена обработка, например:
Назначения = Новый Массив;
Назначения.Добавить("Документ.ЗаказПокупателя");
ПараметрыРегистрации.Вставить("Назначение", Назначения);
  • -        Наименование – наименование обработки;
  • -        Версия – строка с номером версии обработки, например, “1.0”;
  • -        БезопасныйРежим – флаг использования обработки в безопасном режиме;
  • -        Информация – примечание, дополнительная информация по обработке.
  • * обязательная экспортная процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода).

Используется для формирования печатных форм объектов.

Принимает параметры:

  • -        МассивОбъектов – список объектов ссылочного типа для формирования печатных форм.

Возвращает параметры:

  • -        КоллекцияПечатныхФорм – таблица значений, содержащая сформированные табличные документы;
  • -        ОбъектыПечати – список объектов печати;
  • -        ПараметрыВывода – параметры сформированных табличных документов.

 

  • * вспомогательные методы заполнения параметров, таблиц и другие.

 

Замечания:

Предложенная реализация механизма внешних печатных форм далека от идеала, обладает значительным количеством ограничений и некоторыми недостатками по сравнению с реализацией в БСП. Например, для подключения внешней печатной формы новому типа объекта необходимо будет изменить тип параметра общей команды «ДополнительныеПечатныеФормы».

Но, тем не менее, является достаточно простым и работоспособным примером работы с внешними печатными формами в управляемом приложении.

См. также

SALE! 25%

Infostart PrintWizard

Пакетная печать Печатные формы Инструментарий разработчика Платформа 1С v8.3 Запросы 1С:Зарплата и кадры бюджетного учреждения 1С:Конвертация данных 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Платные (руб)

Инструмент, позволяющий абсолютно по-новому взглянуть на процесс разработки печатных форм. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и "прозрачность" разработки, а также навести порядок в многообразии корпоративных печатных форм.

18000 15300 руб.

06.10.2023    7302    22    6    

39

Универсальная печать по шаблонам Word (Печать договоров из 1С БП 3, УНФ 1.6, ЗУП 3, УТ 11, КА 2, ERP 2, ДО 3)

Печатные формы Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 1С:ERP Управление предприятием 2 Платные (руб)

Научите вашу 1C печатать из 1С в файл Word (Например: трудовые договоры, договоры с контрагентами, спецификации, дополнительные соглашения, приказы, коммерческие предложения, акты, накладные, карточки партнера или любого справочника и многие другие). Универсальная печать предназначена для формирования печатных форм на основе шаблонов в формате Word из любой конфигурации 1С. С помощью данного инструмента можно самостоятельно заполнить шаблон реквизитами справочника или документа 1С и сформировать печатные формы на основании ссылки на любой объект.

5400 руб.

08.10.2019    42700    144    88    

134

SALE! 25%

УТ 11, КА 2, ERP 2: Настраиваемые под каждую организацию печать и подпись ответственных лиц в печатных формах (ТОРГ-12, Счёт-фактура, УПД, УКД, Заказ клиента, Акт сверки, М-15 и др.)

Печатные формы Взаиморасчеты Оптовая торговля Производство готовой продукции (работ, услуг) Акт сверки Оперативный учет Управляемые формы 1С:Управление торговлей 11 Россия Бухгалтерский учет Управленческий учет Платные (руб)

Задайте для каждой организации свою печать и для каждого физического лица свою подпись. Выберите в документе печатную форму "... с печатью и подписью" - и автоматически сформируется табличный документ с печатью и подписями той организации и ответственных лиц, которые указаны в документе.

12000 9000 руб.

13.03.2018    56455    179    76    

112

Печатные формы КС-2 и КС-3 в "1С:Бухгалтерия 3.0"

Печатные формы Производство готовой продукции (работ, услуг) Платформа 1С v8.3 Бухгалтерский учет Оперативный учет 1С:Бухгалтерия 3.0 Строительство Россия Бухгалтерский учет Платные (руб)

Откройте для себя заполнение КС-2 и КС-3 в "1С:Бухгалтерия 3.0". Вы получаете удобство, скорость и систему, чтобы заполнить, распечатать и сохранить формы КС-2 и КС-3 из документов "Оказание производственных услуг" или "Реализация товаров услуг". Вы можете заполнить дополнительную информацию о материалах из документов "Требование-накладная" и указать сведения, которые не предусмотрены типовой конфигурацией "1С:Бухгалтерия 3.0". Так же доступно множество настроек для формирования КС-2 и КС-3.

3240 руб.

13.02.2019    88011    388    44    

371

Печать актов МХ-1, МХ-3 в 1С:Бухгалтерия 3.0

Печатные формы Логистика, склад и ТМЦ Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)

Обработки для "1С:Бухгалтерия 3.0", которые формируют акты МХ-1 и МХ-3 для документов "ПоступлениеТоваровУслуг", "Реализация товаров услуг", "Возврат товаров поставщику", "Передача материалов в эксплуатацию" соответственно. Так же можно сформировать акты с факсимиле, которая загружена в 1С:Бухгалтерия 3.0.

2520 руб.

18.02.2019    61109    170    14    

139

Путевые листы (расширение)

Печатные формы Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Транспорт, автопарки, такси Бухгалтерский учет Платные (руб)

Учет путевых листов выполнен в виде расширения. Предназначен для учета путевых листов в конфигурации Бухгалтерия предприятия 3.0. и Комплексная автоматизация 2. Печатная форма: Типовая межотраслевая форма № 3. Утверждена постановлением Госкомстата России от 28.11.97 № 78. Типовая межотраслевая форма № 4-П от 18.09.2008 г. N 152 с учетом изменений указанных в Приказе Министерства транспорта Российской Федерации №368 от 11 сентября 2020 г. №368, Типовая межотраслевая форма № ЭСМ-7, и др. ЭСМ-2, 4-С, 3 спец., 6 спец., ПЛ для Автомобильного крана. .

2000 руб.

14.10.2019    36531    225    215    

139
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. 0vrcr 57 10.04.13 10:27 Сейчас в теме
Наверное имеет смысл _сначала_ написать про БСП, а уже потом предлагать ваять нетленки? :)
2. AleksSF 222 10.04.13 10:46 Сейчас в теме
Не совсем понятно. Есле конфа не типовая, значит обновлений от 1С нет.
Тогда не проще ли вставить нужную форму в конфигурацию.
3. KliMich 10.10.13 17:09 Сейчас в теме
Как альтенатива БСП - почему бы нет
(2) AleksSF, полностью согласен. Но может AlexSvt хочет закрыть доступ юзерам к кофигуратору и дать им возможность самим вставлять свои печатные формы...
4. user861984 14.11.17 06:42 Сейчас в теме
Зачем тут создается общий модуль ДополнительныеПечатныеФормыКлиент, если он не заполняется?
5. AlexSvt 18 03.12.17 23:33 Сейчас в теме
(4) Здравствуйте. Почему же не заполняется? В этом модуле есть одна функция ОткрытьФормуКомандДополнительныхПечатныхФорм() и в тексте она описана. Других методов модуль не содержит.
6. serpanik 21.08.22 00:20 Сейчас в теме
ЗначениеВозврата = ВыбратьФайл("открыть");

хм. а это точно 8.3? :)
Оставьте свое сообщение