Настройка взаимодействия телеграм бота с 1С через Webhook

//Наш модуль HTTP сервиса

Функция PingGetPing(Запрос)
    //GET запрос будет возвращать простой ответ
    //об успешной обработке запроса
    Возврат МодульРаботыСHTTP.ПолучитьПростойУспешныйОтвет();
КонецФункции

Функция SendPostSend(Запрос)

    //Обрабатывать сообщения мы будем через попытку и при ошибке
    //мы будет вызывать функцию обработки ошибки
    //При любом варианте мы будем получать уже готовый для отправки ответ.
    
    Попытка
        Ответ=МодульРаботыСТГ.ОбработатьВходящийЗапрос(Запрос);        
    Исключение
        Ответ=МодульРаботыСHTTP.ОтветОбОшибке(ИнформацияОбОшибке());        
    КонецПопытки;
    //Вызов процедуры, фиксирующей все обращения к шаблону send этого HTTPСервиса 
    МодульРаботыСHTTP.ЗаписатьЛог("send",Запрос,Ответ);
    
    Возврат Ответ;
КонецФункции

#Область ПрограммныйИнтерфейс

//функция возвращающая строку JSON с табуляцией 
//на основании переданного объекта
Функция ПолучитьСтрокуJSON(ОбъектJSON) Экспорт 
    ПараметрыЗаписиJSON=Новый ПараметрыЗаписиJSON(,Символы.Таб);
    
    ЗаписьJSON=Новый ЗаписьJSON;
    ЗаписьJSON.УстановитьСтроку(ПараметрыЗаписиJSON);
    ЗаписатьJSON(ЗаписьJSON,ОбъектJSON);
    Возврат ЗаписьJSON.Закрыть();
КонецФункции 

//функция возвращающая объект 
//на основании переданной строки JSON 
Функция ПолучитьОбъектJSON(СтрокаJSON) Экспорт
    ЧтениеJSON=Новый ЧтениеJSON;
    ЧтениеJSON.УстановитьСтроку(СтрокаJSON);
    ОбъектJSON=ПрочитатьJSON(ЧтениеJSON);
    ЧтениеJSON.Закрыть();
    Возврат ОбъектJSON
КонецФункции 

//функция создает ответ, на основании переданного ей объекта

Функция ОтветJSON(Объект,КодСостояния=200) Экспорт
    
    HTTPСервисОтвет=Новый HTTPСервисОтвет(КодСостояния);
    HTTPСервисОтвет.УстановитьТелоИзСтроки(ПолучитьСтрокуJSON(Объект));
    HTTPСервисОтвет.Заголовки.Вставить("Content-Type","application/json");
    
    Возврат HTTPСервисОтвет;
    
КонецФункции 

//функция создает простой ответ об успешном обрабатывании кода
Функция ПолучитьПростойУспешныйОтвет() Экспорт
    
    СтруктураОтвета=Новый Структура; 
    
    СтруктураОтвета.Вставить("Result","Its all good");
    Возврат ОтветJSON(СтруктураОтвета)
    
КонецФункции 

//функция фиксирует ошибку в журнале регистрации и 
//передает информацию о ней в ответ
Функция ОтветОбОшибке(ИнформацияОбОшибке) Экспорт
    
    ЗаписьЖурналаРегистрации("HTTPСервисы.Ошибка",УровеньЖурналаРегистрации.Ошибка,,,
    ПодробноеПредставлениеОшибки(ИнформацияОбОшибке));
    Результат=Новый Структура;
    Результат.Вставить("Result","Error");
    Результат.Вставить("ErrorText",КраткоеПредставлениеОшибки(ИнформацияОбОшибке));
    
    Возврат ОтветJSON(Результат,500);
    
КонецФункции 

//Процедура будет фиксировать все поступающие http запросы
Процедура ЗаписатьЛог(ИмяМетода,Запрос,Ответ)  Экспорт 
    
    НовыйЛог=Документы.ВходящиеЗапросы.СоздатьДокумент();
    НовыйЛог.Метод=ИмяМетода;
    ТелоЗапроса=Запрос.ПолучитьТелоКакСтроку();
    Попытка 
        ТелоЗапроса=ПолучитьСтрокуJSON(ПолучитьОбъектJSON(ТелоЗапроса));
    Исключение
        ОтветОбОшибке(ИнформацияОбОшибке());
    КонецПопытки; 
    НовыйЛог.ТелоЗапроса=ТелоЗапроса;
    НовыйЛог.ТелоОтвета=Ответ.ПолучитьТелоКакСтроку();
    НовыйЛог.КодОтвета=Ответ.КодСостояния;
    НовыйЛог.Дата=ТекущаяДатаСеанса();
    
    НовыйЛог.Записать();
    
КонецПроцедуры

#КонецОбласти

#Область ПрограммныйИнтерфейс 
//обрабатываем входящий запрос
Функция ОбработатьВходящийЗапрос(Запрос) Экспорт 

    //Преобразуем JSONСтроку в структура(объеки) и разбираем его по свойствам(полям)
    ДанныеЗапроса= МодульРаботыСHTTP.ПолучитьОбъектJSON(Запрос.ПолучитьТелоКакСтроку());    
    //Если полученная структура имеет свойство message то обрабатываем её иначе
    //возвращаем простой успешный ответ 
    Если ДанныеЗапроса.Свойство("message") тогда
        Возврат ОбработатьСообщение(ДанныеЗапроса.message)
    Иначе        
        Возврат МодульРаботыСHTTP.ПолучитьПростойУспешныйОтвет()
    КонецЕсли;
    
