Загрузка банковских выписок из Альфа-Банка

    СоответствиеКонтрагентов = Новый Соответствие;
	СоотРасчСчетов = Новый Соответствие;
	
	Попытка
		Запрос = Новый Запрос;
		Запрос.Текст = "ВЫБРАТЬ
		|	СписокПлательщиков.Контрагент.ИНН КАК ИНН,
		|	СписокПлательщиков.Контрагент КАК Контрагент
		|ИЗ
		|	РегистрСведений.СписокПлательщиков КАК СписокПлательщиков";
		
		Выборка = Запрос.Выполнить().Выбрать();  
		Пока Выборка.Следующий() Цикл СоответствиеКонтрагентов.Вставить(Выборка.ИНН, Выборка.Контрагент); КонецЦикла;
		
		Запрос = Новый Запрос;
		Запрос.Текст = "ВЫБРАТЬ
		|	СписокПлательщиков.Контрагент КАК Контрагент
		|ПОМЕСТИТЬ СписокКонтрагентов
		|ИЗ
		|	РегистрСведений.СписокПлательщиков КАК СписокПлательщиков
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	БанковскиеСчета.НомерСчета КАК НомерСчета,
		|	БанковскиеСчета.Ссылка КАК Ссылка
		|ИЗ
		|	Справочник.БанковскиеСчета КАК БанковскиеСчета
		|ГДЕ
		|	БанковскиеСчета.Владелец В
		|			(ВЫБРАТЬ
		|				СписокКонтрагентов.Контрагент КАК Контрагент
		|			ИЗ
		|				СписокКонтрагентов КАК СписокКонтрагентов)
		|	И БанковскиеСчета.ПометкаУдаления = ЛОЖЬ";
		
		Выборка = Запрос.Выполнить().Выбрать();  
		Пока Выборка.Следующий() Цикл СоотРасчСчетов.Вставить(Выборка.НомерСчета, Выборка.Ссылка); КонецЦикла;
		
	Исключение
		
	КонецПопытки;
	
	КоличествоСтрок = СтрЧислоСтрок(ТекстДляРазбора);
	ТекущаяСтрока = 3;
	
	Пока ТекущаяСтрока <= КоличествоСтрок Цикл
		
		Стр = СокрЛП(СтрПолучитьСтроку(ТекстДляРазбора, ТекущаяСтрока));
		
		МасЭлементов = СтрРазделить(Стр, Символы.Таб); 
		РасСчет = МасЭлементов[7];   		
		Если БанковскийСчет.НомерСчета <> РасСчет Тогда
			Сообщить("Не совпадает расчетный счет: " + РасСчет);  
			ТекущаяСтрока = ТекущаяСтрока + 1;
			Продолжить;
		КонецЕсли;
		
		Загружать = Истина;
		
		РасходПриход = МасЭлементов[26]; //С латинская
		ВидОперации = МасЭлементов[27];  //01 - не анализируем
		НомерДок = Формат(МасЭлементов[29],"ЧГ=0");
		ДатаДок = ДатаИзСтроки(МасЭлементов[28]); //дата учета операции по счету !
		Сумма = МасЭлементов[31];
		
		ИННКонтрагента = МасЭлементов[34];
		РасчСчетКонтрагента = МасЭлементов[36]; 		
		
		Назначение = МасЭлементов[64];
		
		НоваяСтрокаДокументов = СписокДокументов.Добавить();
		
		НоваяСтрокаДокументов.Дата = ДатаДок;
		НоваяСтрокаДокументов.НомерДок = НомерДок;
		НоваяСтрокаДокументов.СуммаДокумента = Сумма;
		
		Если РасходПриход = "C" Тогда
			НоваяСтрокаДокументов.СуммаПоступило = Сумма;
			НоваяСтрокаДокументов.ВидОперации = Перечисления.ВидыОперацийПоступлениеБезналичныхДенежныхСредств.ОплатаПокупателя;
		Иначе
			НоваяСтрокаДокументов.СуммаСписано = Сумма;
			Загружать = Ложь; //документы списания денежных средств не загружаем !
		КонецЕсли;
		
		Если НомерДок = "" Тогда
			Загружать = Ложь;
		КонецЕсли;

		Если Сумма = 0 Тогда
			Загружать = Ложь;
		КонецЕсли;
		
		Контрагент = СоответствиеКонтрагентов.Получить(ИННКонтрагента);
		Если Контрагент = Неопределено Тогда       
			//длительная операция чтения данных из базы, в моем случае редкая по исполнению
			//поскольку в моем случае все контрагенты, являющиеся плательщиками, находятся в отдельном регистре.
			//для общего случая нужно создать СоответствиеКонтрагентов с отбором
			//по признаку Покупатель = Истина, ПометкаУдаления = Ложь, может еще что исходя из вашей специфики
			Контрагент = Справочники.Контрагенты.НайтиПоРеквизиту("ИНН", ИННКонтрагента); 
		КонецЕсли;
		НоваяСтрокаДокументов.Контрагент = Контрагент;  
		
		Попытка
			НоваяСтрокаДокументов.Договор = Контрагент.ОсновнойДоговорКонтрагента; //не у всех есть такой реквизит! 
		Исключение
		КонецПопытки;
		
		Если НЕ ЗначениеЗаполнено(Контрагент) Тогда  
			//контрагентов нужно заранее создавать
			//либо вручную, либо дописать здесь программное создание новых контрагентов,
			//как, например, программное создание банковских счетов контрагентов
			Загружать = Ложь;
		КонецЕсли;

		РасСчетКонтр = СоотРасчСчетов.Получить(РасчСчетКонтрагента);
		Если РасСчетКонтр = Неопределено Тогда 
			//длительная операция чтения данных из базы, в моем случае редкая по исполнению
			//поскольку в моем случае все контрагенты, являющиеся плательщиками, находятся в отдельном регистре
			//и связанные банковские расчетные счета тоже легко отфильтровать.
			//для общего случая нужно создать СоответствиеБанкСчетов с отбором
			//по контрагентам-владельцам, может еще что исходя из вашей специфики
			РасСчетКонтр = Справочники.БанковскиеСчета.НайтиПоРеквизиту("НомерСчета", РасчСчетКонтрагента);
		КонецЕсли;
		НоваяСтрокаДокументов.СчетКонтрагента = РасСчетКонтр;
		
		Если НЕ ЗначениеЗаполнено(РасСчетКонтр) Тогда
			
			Если ЗначениеЗаполнено(Контрагент) Тогда
				НовыйРасчСчет = Справочники.БанковскиеСчета.СоздатьЭлемент();
				НовыйРасчСчет.Владелец = Контрагент;
				НовыйРасчСчет.НомерСчета = МасЭлементов[36];
				Банк = Справочники.Банки.НайтиПоКоду(МасЭлементов[38]);
				Если Не ЗначениеЗаполнено(Банк) Тогда
					Банк = Справочники.Банки.СоздатьЭлемент();
					Банк.Наименование = МасЭлементов[37];
					Банк.Код = МасЭлементов[38];
					Банк.КоррСчет = МасЭлементов[39];
					Банк.Записать();
				КонецЕсли;
				НовыйРасчСчет.Банк = Банк.Ссылка;
				//НовыйРасчСчет.БанкДляРасчетов = Банк.Ссылка; //это не нужно!
				НовыйРасчСчет.ВидСчета = "Расчетный";
				НовыйРасчСчет.ВалютаДенежныхСредств = мВалютаРегламентированногоУчета;
				НовыйРасчСчет.Наименование = Лев(МасЭлементов[36] + ", " + Банк, 100); 
				НовыйРасчСчет.Записать();
				НоваяСтрокаДокументов.СчетКонтрагента = НовыйРасчСчет.Ссылка;
			КонецЕсли;
			
		КонецЕсли;
		
		НоваяСтрокаДокументов.НазначениеПлатежа = СокрЛП(Назначение);
		НоваяСтрокаДокументов.Загружать = Загружать;
		
		ТекущаяСтрока = ТекущаяСтрока + 1;
				
	КонецЦикла;

