Формирование и отправка данных в SPOT 2D для 1С: 7.7

// XMLstr текст csv файла отправки.
Функция ОтправкаPOSTзапросом(XMLstr="",ИмяФайла)
	
	MSXMLver = "6";
	Попытка
		Http = CreateObject("MSXML2.ServerXMLHTTP."+MSXMLver+".0");
	Исключение 
		Попытка
			MSXMLver = "4";
			Http = CreateObject("MSXML2.ServerXMLHTTP."+MSXMLver+".0"); 
		Исключение 
			Сообщить(ОписаниеОшибки(),"!");
			Сообщить("Для работы модуля обмена необходима библиотека MSXML не ниже 4.0","!");
			Возврат "Для работы модуля обмена необходима библиотека MSXML не ниже 4.0";
		КонецПопытки;
	КонецПопытки;
	
	
	login = "**";
	passw = "**";
	DistrID = "**";
	
	Если ПустаяСтрока(XMLstr) = 0 Тогда
		Boundary = СтрЗаменить(ТекущееВремя(),":","");
		//формируем тело запроса
		
		Body = +"--"+Boundary+РазделительСтрок
		+"Content-Disposition: form-data; name=""ufile""; filename="""+СтрЗаменить(ИмяФайла,".csv","")+""""+РазделительСтрок
		+"Content-Type: text/plain"+РазделительСтрок+РазделительСтрок
		+XMLstr+РазделительСтрок+РазделительСтрок
		+"--"+Boundary+РазделительСтрок
		+"Content-Disposition: form-data; name=""__login"""+РазделительСтрок+РазделительСтрок
		+login+РазделительСтрок
		+"--"+Boundary+РазделительСтрок
		+"Content-Disposition: form-data; name=""__password"""+РазделительСтрок+РазделительСтрок
		+passw+РазделительСтрок
		+"--"+Boundary+РазделительСтрок
		+"Content-Disposition: form-data; name=""__did"""+РазделительСтрок+РазделительСтрок
		+DistrID+РазделительСтрок
		+"--"+Boundary;
		
	КонецЕсли;
	
	ServiceRequest = "http://aqualife.spot2d.com/dinfo/auto-upload.phtml";
	ServiceIP = "aqualife.spot2d.com";
	
	Http.Open ("POST", ServiceRequest, -1); //асинхронный запрос
	Http.SetRequestHeader("Content-Type","multipart/form-data; boundary="+Boundary);
	
	//ЗначениеВФайл(КаталогИБ()+ИмяФайла,Body,0);
	
	Http.Send(Body);
	
	Состояние("Ожидание ответа на запрос...");
	ВремяОжидания = 0;
	Пока Http.ReadyState <> 4 Цикл
		Попытка
			Если Http.waitForResponse(1) = 0 Тогда //превышено время ожидания ответа =1s
				Если ВремяОжидания >= 60 Тогда //60s
					Состояние("");
					Сообщить("Превышен интервал ожидания запроса сервера "+ServiceIP,"!");
					Возврат 0; 
				КонецЕсли;
				ВремяОжидания = ВремяОжидания + 1; //1s
				Состояние("Ожидание ответа на запрос... "+Строка(ВремяОжидания)+"s");
			КонецЕсли;
		Исключение 
			Сообщить(ОписаниеОшибки(),"!");
			Возврат 0;
		КонецПопытки; 
	КонецЦикла; 
	
	//Состояние("");
	
	Response = Http.ResponseXML;
	Заголовки = Http.getAllResponseHeaders();
	Сообщить("Заголовки: "+СпС(Лев(СпС(Заголовки),255)));
	
	ОтветСервера = Http.responseText; 
	Сообщить("Response: "+СпС(Лев(СпС(Response),255)));
	Сообщить("ОтветСервера: "+СпС(Лев(СпС(ОтветСервера),255)));
	текст = СоздатьОбъект("Текст");
	текст.ДобавитьСтроку(ОтветСервера);
	текст.Записать(КаталогВременныхФайлов()+"AquaОтвет.xml");
	
	Если Http.Status = 200 Тогда
		Сообщить("HTTP status: "+Http.Status+" "+Http.StatusText+", время ожидания "+?(ВремяОжидания=0,"<1",Строка(ВремяОжидания))+"s");
		Возврат "HTTP status: "+Http.Status+" "+Http.StatusText+", "+ОтветСервера+", время ожидания "+?(ВремяОжидания=0,"<1",Строка(ВремяОжидания))+"s";
	Иначе
		Сообщить("HTTP status: "+Http.Status+" "+Http.StatusText+", ошибка!","!");
		Возврат "HTTP status: "+Http.Status+", "+Http.StatusText+", "+ОтветСервера+", ошибка!";
	КонецЕсли;
	
	
КонецФункции // SendHTTPRequest