КонецФункции 

#КонецОбласти 

#Область СлужебныеПроцедурыИФункции

Функция ОбработатьСообщение(ДанныеСообщения)
    //У каждого чата в телеграм есть уникальный идентификатор, 
    //с помощью которого можно обратиться к нему и отправить сообщение
    ИдентификаторЧата=ДанныеСообщения.Chat.id;
    
    СтруктураОтвета=Новый Структура;    
    СтруктураОтвета.Вставить("chat_id",ИдентификаторЧата);
    
    //получаем ваш текст сообщения или подпись
    //которую вы прикрепили в фото или аудио
    //
    ТекстСообщения=ПолучитьТекстСообщения(ДанныеСообщения);
    ПолучательСообщения="";
    
    //Так как в полученной структуре может отсутствовать отправитель
    //то проверяем есть ли он 
    Если ДанныеСообщения.Свойство("from") тогда
        Отправитель=ДанныеСообщения.from;
        //username это то как мы можем найти нашего пользователя через собаку
        //если его нет то пытаемся получить имя или фамилию отправителя
        //в крайнем случае получаем уникальный id пользователя,
        //он не пишется в профиле пользователя, но его можно найти через         
        //другого бота @useridgetbot
        Если Отправитель.Свойство("username") тогда
            ПолучательСообщения="@"+Отправитель.username;            
        ИначеЕсли Отправитель.Свойство("first_name") тогда
            ПолучательСообщения=Отправитель.first_name;
        ИначеЕсли Отправитель.Свойство("last_name") тогда
            ПолучательСообщения=Отправитель.last_name;
        Иначе
            ПолучательСообщения=Отправитель.id;
        КонецЕсли;
    КонецЕсли;
    
    
    //Теперь мы проверяем на то что мы отправили нашему боту для каждого из них есть свой уникальный тип
    //если мы отправляем какую-либо аудио запись, то используется метод sendAudio,а к файлу можно получить доступ через уникальный file_id
    //он указывает на файл на серверах телеграма и зная этот id, мы можем вновь его отправить
    //свойство capition это подпись под фото или аудио
    //фото в запросе приходит Photo как массив объектов PhotoSize, мы получаем последний, так как его качество лучше     
    Если ДанныеСообщения.Свойство("audio") тогда
        СтруктураОтвета.Вставить("method","sendAudio");
        СтруктураОтвета.Вставить("caption",ПолучательСообщения+", "+ТекстСообщения);
        СтруктураОтвета.Вставить("audio",ДанныеСообщения.audio.file_id);
        
    ИначеЕсли ДанныеСообщения.Свойство("photo") тогда
        КоличествоРазмеров=ДанныеСообщения.photo.Количество();
        СтруктураОтвета.Вставить("method","sendPhoto");
        СтруктураОтвета.Вставить("caption",ПолучательСообщения+", "+ТекстСообщения);
        СтруктураОтвета.Вставить("photo",ДанныеСообщения.photo[КоличествоРазмеров-1].file_id);        
        
    ИначеЕсли ДанныеСообщения.Свойство("voice") тогда
        СтруктураОтвета.Вставить("method","sendVoice");
        СтруктураОтвета.Вставить("voice",ДанныеСообщения.voice.file_id);
        
    ИначеЕсли ДанныеСообщения.Свойство("video_note") тогда
        СтруктураОтвета.Вставить("method","sendVideoNote");
        СтруктураОтвета.Вставить("video_note",ДанныеСообщения.video_note.file_id);
        
    ИначеЕсли ДанныеСообщения.Свойство("sticker") тогда
        СтруктураОтвета.Вставить("method","sendSticker");
        СтруктураОтвета.Вставить("sticker",ДанныеСообщения.sticker.file_id);
        
    Иначе        
        СтруктураОтвета.Вставить("method","sendMessage");
        СтруктураОтвета.Вставить("text",ПолучательСообщения+", "+ТекстСообщения);
        
    КонецЕсли;
    
    Возврат МодульРаботыСHTTP.ОтветJSON(СтруктураОтвета);
КонецФункции 

Функция ПолучитьТекстСообщения(ДанныеСообщения)
    
    //подпись бота нужна, для выделения от кого это сообщения
    //если добавить его в группу, то будет неудобно читать беседу
      ПодписьБота=Символы.ПС+"© бот";    
    //у сообщения есть text если это простое текстовое сообщение 
    //и capition если это надпись у аудио или фото файла
    //если нет ни текста ни capition значит в сообщении пришел объект, 
    //логику обработки которого я еще не написал
    Если ДанныеСообщения.Свойство("text") тогда
        ТекстСообщения=ДанныеСообщения.text+ПодписьБота;
    ИначеЕсли ДанныеСообщения.Свойство("caption") тогда
        ТекстСообщения=ДанныеСообщения.caption+ПодписьБота;
    Иначе
        ТекстСообщения="ошибка в распознавании сообщения 1с"+ПодписьБота;
    КонецЕсли;    
    Возврат ТекстСообщения
    
КонецФункции

#КонецОбласти