КолонкиТЗ = "НомерДок, Дата, Контрагент, СуммаПоступило"; 
	КопияТЗ = СписокДокументов.СкопироватьКолонки(КолонкиТЗ);
	Для Каждого Стр Из СписокДокументов Цикл
		Если Стр.Загружать Тогда
			ЗаполнитьЗначенияСвойств(КопияТЗ.Добавить(), Стр);
		КонецЕсли;
	КонецЦикла;

	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	ВнешняяТаблица.НомерДок КАК НомерДок,
	|	ВнешняяТаблица.Дата КАК Дата,
	|	ВнешняяТаблица.Контрагент КАК Контрагент,
	|	ВнешняяТаблица.СуммаПоступило КАК СуммаПоступило
	|ПОМЕСТИТЬ СписокДокументов
	|ИЗ
	|	&ВнешняяТаблица КАК ВнешняяТаблица
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	СписокДокументов.НомерДок КАК НомерДок,
	|	СписокДокументов.Дата КАК Дата,
	|	СписокДокументов.Контрагент КАК Контрагент,
	|	СписокДокументов.СуммаПоступило КАК СуммаПоступило,
	|	ЕСТЬNULL(ПлатежноеПоручениеВходящее.Ссылка, НЕОПРЕДЕЛЕНО) КАК Документ
	|ИЗ
	|	СписокДокументов КАК СписокДокументов
	|		ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПлатежноеПоручениеВходящее КАК ПлатежноеПоручениеВходящее
	|		ПО СписокДокументов.НомерДок = ПлатежноеПоручениеВходящее.НомерВходящегоДокумента
	|			И СписокДокументов.Дата = ПлатежноеПоручениеВходящее.ДатаВходящегоДокумента
	|			И СписокДокументов.Контрагент = ПлатежноеПоручениеВходящее.Контрагент
	|			И СписокДокументов.СуммаПоступило = ПлатежноеПоручениеВходящее.СуммаДокумента";
	
	Запрос.УстановитьПараметр("ВнешняяТаблица", КопияТЗ);
	Выборка = Запрос.Выполнить().Выбрать();
	Если Выборка.Следующий() Тогда
		Выборка.Сбросить();
	КонецЕсли;
	
	Для Каждого СтрокаТЗ Из СписокДокументов Цикл
		
		Если НЕ СтрокаТЗ.Загружать Тогда
			Продолжить;
		КонецЕсли; 		
		
		//загружаем только приходы денег !
		Если СтрокаТЗ.СуммаПоступило <= 0 Тогда
			Продолжить;
		КонецЕсли;
		
		ПараметрыОтбора = Новый Структура(КолонкиТЗ);
		ЗаполнитьЗначенияСвойств(ПараметрыОтбора, СтрокаТЗ);
				
		НайденныйДокумент = Неопределено;
		Если Выборка.НайтиСледующий(ПараметрыОтбора) Тогда
			НайденныйДокумент = Выборка.Документ;	
		Иначе
			НовДок = Документы.ПлатежноеПоручениеВходящее.СоздатьДокумент();
			НовДок.Дата = СтрокаТЗ.Дата;
			НовДок.НомерВходящегоДокумента = СтрокаТЗ.НомерДок;
			НовДок.ДатаВходящегоДокумента = СтрокаТЗ.Дата;
			НовДок.Контрагент = СтрокаТЗ.Контрагент;
			НовДок.СчетКонтрагента = СтрокаТЗ.СчетКонтрагента;
			НовДок.Оплачено = Истина;
			НовДок.СуммаДокумента = СтрокаТЗ.СуммаПоступило;
			НовДок.Организация = Организация;
			НовДок.СчетОрганизации = БанковскийСчет;
			НовДок.ВалютаДокумента = мВалютаРегламентированногоУчета;
			НовДок.ВидОперации = Перечисления.ВидыОперацийПоступлениеБезналичныхДенежныхСредств.ОплатаПокупателя;
			НовДок.НазначениеПлатежа = СтрокаТЗ.НазначениеПлатежа;
			НовДок.СчетБанк = ПланыСчетов.Хозрасчетный.НайтиПоКоду("51.09");
			НовДок.Комментарий = "#Загружен через клиент-банк";
			
			Попытка
				НовДок.Записать(); //мы не проводим документ ! специально для дальнейшей ручной обработки
			Исключение
			КонецПопытки;
			
			НайденныйДокумент = НовДок.Ссылка;
			
		КонецЕсли;
		
		Выборка.Сбросить();
		
		СтрокаТЗ.Документ = НайденныйДокумент;
				
	КонецЦикла;

1. Анализ прав и ролей. Поиск подходящего профиля - алгоритмический анализ и поиск
2. Оцифровка и визуализация склада - программная прорисовка склада
3. Удаление документов для любых баз на управляемых формах
4. Удаление справочников для любых баз на управляемых и обычных формах
5. Перенумерация документов и справочников - с учетом префиксов номеров
6. Свертка базы УТ 10.3 подокументно - новая концепция 
7. Матричное программирование - демо-стенд матричного калькулятора
8. Справочное хранение товаров в КА 2.5 - кейс запуска адресного склада
9. Мини-обзор разных задач - от очевидного до неочевидного
10. Поиск отчета по документам - пример анализа незнакомых конфигураций
11. Флажок в динамическом списке - от теории до практики "как бы простой" задачи
12. Из Json в ДеревоЗначений - удобный просмотрщик json-структуры
13. Внедрение адресного склада в КА 2.5 - кейс запуска адресного склада
14. Фрилансеру: про цены, про клиентов, про планирование - мое исследование
15. Что такое форматированный документ - прекрасная возможность раскрасить любой текст
16. Программная работа с упаковками в КА 2.5 - примеры адаптаций механизмов упаковок в КА 2.5
17. Универсальное сравнение регистров накопления - связь по измерениям, сравнение по ресурсам
18. Обход объекта рекурсивно - просмотр реквизитов документа с бесконечным открытием подуровней