Пример связи 1С и мессенджера Telegram. Получение данных из 1С запросом из Telegram

Публикация № 419846 19.11.15

Интеграция и обмен данными - Боты

API Telegram HTTPСоединение JSON

В результате чтения публикации Вы получите готовую внешнюю обработку, позволяющую получать из 1С данные, запрашиваемые через Telegram. В данной статье рассмотрим следующее: Использование HTTPСоединение; Чтение JSON для версии 1С 8.3.6 и выше, а также аналог JSON для версии 1С ниже 8.3.6; Подключение обработчика ожидания; Некоторые основные возможности API Telegram; Как создать бота для Telegram; Программное создание колонок дерева на управляемой форме;

1. Регистрация бота

            Для начала зарегистрируем бота, получим его id - токен. В Telegram для этого создан специальный бот — @BotFather. Добавляем его в контакт. Получаем получаем список его команд, написав ему /start.

            Введите команду /newbot — бот попросит придумать имя нашему новому боту (оно должно оканчиваться на «bot»). BotFather предоставит токен бота и ссылку для добавления бота в контакты. Проверим полученный токен с помощью ссылки api.telegram.org/bot<TOKEN>/getMe 

            Этого, в принципе, достаточно.

2. Создание обработки в 1С

            Создадим внешнюю обработку. Добавим реквизиты обработки строковый переменной длины «Бот», «Токен», «Сервер».

            Т.к. обработку не будем привязывать к конкретной конфигурации, то список понимаемых команд будем хранить в табличной части обработки «ТаблицаПонимаемыхКоманд» (а так, в принципе, команды можно хранить в справочнике конфигурации).

            Реквизиты ТЧ строковые: «Имя», «ВыполняемоеДействие», «Параметр», «Описание»

 

 

 

Команды пользователя (те, которые он буде писать боту) по той же причине будем хранить в табличной части «КомандыПользователей» (если не делать обработку универсальной, то, конечно, предпочтительно использовать регистр сведений – далее, в листингах кода укажем примеры и для регистра сведений тоже).

Реквизиты ТЧ: числовые «chat_id», «date», булево «Выполнено» и строковый «Команда»

 

 

            Теперь создадим управляемую форму обработки, назначим ее основной и разместим реквизиты «Бот» и «Токен» (необязательно, но для наглядности):

 

Также создадим реквизит формы «Дерево» – тип «ДеревоЗначений». В нем будут отображаться чаты. Для наглядности выведем его на форму. Колонки дерева создадим программно (см.далее).

Для  события формы ПриСозданииНаСервере добавим процедуру:

 

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
    
    Объект.Бот = "@бот_bot"; //Имя бота
    Объект.Токен = "111111111:ххххххххххххххххххххххCJw"; //Ваш токен telegram
    Объект.Сервер = "api.telegram.org";
    //Заполнение таблицы команд бота
    НоваяКоманда = Объект.ТаблицаПонимаемыхКоманд.Добавить();
    НоваяКоманда.Имя = "/start";
    НоваяКоманда.ВыполняемоеДействие = "ВывестиПриветствие";
    НоваяКоманда.Параметр = "";
    НоваяКоманда.Описание = "начало работы";
    НоваяКоманда.Параметр = "";
    НоваяКоманда = Объект.ТаблицаПонимаемыхКоманд.Добавить();
    НоваяКоманда.Имя = "/help";
    НоваяКоманда.ВыполняемоеДействие = "ВывестиПодсказку";
    НоваяКоманда.Описание = "получение подсказки";
    НоваяКоманда.Параметр = "";
    НоваяКоманда = Объект.ТаблицаПонимаемыхКоманд.Добавить();
    НоваяКоманда.Имя = "/sys_info";
    НоваяКоманда.ВыполняемоеДействие = "СистемнаИнформация";
    НоваяКоманда.Описание = "системная инф-ция. Параметр через пробел:" +
        Символы.ПС + Символы.Таб + "ВерсияОС;ВерсияПриложения {по умолчанию};ИдентификаторКлиента;ИнформацияПрограммыПросмотра;ОперативнаяПамять;Процессор;ТипПлатформы.";
    НоваяКоманда.Параметр = "";
КонецПроцедуры

 

Создадим команду формы «ПоказатьСообщения», выведем ее на форму в виде кнопки и Обработчик команды

 

&НаКлиенте
Процедура ПоказатьСообщения(Команда = Неопределено)
    Ресурс = "bot" + Объект.Токен + "/getUpdates";
    Соединение = Новый HTTPСоединение(Объект.Сервер, 443, , , , , Новый ЗащищенноеСоединениеOpenSSL());
    Запрос = Новый HTTPЗапрос(Ресурс);
    Ответ = Соединение.Получить(Запрос);
    ДвоичныеДанныеОтвета = Ответ.ПолучитьТелоКакДвоичныеДанные();
    ПрочитатьДвоичныеДанныеОтвета(ДвоичныеДанныеОтвета);
КонецПроцедуры

 

Обратите внимание, что для протокола «https» порт указывается 443

Если Вы используете версию 1С 8.3.6 и выше, то в процедура ПрочитатьДвоичныеДанныеОтвета() будем использовать новый объект ЧтениеJSON().

 

&НаСервере
Процедура ПрочитатьДвоичныеДанныеОтвета(ДвоичныеДанныеОтвета)
    ИмяФайла = ПолучитьИмяВременногоФайла("tgm");
    ДвоичныеДанныеОтвета.Записать(ИмяФайла);
    ДеревоЗн = Новый ДеревоЗначений();
    //{Для версии 1С 8.3.6 и выше
    ЧтениеJSON = Новый ЧтениеJSON();
    ЧтениеJSON.ОткрытьФайл(ИмяФайла);
    СформироватьДерево(ДеревоЗн, ДеревоЗн, ЧтениеJSON);
    ЧтениеJSON.Закрыть();
    //}
    
    //Создание колонок Реквизита формы типа ДанныеФормыДерево
    Если ЭтаФорма.Элементы.Дерево.ПодчиненныеЭлементы.Количество() = 0 Тогда
        МассивДобавляемыхРеквизитов = Новый Массив;
        Для Каждого Колонка Из ДеревоЗн.Колонки Цикл
            МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, "Дерево"));
        КонецЦикла;
        ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);
    КонецЕсли;
    ////
    // Преобразование объекта прикладного типа ДеревоЗначений
    // в реквизит управляемой формы (данные формы)
    ЗначениеВРеквизитФормы(ДеревоЗн, "Дерево");
    //Создание колонок элемента формы типа ТаблицаФормы для отображения дерева
    //которое для наглядности разместили на форме дерево сообщений
    Если ЭтаФорма.Элементы.Дерево.ПодчиненныеЭлементы.Количество() = 0 Тогда
        Для Каждого Колонка Из ДеревоЗн.Колонки Цикл
            НовыйЭлемент = Элементы.Добавить(Колонка.Имя, Тип("ПолеФормы"), Элементы.Дерево);
            НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
            НовыйЭлемент.ПутьКДанным = "Дерево." + Колонка.Имя;
        КонецЦикла;
    КонецЕсли;
    ////
    ЗаполнитьРС(ДеревоЗн);
КонецПроцедуры

 

В процедуре ЗаполнитьРС() будем заполнять табличную часть «КомандыПользователей» (или же регистр сведений). (код процедуры далее).

Процедура ЗаполнитьСтруктуруИзОтветаJSON() заполняет дерево чатов:

 

//Рекурсивное заполнение дерева для версии 1С 8.3.6 и выше
&НаСервере
Процедура СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON, Знач ИмяКолонки = Неопределено)
    ЧтениеJSON.Прочитать();
    TипJSON = ЧтениеJSON.ТипТекущегоЗначения;
    Если TипJSON = ТипЗначенияJSON.НачалоОбъекта ИЛИ TипJSON = ТипЗначенияJSON.НачалоМассива Тогда
        НовСтр = СтрДерево.Строки.Добавить();
        СформироватьДерево(Дерево, НовСтр, ЧтениеJSON);
    ИначеЕсли TипJSON = ТипЗначенияJSON.ИмяСвойства Тогда
        СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON, ЧтениеJSON.ТекущееЗначение);
    ИначеЕсли TипJSON = ТипЗначенияJSON.Число ИЛИ TипJSON = ТипЗначенияJSON.Строка ИЛИ TипJSON = ТипЗначенияJSON.Булево ИЛИ TипJSON = ТипЗначенияJSON.Null Тогда
        Если Дерево.Колонки.Найти(ИмяКолонки) = Неопределено Тогда
            Дерево.Колонки.Добавить(ИмяКолонки);
        КонецЕсли;
        СтрДерево[ИмяКолонки] = ЧтениеJSON.ТекущееЗначение;
        СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON);
    ИначеЕсли TипJSON = ТипЗначенияJSON.Комментарий Тогда
        Если Дерево.Колонки.Найти("Комментарий") = Неопределено Тогда
            Дерево.Колонки.Добавить("Комментарий");
        КонецЕсли;
        СтрДерево.Комментарий = ЧтениеJSON.ТекущееЗначение;
        СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON);
    ИначеЕсли СтрДерево <> Неопределено Тогда
        СформироватьДерево(Дерево, СтрДерево.Родитель, ЧтениеJSON);
    КонецЕсли;
КонецПроцедуры
//}

 

Если Вы используете версию 1С ниже 8.3.6 то процедура ПрочитатьДвоичныеДанныеОтвета() будет такой:

 

&НаСервере
Процедура ПрочитатьДвоичныеДанныеОтвета(ДвоичныеДанныеОтвета)
    ИмяФайла = ПолучитьИмяВременногоФайла("tgm");
    ДвоичныеДанныеОтвета.Записать(ИмяФайла);
    ДеревоЗн = Новый ДеревоЗначений();
    //{для версии 1С ниже 8.3.6 - раскомментируйте
    ЧтениеJSON = Новый ТекстовыйДокумент();
    ЧтениеJSON.Прочитать(ИмяФайла);
    Рез = ЗаполнитьСтруктуруИзОтветаJSON(ДеревоЗн, ДеревоЗн.Строки.Добавить(), ЧтениеJSON.ПолучитьТекст());
    //}
    //Создание колонок Реквизита формы типа ДанныеФормыДерево
    Если ЭтаФорма.Элементы.Дерево.ПодчиненныеЭлементы.Количество() = 0 Тогда
        МассивДобавляемыхРеквизитов = Новый Массив;
        Для Каждого Колонка Из ДеревоЗн.Колонки Цикл
            МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, "Дерево"));
        КонецЦикла;
        ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);
    КонецЕсли;
    ////
    
    // Преобразование объекта прикладного типа ДеревоЗначений
    // в реквизит управляемой формы (данные формы)
    ЗначениеВРеквизитФормы(ДеревоЗн, "Дерево");
    //Создание колонок элемента формы типа ТаблицаФормы для отображения дерева
    //которое для наглядности разместили на форме дерево сообщений
    Если ЭтаФорма.Элементы.Дерево.ПодчиненныеЭлементы.Количество() = 0 Тогда
        Для Каждого Колонка Из ДеревоЗн.Колонки Цикл
            НовыйЭлемент = Элементы.Добавить(Колонка.Имя, Тип("ПолеФормы"), Элементы.Дерево);
            НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
            НовыйЭлемент.ПутьКДанным = "Дерево." + Колонка.Имя;
        КонецЦикла;
    КонецЕсли;
    ////
    ЗаполнитьРС(ДеревоЗн);
КонецПроцедуры

 

Как уже было сказано, в процедуре ЗаполнитьРС() будем заполнять табличную часть «КомандыПользователей» (или же регистр сведений). (код процедуры далее).

Процедура ЗаполнитьСтруктуруИзОтветаJSON() – это парсер JSON и рекурсивное заполнение дерева для версии ниже 1С 8.3.6:

 

//{Рекурсивное заполнение дерева для версии ниже 1С 8.3.6
&НаСервере
Функция ЗаполнитьСтруктуруИзОтветаJSON(Дерево, СтрДерево, Знач ТекстJSON) Экспорт
    Результат = Новый Структура;
    ТекстJSON = СтрЗаменить(ТекстJSON, "\""", """");
    ТекстJSON = СтрЗаменить(ТекстJSON, """", "");
    Если Лев(ТекстJSON, 1) = "{" Тогда
        ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, "Структура", Дерево, СтрДерево);
    ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда
        МассивДанных = Новый Массив;
        ЗаполнитьДанныеИзОтветаJSON(МассивДанных, ТекстJSON, "Массив", Дерево, СтрДерево);
        Результат.Вставить("Значение", МассивДанных);
    КонецЕсли;
    Возврат Результат;
КонецФункции

&НаСервере
Процедура ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, ТипДанных, Дерево, СтрДерево)
    ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));
    НомерЗначения = 0;
    Пока ТекстJSON <> "" Цикл
        ПервыйСимвол = Лев(ТекстJSON, 1);
        Если ПервыйСимвол = "{" Тогда
            Значение = Новый Структура;
            НовСтр = СтрДерево.Строки.Добавить();
            ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура", Дерево, НовСтр);
            Если ТипДанных = "Структура" Тогда
                Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);
                НомерЗначения = НомерЗначения + 1;
            ИначеЕсли ТипДанных = "Массив" Тогда
                Результат.Добавить(Значение);
            КонецЕсли;
        ИначеЕсли ПервыйСимвол = "[" Тогда
            Значение = Новый Массив;
            НовСтр = СтрДерево.Строки.Добавить();
            ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив", Дерево, НовСтр);
            Если ТипДанных = "Структура" Тогда
                Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);
                НомерЗначения = НомерЗначения + 1;
            Иначе
                Результат.Добавить(Значение);
            КонецЕсли;
        ИначеЕсли ПервыйСимвол = "}" И ТипДанных = "Структура" Тогда
            ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));
            Если Лев(ТекстJSON, 1) = "," Тогда
                ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));
            КонецЕсли;
            Возврат;
        ИначеЕсли ПервыйСимвол = "]" И ТипДанных = "Массив" Тогда
            ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));
            Если Лев(ТекстJSON, 1) = "," Тогда
                ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));
            КонецЕсли;
            Возврат;
        Иначе
            Если ТипДанных = "Структура" Тогда
                Поз = Найти(ТекстJSON, ":");
                Если Поз = 0 Тогда
                    Прервать;
                КонецЕсли;
                ИмяЗначения = СокрЛП(Лев(ТекстJSON, Поз - 1));
                ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + 1));
                Если Лев(ТекстJSON, 1) = "{" Тогда
                    Значение = Новый Структура;
                    НовСтр = СтрДерево.Строки.Добавить();
                    ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура", Дерево, НовСтр);
                ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда
                    Значение = Новый Массив;
                    НовСтр = СтрДерево.Строки.Добавить();
                    ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив", Дерево, НовСтр);
                Иначе
                    Поз = 0;
                    Для Сч = 1 По СтрДлина(ТекстJSON) Цикл
                        Символ = Сред(ТекстJSON, Сч, 1);
                        Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда
                            Поз = Сч;
                            Прервать;
                        КонецЕсли;
                    КонецЦикла;
                    Если Поз = 0 Тогда
                        Значение = ТекстJSON;
                        ТекстJSON = "";
                    Иначе
                        Значение = Лев(ТекстJSON, Поз - 1);
                        ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));
                    КонецЕсли;
                    Значение = СокрЛП(Значение);
                КонецЕсли;
                Результат.Вставить(ИмяЗначения, Значение);
                Если Дерево.Колонки.Найти(ИмяЗначения) = Неопределено Тогда
                    Дерево.Колонки.Добавить(ИмяЗначения);
                КонецЕсли;
                Если ИмяЗначения = "text" Тогда
                    СтрДерево[ИмяЗначения] = ?(СтрДлина(Значение) > 1, Сред(Значение, 2), Значение);
                ИначеЕсли ИмяЗначения = "id" ИЛИ ИмяЗначения = "date" Тогда
                    СтрДерево[ИмяЗначения] = Число(Значение);
                Иначе
                    СтрДерево[ИмяЗначения] = Значение;
                КонецЕсли;
            ИначеЕсли ТипДанных = "Массив" Тогда
                Поз = 0;
                Для Сч = 1 По СтрДлина(ТекстJSON) Цикл
                    Символ = Сред(ТекстJSON, Сч, 1);
                    Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда
                        Поз = Сч;
                        Прервать;
                    КонецЕсли;
                КонецЦикла;
                Если Поз = 0 Тогда
                    Значение = ТекстJSON;
                    ТекстJSON = "";
                Иначе
                    Значение = Лев(ТекстJSON, Поз - 1);
                    ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));
                КонецЕсли;
                Значение = СокрЛП(Значение);
                Результат.Добавить(Значение);
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
КонецПроцедуры

 

Теперь опишем процедуру, заполняющую табличную часть «КомандыПользователей» либо регистр сведений:

 

&НаСервере
Процедура ЗаполнитьРС(ДеревоЗн)
    Для Каждого СтрОк Из ДеревоЗн.Строки Цикл //"Ок"
        Для Каждого СтрНов Из СтрОк.Строки Цикл //
            Для Каждого СтрАп Из СтрНов.Строки Цикл //update_id
                Для Каждого СтрМесс Из СтрАп.Строки Цикл //message_id
                    date = СтрМесс.date;
                    Команда = СокрЛП(СтрМесс.text);
                    Параметр = "";
                    
                    ПозицияПараметра = Найти(Команда, " "); //СтрНайти(Команда, " ") не подходит, т.к. ищет в различных направлениях - не только с начала строки
                    Если ПозицияПараметра <> 0 Тогда
                        Параметр = СокрЛП(Сред(Команда, ПозицияПараметра + 1));
                        //{если версия ниже 1С 8.3.6 разкомментируйте
                        //Параметр = ПереобразоватьЮникод(Параметр);
                        //}
                        Команда = Лев(Команда, ПозицияПараметра - 1);
                    КонецЕсли;
                    Если ЗначениеЗаполнено(Команда) Тогда
                        МассивНайденныхКоманд = Объект.ТаблицаПонимаемыхКоманд.НайтиСтроки(Новый Структура("Имя", Команда));
                        Если МассивНайденныхКоманд.Количество() > 0 Тогда
                            Для Каждого СтрИнфо Из СтрМесс.Строки Цикл //message_id
                                chat_id = СтрИнфо.id;
                                Если ЗначениеЗаполнено(chat_id) И chat_id > 0 Тогда
                                    //{Раскомментируйте, если используете регистр сведений КомандыПользователей
                                    //РС = РегистрыСведений.КомандыПользователей.СоздатьНаборЗаписей();
                                    //РС.Отбор.chat_id.Установить(chat_id);
                                    //РС.Отбор.date.Установить(date);
                                    //РС.Прочитать();
                                    //
                                    //Если РС.Количество() > 0 Тогда
                                    //
                                    //         Для Каждого СтрРС Из РС Цикл
                                    //                     Если НЕ СтрРС.Выполнено Тогда
                                    //                                 СтрРС.Выполнено = ВыполнитьКомандуБота(СтрРС);
                                    //                     КонецЕсли;
                                    //         КонецЦикла;
                                    //
                                    //         РС.Записать();
                                    //
                                    //Иначе
                                    //         РСЗ = РегистрыСведений.КомандыПользователей.СоздатьМенеджерЗаписи();
                                    //         РСЗ.chat_id = chat_id;
                                    //         РСЗ.date = date;
                                    //         РСЗ.Команда = Команда;
                                    //         РСЗ.Выполнено = ВыполнитьКомандуБота(РСЗ);
                                    //         РСЗ.Записать();
                                    //
                                    //КонецЕсли;
                                    //}
                                    //{а это закомментируйте, если используете РС КомандыПользователей
                                    РС = Объект.КомандыПользователей.НайтиСтроки(Новый Структура("chat_id, date", chat_id, date));
                                    Если РС.Количество() > 0 Тогда
                                        Для Каждого СтрРС Из РС Цикл
                                            Если НЕ СтрРС.Выполнено Тогда
                                                СтрРС.Выполнено = ВыполнитьКомандуБота(СтрРС, Параметр);
                                            КонецЕсли;
                                        КонецЦикла;
                                    Иначе
                                        РСЗ = Объект.КомандыПользователей.Добавить();
                                        РСЗ.chat_id = chat_id;
                                        РСЗ.date = date;
                                        РСЗ.Команда = Команда;
                                        РСЗ.Выполнено = ВыполнитьКомандуБота(РСЗ, Параметр);
                                    КонецЕсли;
                                    //}
                                    прервать;
                                КонецЕсли;
                            КонецЦикла;
                        Иначе
                            //команда не найдена
                            //можно вывести справку по командам
                            //...
                        КонецЕсли;
                    КонецЕсли;
                КонецЦикла;
            КонецЦикла;
        КонецЦикла;
    КонецЦикла
КонецПроцедуры

 

Если вы будете использовать регистр сведений (я назвал его «КомандыПользователей»), то закомментируйте/раскомментируйте соответствующие участки кода.

            Обратите внимание, что если версия ниже 1С 8.3.6, то в коде переменную Параметр надо преобразовать из Юникода (этот участок обозначен в коде в комментарии):

 

//{если версия ниже 1С 8.3.6 разкомментируйте
//Параметр = ПереобразоватьЮникод(Параметр);
//}

 

Для этого используем две функции Юникод – парсер (он нужен только для версии 1С ниже 8.3.6):

 

&НаСервере
Функция ПереобразоватьЮникод(Знач СтрокаВход)
    Строка = СтрокаВход;
    // Создаем таблицу спецСимволов
    ТаблицаСимволов = Новый ТаблицаЗначений;
    ТаблицаСимволов.Колонки.Добавить("КодСимвола", Новый ОписаниеТипов("Строка", ,
            Новый КвалификаторыСтроки(9, ДопустимаяДлина.Переменная)), , );
    ТаблицаСимволов.Колонки.Добавить("ЗначениеКода", Новый ОписаниеТипов("Строка", ,
            Новый КвалификаторыСтроки(1, ДопустимаяДлина.Переменная)), , );
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\""";
    Стр.ЗначениеКода = """";
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\n";
    Стр.ЗначениеКода = Символы.ПС;
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\t";
    Стр.ЗначениеКода = Символы.Таб;
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\/";
    Стр.ЗначениеКода = "\";
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\u2013";
    Стр.ЗначениеКода = "–";
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\r";
    Стр.ЗначениеКода = Символы.ВК;
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\u00bb";
    Стр.ЗначениеКода = """";
    Стр = ТаблицаСимволов.Добавить();
    Стр.КодСимвола = "\u00ab";
    Стр.ЗначениеКода = """";
    Для каждого Стр Из ТаблицаСимволов Цикл // перебор спец символов
        
        КодСимв = СокрЛП(Стр.КодСимвола);
        ЗначениеСимвола = Стр.ЗначениеКода;
        Строка = СтрЗаменить(Строка, КодСимв, ЗначениеСимвола);
    КонецЦикла;
    СтрокаСимволов = "абвгдеёжзийклмнопрстуфхцчшщъыьэюяАБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ"""; // набор декодируемых символов. Если вам нужны еще символы просто впишите их
    КоличествоСимв = СтрДлина(СтрокаСимволов);
    Счетчик = 0;
    Пока Счетчик <= КоличествоСимв Цикл // кодировка в обычные символы
        ТекСимвол = Сред(СтрокаСимволов, Счетчик, 1);
        ЮКод = ЮникодСимвола(ТекСимвол);
        Строка = СтрЗаменить(Строка, НРег(ЮКод), ТекСимвол);
        Строка = СтрЗаменить(Строка, ВРег(ЮКод), ТекСимвол);
        Счетчик = Счетчик + 1;
    КонецЦикла;
    Возврат Строка;
КонецФункции



&НаСервере
Функция ЮникодСимвола(знач Символ)
    пЧисло = КодСимвола(Символ, 1); СимвСтр = "\u0000"; лЦифры = "123456789ABCDEF"; Рез = пЧисло; лСтр = "";
    Пока Рез > 0 Цикл
        Ост = Рез % 16;
        если ост < 10 Тогда лСтр = "" + Ост + лСтр;
        Иначе лСтр = Сред(лЦифры, Ост, 1) + лСтр; КонецЕсли;
        Рез = Цел(Рез / 16);
    КонецЦикла;
    Возврат Лев(СимвСтр, 6 - СтрДлина(лСтр)) + лСтр;
КонецФункции

//}

 

В процедуре ЗаполнитьРС() вызывается функция ВыполнитьКомандуБота(ЗаписьРегистра, Параметр), где ЗаписьРегистра – это строка табличной части ТаблицаПонимаемыхКоманд. Параметр – параметр команды (то, что написал боту пользователь).

 

&НаСервере
Функция ВыполнитьКомандуБота(ЗаписьРегистра, Параметр)
    Команда = ЗаписьРегистра.Команда;
    МассивНайденныхСтрок = Объект.ТаблицаПонимаемыхКоманд.НайтиСтроки(Новый Структура("Имя", Команда)); //исправьте, если используете РС
    Если МассивНайденныхСтрок.Количество() > 0 Тогда
        Для Каждого Стр Из МассивНайденныхСтрок Цикл
            Если Стр.ВыполняемоеДействие = "ВывестиПриветствие" Тогда
                //////ВывестиПриветствие(ЗаписьРегистра.chat_id);
            ИначеЕсли Стр.ВыполняемоеДействие = "ВывестиПодсказку" Тогда
                //////ВывестиПодсказку(ЗаписьРегистра.chat_id);
            ИначеЕсли Стр.ВыполняемоеДействие = "СистемнаИнформация" Тогда
                //////ВывестиСистемнуюИнформацию(ЗаписьРегистра.chat_id, Параметр);
            Иначе
                //////ВывестиПодсказку(ЗаписьРегистра.chat_id);
            КонецЕсли;
        КонецЦикла;
    Иначе
        //////ВывестиПодсказку(ЗаписьРегистра.chat_id);
    КонецЕсли;
    возврат Истина;
КонецФункции



&НаСервере
Процедура СообщитьОбОшибке(chat_id, ТекстОшибки)
    Ресурс = "bot" + Объект.Токен + "/sendMessage?chat_id=" + СтрЗаменить(Формат(chat_id, "ЧДЦ=; ЧС=; ЧРГ=."), ".", "") + "&text=" + ТекстОшибки;
    Соединение = Новый HTTPСоединение(Объект.Сервер, 443, , , , , Новый ЗащищенноеСоединениеOpenSSL());
    Запрос = Новый HTTPЗапрос(Ресурс);
    Ответ = Соединение.Получить(Запрос);
КонецПроцедуры



//Текстовое представление списка команд
&НаСервере
Функция СписокКоманд()
    СтрВозврата = "";
    Для Каждого Стр Из Объект.ТаблицаПонимаемыхКоманд Цикл
        СтрВозврата = СтрВозврата + ?(СтрВозврата <> "", Символы.ПС, "") + Стр.Имя + " - " + Стр.Описание;
    КонецЦикла;
    возврат СтрВозврата;
КонецФункции



&НаСервере
Процедура ВывестиПриветствие(chat_id)
    Ресурс = "bot" + Объект.Токен + "/sendMessage?chat_id=" + СтрЗаменить(Формат(chat_id, "ЧДЦ=; ЧС=; ЧРГ=."), ".", "") + "&text= Здравствуйте!" +
        Символы.ПС + СписокКоманд() + Символы.ПС + "Удачи!";
    Соединение = Новый HTTPСоединение(Объект.Сервер, 443, , , , , Новый ЗащищенноеСоединениеOpenSSL());
    Запрос = Новый HTTPЗапрос(Ресурс);
    Ответ = Соединение.Получить(Запрос);
КонецПроцедуры



&НаСервере
Процедура ВывестиПодсказку(chat_id)
    Ресурс = "bot" + Объект.Токен + "/sendMessage?chat_id=" + СтрЗаменить(Формат(chat_id, "ЧДЦ=; ЧС=; ЧРГ=."), ".", "") + "&text= " + СписокКоманд();
    Соединение = Новый HTTPСоединение(Объект.Сервер, 443, , , , , Новый ЗащищенноеСоединениеOpenSSL());
    Запрос = Новый HTTPЗапрос(Ресурс);
    Ответ = Соединение.Получить(Запрос);
КонецПроцедуры



&НаСервере
Процедура ВывестиСистемнуюИнформацию(chat_id, Параметр)
    Параметр = ?(СокрЛП(Параметр) = "", "ВерсияПриложения", СокрЛП(Параметр));
    Инфо = Новый СистемнаяИнформация();
    Информация = "";
    Попытка
        Информация = Инфо[Параметр];
    Исключение
        Информация = ОписаниеОшибки();
    КонецПопытки;
    Ресурс = "bot" + Объект.Токен + "/sendMessage?chat_id=" + СтрЗаменить(Формат(chat_id, "ЧДЦ=; ЧС=; ЧРГ=."), ".", "") + "&text= " + Информация;
    Соединение = Новый HTTPСоединение(Объект.Сервер, 443, , , , , Новый ЗащищенноеСоединениеOpenSSL());
    Запрос = Новый HTTPЗапрос(Ресурс);
    Ответ = Соединение.Получить(Запрос);
КонецПроцедуры

 

Здесь ВывестиСистемнуюИнформацию() – выводит информацию из базы данных1С. В нашем примере пользователю в Telegram бот может отправить информацию:

  • о версии операционной системы;
  • о версии используемого 1С:Предприятия 8 в формате <основная версия>.<младшая версия>.<релиз>.<дополнительный номер релиза>.(например, 8.2.9.200);
  • Уникальный идентификатор клиента. Для данного компьютера и данного пользователя операционной системы идентификатор один, вне зависимости от информационной базы и пользователя информационной базы;
  • о веб-браузере (userAgent);
  • о размере оперативной памяти;
  • Идентификатор процессора;
  • тип платформы, в рамках которой осуществляется работа.

Все, что мы сделали будет работать только тогда, когда пользователь нажмет кнопку «Показать сообщения».

Для того, чтобы все работало автоматом, лучше использовать фоновое задание. Но так как наша обработка не привязана к конкретной базе данных и к конкретной конфигурации. То подключим обработчик ожидания.

Сделаем так:

Создадим команду формы «ЗапускФоновыхЗаданий», разместим соответствующую кнопку на форме. Обработчик команды:

 

//Автоматическая работа

&НаКлиенте
Процедура АвтоматическаяРабота(Команда)
    ПодключитьОбработчикОжидания("Автомат", 15); //Запуск каждые 15 секунд
КонецПроцедуры

&НаКлиенте
Процедура Автомат()
    ПоказатьСообщения();
КонецПроцедуры

////

 

Вот и все – обработка прилагается.

Отдельное спасибо пользователю Инфостарт igo1 -  перекодировка из Юникода (Unicode) в строку.

Основу для построения чата для версии 1С ниже 8.3.6 (парсер JSON) получил отсюда

 

UPD. В комментариях был задан вопрос "как отправлять файлы".

Вот текст процедуры, которая выполняет отчет "Продажи" (на СКД), сохраняет результат в Excel и отправляет в Telegram:

 

Процедура ОтправитьФайл(chat_id)
    
    Таб = Новый ТабличныйДокумент;
    
    Отчеты.Продажи.Создать().СкомпоноватьРезультат(Таб);
    
    ИмяФайла = ПолучитьИмяВременногоФайла("xlsx");
    
    Таб.Записать(ИмяФайла);
    
    СтрокаСоединения = "/bot" + Объект.Токен + "/sendDocument";
    
    Boundary = "----" + Строка(Новый УникальныйИдентификатор());
    
    //Определяем массив для процедуры ОбъединитьФайлы
    МассивФайловДляОбъединения = Новый Массив;
    
    //Формируем начальный фрагмент файла POST-запроса
    ИмяФайлаОтправкиНачало = ПолучитьИмяВременногоФайла("txt");
    ФайлОтправкиНачало = Новый ЗаписьТекста(ИмяФайлаОтправкиНачало, КодировкаТекста.UTF8);
    
    //Формируем конечный фрагмент файла POST-запроса
    ИмяФайлаОтправкиКонец = ПолучитьИмяВременногоФайла("txt");
    ФайлаОтправкиКонец = Новый ЗаписьТекста(ИмяФайлаОтправкиКонец, КодировкаТекста.UTF8);
    
    ТекстДляОтправки = "";
    
    ТекстДляОтправки = ТекстДляОтправки + "--" + Boundary + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""chat_id""" + Символы.ПС + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + chat_id + Символы.ПС;
    
    ТекстДляОтправки = ТекстДляОтправки + "--" + Boundary + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""document""; filename=""report.xlsx""" + Символы.ПС;
    
    ФайлОтправкиНачало.ЗаписатьСтроку(ТекстДляОтправки);
    ФайлОтправкиНачало.Закрыть();
    
    МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиНачало);
    
    МассивФайловДляОбъединения.Добавить(СокрЛП(ИмяФайла));
    
    ТекстДляОтправки = "" + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + "--" + Boundary + "--";
    ФайлаОтправкиКонец.ЗаписатьСтроку(ТекстДляОтправки);
    ФайлаОтправкиКонец.Закрыть();
    МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиКонец);
    
    ИмяФайлаОтправки = ПолучитьИмяВременногоФайла("txt");
    ОбъединитьФайлы(МассивФайловДляОбъединения, ИмяФайлаОтправки);
    
    HTTPЗапрос = Новый HTTPЗапрос;
    Заголовки = Новый Соответствие;
    
    HTTPЗапрос.Заголовки.Вставить("Connection", "keep-alive");
    HTTPЗапрос.Заголовки.Вставить("Content-Type", "multipart/form-data; boundary=" + Boundary);
    
    HTTPЗапрос.УстановитьИмяФайлаТела(ИмяФайлаОтправки);
    HTTPЗапрос.АдресРесурса = СтрокаСоединения;
    
    ЗащищенноеСоединение = Новый ЗащищенноеСоединениеOpenSSL(Новый СертификатКлиентаWindows, Новый СертификатыУдостоверяющихЦентровWindows);
    HTTPСоединение = Новый HTTPСоединение(Объект.Сервер, , , , , , ЗащищенноеСоединение);
    
    Попытка
        ОтветHTTP = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
    Исключение
        СообщитьОбОшибке(chat_id, ОписаниеОшибки());
    КонецПопытки;
КонецПроцедуры

Спасибо,  FSerg, отличие отправки фото от файла - API метод sendDocument.

Скачать файлы

Наименование Файл Версия Размер
Пример готовой обработки обмен между 1С и мессенджера Telegram

.epf 12,95Kb
534
.epf 12,95Kb 534 Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. iolko 290 19.11.15 11:56 Сейчас в теме
2. Luchik 641 19.11.15 13:46 Сейчас в теме
(1) iolko, в публикации много чего не показано, например, как из 1С передавать файлы... или по команде из telegram запускать, допустим, выгрузку информационно базы - напишите, многим будет интересно
5. iolko 290 20.11.15 04:00 Сейчас в теме
(2) это да (про файлы) , в принципе вся логика уже готова, наверное в понедельник будет доступно, ну и подход к обработке сообщений, немного другой.
6. nomadon 349 20.11.15 11:29 Сейчас в теме
(5) iolko, (1) iolko, (2) посмотрите этот пример)) http://infostart.ru/public/416348/
9. iolko 290 22.11.15 17:28 Сейчас в теме
(6) nomadon, да понятно, что уже выдумато ))) но вот ни как не могу допонять как отправлять файлы.... вот ни как... может у кого есть идеи или примеры или толковое описание...
grin_64; yur4ik9408; +2 Ответить
162. user853472 25.02.18 23:32 Сейчас в теме
(1)
Доброго времени суток! Помогите отправить картинку с клавиатурой inline_keyboard.

Если убрать секцию с клавиатурой то все работает. Клавиатура нужна очень...шел третий день....

Пользуюсь кодом:
ддКартинка = Блюдо.Ссылка.ОсновноеИзображение.Хранилище.Получить().ПолучитьДвоичныеДанные();
				
				времКаталог = КаталогВременныхФайлов();
				времФайлКартинки = ПолучитьИмяВременногоФайла("jpg");
				имяВремяФайла = СтрЗаменить(времФайлКартинки,времКаталог,"");
								
				ддКартинка.Записать(времФайлКартинки);
				
				СтрокаСоединения = "/bot" + Константы.Токен.Получить() + "/sendPhoto";
				
				//Определяем массив для процедуры ОбъединитьФайлы 
				МассивФайловДляОбъединения = Новый Массив; 
				
				//Формируем начальный фрагмент файла POST-запроса 
				ИмяФайлаОтправкиНачало = ПолучитьИмяВременногоФайла("txt"); 
				ФайлОтправкиНачало = Новый ЗаписьТекста(ИмяФайлаОтправкиНачало, КодировкаТекста.UTF8); 
				
				//Формируем конечный фрагмент файла POST-запроса 
				ИмяФайлаОтправкиКонец = ПолучитьИмяВременногоФайла("txt"); 
				ФайлаОтправкиКонец = Новый ЗаписьТекста(ИмяФайлаОтправкиКонец, КодировкаТекста.UTF8);
				
				ТекстДляОтправки = "";
				
				Boundary = "----" + Строка(Новый УникальныйИдентификатор());
				
				// ЧАТ
				ТекстДляОтправки = ТекстДляОтправки + "--" + Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""chat_id"""+ Символы.ПС + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + СокрЛП(Формат(Клиент.Код,"ЧГ=0")) + Символы.ПС;
				
				// ПОДПИСЬ  
				Подпись = "Наименование: " + Блюдо.Ссылка.Наименование + Символы.ПС + "Цена: " + Блюдо.Ссылка.Цена;  
				
				ТекстДляОтправки = ТекстДляОтправки + "--" + Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""caption""" + Символы.ПС + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + СокрЛП(Подпись) + Символы.ПС;
				                                                         
				// ФОТО
				ТекстДляОтправки = ТекстДляОтправки + "--" +  Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""photo""; filename=""" + имяВремяФайла + """" + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Type: image/jpg" + Символы.ПС;
				
				//КЛАВИАТУРА
				клСтруктура = Новый Структура;
				Строки = Новый Массив;
				Кнопки = Новый Массив;
				Кнопки.Добавить(Новый Структура("text, callback_data", "В корзину", Блюдо.Ссылка.Код));
				Строки.Добавить(Кнопки);	
				клСтруктура.Вставить("inline_keyboard",Строки);
				ЗаписьJSON = Новый ЗаписьJSON;
				ЗаписьJSON.УстановитьСтроку(Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет));  //Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет,,,ЭкранированиеСимволовJSON.СимволыВнеASCII)  
				ЗаписатьJSON(ЗаписьJSON,клСтруктура,,);
				Клавиатура = ЗаписьJSON.Закрыть();

				ТекстДляОтправки = ТекстДляОтправки + "--" +  Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""reply_markup""" + Символы.ПС+ Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + СокрЛП(Клавиатура) + Символы.ПС; 				
				
				ФайлОтправкиНачало.ЗаписатьСтроку(ТекстДляОтправки);
				ФайлОтправкиНачало.Закрыть(); 
				
				МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиНачало); 
				МассивФайловДляОбъединения.Добавить(времФайлКартинки); 
				
				ТекстДляОтправки = "";
				ТекстДляОтправки = ТекстДляОтправки + Символы.ПС  + "--" +  Boundary+"--";
				ФайлаОтправкиКонец.ЗаписатьСтроку(ТекстДляОтправки);
				ФайлаОтправкиКонец.Закрыть(); 
				МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиКонец); 
				
				ИмяФайлаОтправки = ПолучитьИмяВременногоФайла("txt");
				
				ОбъединитьФайлы(МассивФайловДляОбъединения, ИмяФайлаОтправки);
				
				HTTPЗапрос = Новый HTTPЗапрос;
				HTTPЗапрос.Заголовки.Вставить("Connection", "keep-alive"); 
				HTTPЗапрос.Заголовки.Вставить("Content-Type", "multipart/form-data; boundary="+Boundary); 
				HTTPЗапрос.УстановитьИмяФайлаТела(ИмяФайлаОтправки);    
				HTTPЗапрос.АдресРесурса = СтрокаСоединения; 
				
				Результат = ОтправитьЗапросНаОбработкуВTelegramPOST(HTTPЗапрос);
Показать
163. user853472 25.02.18 23:33 Сейчас в теме
(1)

Доброго времени суток! Помогите отправить картинку с клавиатурой inline_keyboard.

Если убрать секцию с клавиатурой то все работает. Клавиатура нужна очень...шел третий день....

Пользуюсь кодом:
ддКартинка = Блюдо.Ссылка.ОсновноеИзображение.Хранилище.Получить().ПолучитьДвоичныеДанные();
				
				времКаталог = КаталогВременныхФайлов();
				времФайлКартинки = ПолучитьИмяВременногоФайла("jpg");
				имяВремяФайла = СтрЗаменить(времФайлКартинки,времКаталог,"");
								
				ддКартинка.Записать(времФайлКартинки);
				
				СтрокаСоединения = "/bot" + Константы.Токен.Получить() + "/sendPhoto";
				
				//Определяем массив для процедуры ОбъединитьФайлы 
				МассивФайловДляОбъединения = Новый Массив; 
				
				//Формируем начальный фрагмент файла POST-запроса 
				ИмяФайлаОтправкиНачало = ПолучитьИмяВременногоФайла("txt"); 
				ФайлОтправкиНачало = Новый ЗаписьТекста(ИмяФайлаОтправкиНачало, КодировкаТекста.UTF8); 
				
				//Формируем конечный фрагмент файла POST-запроса 
				ИмяФайлаОтправкиКонец = ПолучитьИмяВременногоФайла("txt"); 
				ФайлаОтправкиКонец = Новый ЗаписьТекста(ИмяФайлаОтправкиКонец, КодировкаТекста.UTF8);
				
				ТекстДляОтправки = "";
				
				Boundary = "----" + Строка(Новый УникальныйИдентификатор());
				
				// ЧАТ
				ТекстДляОтправки = ТекстДляОтправки + "--" + Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""chat_id"""+ Символы.ПС + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + СокрЛП(Формат(Клиент.Код,"ЧГ=0")) + Символы.ПС;
				
				// ПОДПИСЬ  
				Подпись = "Наименование: " + Блюдо.Ссылка.Наименование + Символы.ПС + "Цена: " + Блюдо.Ссылка.Цена;  
				
				ТекстДляОтправки = ТекстДляОтправки + "--" + Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""caption""" + Символы.ПС + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + СокрЛП(Подпись) + Символы.ПС;
				                                                         
				// ФОТО
				ТекстДляОтправки = ТекстДляОтправки + "--" +  Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""photo""; filename=""" + имяВремяФайла + """" + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Type: image/jpg" + Символы.ПС;
				
				//КЛАВИАТУРА
				клСтруктура = Новый Структура;
				Строки = Новый Массив;
				Кнопки = Новый Массив;
				Кнопки.Добавить(Новый Структура("text, callback_data", "В корзину", Блюдо.Ссылка.Код));
				Строки.Добавить(Кнопки);	
				клСтруктура.Вставить("inline_keyboard",Строки);
				ЗаписьJSON = Новый ЗаписьJSON;
				ЗаписьJSON.УстановитьСтроку(Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет));  //Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет,,,ЭкранированиеСимволовJSON.СимволыВнеASCII)  
				ЗаписатьJSON(ЗаписьJSON,клСтруктура,,);
				Клавиатура = ЗаписьJSON.Закрыть();

				ТекстДляОтправки = ТекстДляОтправки + "--" +  Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""reply_markup""" + Символы.ПС+ Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + СокрЛП(Клавиатура) + Символы.ПС; 				
				
				ФайлОтправкиНачало.ЗаписатьСтроку(ТекстДляОтправки);
				ФайлОтправкиНачало.Закрыть(); 
				
				МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиНачало); 
				МассивФайловДляОбъединения.Добавить(времФайлКартинки); 
				
				ТекстДляОтправки = "";
				ТекстДляОтправки = ТекстДляОтправки + Символы.ПС  + "--" +  Boundary+"--";
				ФайлаОтправкиКонец.ЗаписатьСтроку(ТекстДляОтправки);
				ФайлаОтправкиКонец.Закрыть(); 
				МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиКонец); 
				
				ИмяФайлаОтправки = ПолучитьИмяВременногоФайла("txt");
				
				ОбъединитьФайлы(МассивФайловДляОбъединения, ИмяФайлаОтправки);
				
				HTTPЗапрос = Новый HTTPЗапрос;
				HTTPЗапрос.Заголовки.Вставить("Connection", "keep-alive"); 
				HTTPЗапрос.Заголовки.Вставить("Content-Type", "multipart/form-data; boundary="+Boundary); 
				HTTPЗапрос.УстановитьИмяФайлаТела(ИмяФайлаОтправки);    
				HTTPЗапрос.АдресРесурса = СтрокаСоединения; 
				
				Результат = ОтправитьЗапросНаОбработкуВTelegramPOST(HTTPЗапрос);
Показать
170. user790109 8 11.03.18 18:40 Сейчас в теме
(163) у тебя не возникало ошибки в строке
ОбъединитьФайлы(МассивФайловДляОбъединения, ИмяФайлаОтправки);
? возникает ошибка типа Ошибка при вызове метода контекста (ОбъединитьФайлы)
ОбъединитьФайлы(МассивФайловДляОбъединения, ИмяФайлаОтправки);
по причине:
Ошибка сборки файла
по причине:
Ошибка совместного доступа к файлу 'C:\Users\Гуру\AppData\Local\Temp\v8_7B5A_12.txt'
174. user853472 19.03.18 20:33 Сейчас в теме
(170) нет не возникало.
Совместный доступ, значит уже кто-то/что-то юзает это файл
195. slavik_s 12.12.18 10:08 Сейчас в теме
(163) А зачем посылать клавиатуру в тот момент когда отсылаем картинку? В момент отправки картинки на сервер Телеграм, он возвращает уникальный номер картинки, поэтому в дальнейшем достаточно покупателю отсылать этот номер, а сервер находит вашу картинку и посылает её. Порядок работы нужно изменить. Сначала отсылаем ВСЕ КАРТИНКИ и получаем их номера из Телеграм и записываем их у себя в базу. А теперь имея номер картинки посылаем file_id и подпись под картинкой и необходимую клавиатуру, то есть манипулируем уже не картинками, а номерами file_id. Об этом же все написано в документации Телеграм Bot API.
3. Lapitskiy 994 19.11.15 17:18 Сейчас в теме
Ух, жесть какая-то :)
Все больше на ИС обработок скрещивания1С и прочего и прочего :)
Это замечательно, но напоминает анекдот о том, как британские ученые скрещивали слона и слона, не для пользы, а так просто, "позырить" :)
user645801_yyyuuu123q; simuljakr; Hobbit_Jedi; inf012; romankoav; German; +6 10 Ответить
4. Luchik 641 19.11.15 17:29 Сейчас в теме
(3) Lapitskiy, ;) Можно и для
"позырить"
- я так частенько от наработок других программистов что-то интересное для себя нахожу, поэтому и сам готов поделиться...
Albert_2008; kamsky93; Aleks_Zorro; METAL; WanGoff; +5 Ответить
7. eskor 94 20.11.15 11:32 Сейчас в теме
Luchik, отличная статья, толково и не затянуто. Надо будет поэкспериментировать с Telegram, а то раньше все руки не доходили разобраться.
Спасибо, "плюс в репу"!!!
8. Luchik 641 20.11.15 13:33 Сейчас в теме
(7) eskor, очень приятно :) Спасибо!
10. Luchik 641 24.11.15 09:15 Сейчас в теме
Посмотри http://catalog.1cv7.md/public/387433/ там в комментарии FSerg сделал через ОбъединитьФайлы()
11. PLAstic 285 25.11.15 09:28 Сейчас в теме
198. mamont_d 04.02.19 14:06 Сейчас в теме
(11)а ты сам, резист или энлайт?
199. PLAstic 285 04.02.19 15:02 Сейчас в теме
(198) Кто за прогресс, за развитие науки и технологий, тот, кто и сам занимается этим развитием в 1С, не может быть резистом.
12. sound 534 25.11.15 09:40 Сейчас в теме
Телеграм это тема! Жаль что у меня сервер в закрытой сети, так бы тоже нашел применение. Автору респект за труды и статью.
13. proger1c81 25.11.15 10:56 Сейчас в теме
Поставил себе в избранное. Спасибо за труды.
Как здесь поставить лайк или плюсик за статью?
14. Luchik 641 25.11.15 11:02 Сейчас в теме
(13) proger1c81, Спасибо, достаточно добавления в Избранное :)
15. FSerg 66 27.11.15 11:03 Сейчас в теме
Класс!
Побежал прикручивать бота к 1С :)
16. TreeDogNight 21 30.11.15 15:23 Сейчас в теме
Спасибо за интересную и полезную статью!
К сожалению процедура ОтправитьФайл() не работает=( Всё проходит без ошибок, но и сообщения в телеграме не приходит... Подозреваю, что я передаю туда не правильный "chat_id". Можете пожалуйста объяснить, что из себя представляет этот "chat_id" ?
17. Luchik 641 30.11.15 16:35 Сейчас в теме
(16) TreeDogNight, chat_id это id пользователя - число. Все кто пишет боту получают chat_id. Напишите что-нибудь своему боту, а затем выполните https://api.telegram.org/ВАШТОКЕН/getUpdates в браузере - в ответе сможете найти chat_id (аналогичные действия выполнены в процедуре ПоказатьСообщения() )
TreeDogNight; +1 Ответить
63. DanilaDru 263 05.08.16 16:45 Сейчас в теме
(17) Вы сталкивались с тем что https://api.telegram.org/ТОКЕН/getUpdates возвращает только то что написал в бот создатель бота, а другие пользовтаели телеграмма не видны ?
18. TreeDogNight 21 01.12.15 06:36 Сейчас в теме
Получается chat_id я передаю правильный...
А на что кстати влияет filename?
ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""document""; filename=""report.xlsx""" + Символы.ПС
19. TreeDogNight 21 01.12.15 06:45 Сейчас в теме
 ТекстДляОтправки = ТекстДляОтправки + chat_id + Символы.ПС;

Доработал это место, добавил формат
ТекстДляОтправки = ТекстДляОтправки + Формат(chat_id, "ЧГ=0") + Символы.ПС;

И всё заработало, файл пришел
97. Nicholas 854 11.03.17 14:47 Сейчас в теме
Столкнулся вот с такой ошибкой:

{Обработка.ТелеграммБот.Форма.Форма.Форма(19)}: Ошибка при вызове метода контекста (ПрочитатьДвоичныеДанныеОтвета)
ПрочитатьДвоичныеДанныеОтвета(ДвоичныеДанныеОтвета);
по причине:
Переполнение стека встроенного языка на сервере
по причине:

Обработка.ТелеграммБот.Форма.Форма.Форма : 32 : СформироватьДерево(ДеревоЗн, ДеревоЗн, ЧтениеJSON);
Обработка.ТелеграммБот.Форма.Форма.Форма : 71 : СформироватьДерево(Дерево, НовСтр, ЧтениеJSON);
Обработка.ТелеграммБот.Форма.Форма.Форма : 75 : СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON, ЧтениеJSON.ТекущееЗначение);
Обработка.ТелеграммБот.Форма.Форма.Форма : 83 : СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON);
...
Обработка.ТелеграммБот.Форма.Форма.Форма : 75 : СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON, ЧтениеJSON.ТекущееЗначение);
Обработка.ТелеграммБот.Форма.Форма.Форма : 83 : СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON);
Обработка.ТелеграммБот.Форма.Форма.Форма : 75 : СформироватьДерево(Дерево, СтрДерево, ЧтениеJSON, ЧтениеJSON.ТекущееЗначение);
Обработка.ТелеграммБот.Форма.Форма.Форма : 0
по причине:
Переполнение стека встроенного языка на сервере
98. Luchik 641 13.03.17 09:47 Сейчас в теме
(97)
Да, рекурсия имеет недостаток, связанный с возможностью переполнения стека. Используйте поуровневый обход дерева - пример здесь: http://infostart.ru/public/20797/
Nicholas; +1 Ответить
100. bloodydiman 1 22.03.17 10:22 Сейчас в теме
(97) Проблему решил следующим образом:

	ДеревоЗн = Новый ДеревоЗначений();	
	ЧтениеJSON = Новый ЧтениеJSON();
	ЧтениеJSON.ОткрытьФайл(ИмяФайла);
	СтрДерево = ДеревоЗн;
	Пока ЧтениеJSON.Прочитать() Цикл
		СтрДерево = СформироватьДерево(ДеревоЗн, СтрДерево, ЧтениеJSON,, Ложь);	
	КонецЦикла;
	ЧтениеJSON.Закрыть();

&НаСервере
Функция СформироватьДерево(ДеревоЗн, СтрДерево, ЧтениеJSON, Знач ИмяКолонки = Неопределено, Прочитать = Истина)
	
	Если Прочитать Тогда
		ЧтениеJSON.Прочитать();
	КонецЕсли;
	TипJSON = ЧтениеJSON.ТипТекущегоЗначения;
	Если TипJSON = ТипЗначенияJSON.НачалоОбъекта ИЛИ TипJSON = ТипЗначенияJSON.НачалоМассива Тогда
		НовСтр = СтрДерево.Строки.Добавить();
		Возврат СформироватьДерево(ДеревоЗн, НовСтр, ЧтениеJSON);
	ИначеЕсли TипJSON = ТипЗначенияJSON.ИмяСвойства Тогда
		Возврат СформироватьДерево(ДеревоЗн, СтрДерево, ЧтениеJSON, ЧтениеJSON.ТекущееЗначение);
	ИначеЕсли TипJSON = ТипЗначенияJSON.Число ИЛИ TипJSON = ТипЗначенияJSON.Строка ИЛИ TипJSON = ТипЗначенияJSON.Булево ИЛИ TипJSON = ТипЗначенияJSON.Null Тогда 
		Если ДеревоЗн.Колонки.Найти(ИмяКолонки) = Неопределено Тогда
			ДеревоЗн.Колонки.Добавить(ИмяКолонки);
		КонецЕсли;
		СтрДерево[ИмяКолонки] = ЧтениеJSON.ТекущееЗначение;
		Возврат СформироватьДерево(ДеревоЗн, СтрДерево, ЧтениеJSON);
	ИначеЕсли TипJSON = ТипЗначенияJSON.Комментарий Тогда
		Если ДеревоЗн.Колонки.Найти("Комментарий") = Неопределено Тогда
			ДеревоЗн.Колонки.Добавить("Комментарий");
		КонецЕсли;
		СтрДерево.Комментарий = ЧтениеJSON.ТекущееЗначение;
		Возврат СформироватьДерево(ДеревоЗн, СтрДерево, ЧтениеJSON);
	ИначеЕсли СтрДерево <> Неопределено Тогда
		Возврат СтрДерево.Родитель;
	//	СформироватьДерево(ДеревоЗн, СтрДерево.Родитель, ЧтениеJSON);
	КонецЕсли;
	
КонецФункции
Показать
101. Nicholas 854 22.03.17 11:32 Сейчас в теме
104. PLAstic 285 23.03.17 16:36 Сейчас в теме
(100) Я давал выше вариант, при котором никаких проблем нет. Уже несколько ботов сделал и они прекрасно работают.
simuljakr; +1 Ответить
214. simuljakr 196 26.04.21 23:29 Сейчас в теме
(104). не нашел ваш вариант решения ошибки "Переполнение стека встроенного языка на сервере ", который вы давали выше. Могли бы вы продублировать?
217. user1554859 30.04.21 11:20 Сейчас в теме
(104)Подскажите пожалуйста где вариант решения ошибки.
20. eskor 94 02.12.15 11:01 Сейчас в теме
Парни, ткните носом - начал экспериментировать с ботом, но впоролся в отсутствие описания команд.
Например \getUpdate возвращает все сообщения в истории чата. Но на практике нужны только новые, на крайний случай нужна команда на стороне бота для очистки чата(ов). Можно конечно отсекать сообщения на стороне 1С, но это несерьезно, иначе придется пересоздавать бота с завидной регулярностью.
21. Luchik 641 02.12.15 11:17 Сейчас в теме
(20) eskor, Telegram хранит сообщения чата некоторое время, по истечении которого \getUpdate уже не вернет никаких сообщений. Поэтому хранить старые и, соответственно, отбирать только новые надо на стороне 1С (напрмер, использовать регистр сведений)
22. eskor 94 02.12.15 11:25 Сейчас в теме
(21) Спасибо за ответ. Просто вчера начал долбить командами, до сих пор они еще в чат всплывают.
Кстати, на платформе 8.2 не хотят работать конструкции HTTPЗапрос. Заменил на СОМ-объект, стало намного удобнее:
Ресурс = "/bot" + Токен + "/getUpdates";
	HTTP = Новый COMОбъект("WinHttp.WinHttpRequest.5.1");
	Попытка
		HTTP.Open("GET", "https://"+Сервер+Ресурс, Ложь);
		HTTP.Send();
	Исключение
		//Сообщить(ОписаниеОшибки());
	КонецПопытки;
	ВхТекст = HTTP.ResponseText;

	ПрочитатьДанныеОтвета(ВхТекст);
Показать

на выходе получаем чистый текст, который на сервер передается без "бубна".
akR00b; MCitrus; TreeDogNight; +3 Ответить
23. TreeDogNight 21 03.12.15 07:22 Сейчас в теме
(20) eskor, На сайте телеграма в разделе описания API нашёл описания всех команд и их параметры, в том числе и getUpdates

Вот только как передать эти параметры в http запрос, пока не понял...
24. eskor 94 03.12.15 10:24 Сейчас в теме
(23) TreeDogNight, это я видел, даже пытался в разных вариантах в браузере подергать, увы безрезультатно. Будем надеяться, что срок хранения сообщений не так велик, хотя иметь возможность чистить чаты надо, однозначно. Должна быть команда аналогичная клиентской, что-то типа /ClearHistory или /ClearChat, пока я ее не нашел.
UPD: очередные грабли нашел: никак не могу подобрать символ переноса строки, скорее всего из-за СОМ-объекта не срабатывает Символы.ПС, конструкция html /n тоже не сработала,
-аналогично.
25. TreeDogNight 21 05.12.15 10:09 Сейчас в теме
(24) eskor, У меня получилось настроить получение актуальных обновлений. Вот код:
&НаСервере
Функция ПолучитьОбновления(Смещение = 0, КоличествоОбновлений = 100, Таймаут = 0)

	КоличествоОбновлений = Мин(КоличествоОбновлений, 100);
	
	//Соберем параметры для запроса, если таковые имеются:
	ПараметрыЗапроса = "";
	Если Смещение > 0 Тогда 
		ПараметрыЗапроса = "?offset="+Формат(Смещение, "ЧГ=0");	
	КонецЕсли;
	
	Если Не КоличествоОбновлений = 100 Тогда 
		Если ЗначениеЗаполнено(ПараметрыЗапроса) Тогда 
			ПараметрыЗапроса = "&limit="+Формат(КоличествоОбновлений, "ЧГ=0");	
		Иначе 
			ПараметрыЗапроса = "?limit="+Формат(КоличествоОбновлений, "ЧГ=0");	
		КонецЕсли;
	КонецЕсли;
	
	Если Таймаут > 0 Тогда 
		Если ЗначениеЗаполнено(ПараметрыЗапроса) Тогда 
			ПараметрыЗапроса = "&timeout="+Формат(Таймаут, "ЧГ=0");	
		Иначе 
			ПараметрыЗапроса = "?timeout="+Формат(Таймаут, "ЧГ=0");	
		КонецЕсли;                                                                                                
	КонецЕсли;
	
	Ресурс 				 = "bot" + Объект.Токен + "/"+ИмяМетодаHTTP+ПараметрыЗапроса;
	Соединение  		 = Новый HTTPСоединение(Объект.Сервер,443,,,,,Новый ЗащищенноеСоединениеOpenSSL());
	Запрос 				 = Новый HTTPЗапрос(Ресурс);
	Ответ 				 = Соединение.Получить(Запрос);
	ДвоичныеДанныеОтвета = Ответ.ПолучитьТелоКакДвоичныеДанные(); 
	
	Возврат ДвоичныеДанныеОтвета;
	
КонецФункции
Показать
27. eskor 94 07.12.15 14:18 Сейчас в теме
(25) TreeDogNight, мы похоже с GET запросом колдуем, для проверки сообщений пойдет на ура, а вот отправку надо в POST запросе гнать, как раз параметры в справке намекают на это, похоже именно там расстановка переносов и прочие параметры.
Для моего кода это изменять тип и вставлять параметры в HTTP.Send(.......). В джейсона простейшее преобразование через 2 массива, в одном ищешь свой символ и по тому же индексу получаешь соответствие, только вот что и зачем?
TreeDogNight; +1 Ответить
30. iolko 290 09.12.15 07:22 Сейчас в теме
(25) TreeDogNight,
Вообще можно сделать так....
1) Берем GetUpdates - получаем ID всех обновлений.
Пишем в массив, берем максимум от массива - это последнее обновление, пишем хоть куда (регистр, спр, константа)
И все... дальше отправляем запрос
getUpdates?offers=(тут ID сообщения +1)&limit=1
в результате .. если результат > 0 то у нас есть новое сообщение.
При этом если результат = 0 и потом выполнить GetUpdates - то история Telegram очищается.
Это одна из реализаций.

Вторая
Опрашиваем через GetUpdates - пишем в регистр ID, текст, ChatID и статус - отвечено или нет
ну а потом просто сравниваем то что пришло и отвечено - игнорим, то что пришло и не отвечено отвечаем и пишем статус.

При этом из текстов API видно, что GetUpdates хранит историю максимум за 24 часа... так что мы не перегрузим проверку на сообщения.
От как то так, Всем УдачеФФ!!
Aspire1C; Kireno; nightowl; METAL; eskor; TreeDogNight; +6 Ответить
31. TreeDogNight 21 09.12.15 07:46 Сейчас в теме
(30) iolko, Да, я как раз выбрал первый способ!
Теперь я задумался над авторизацией пользователя, для открытия доступа к командам бота.
Никто не знает, как можно пограммно провести аудентификацию пользователя?
33. iolko 290 09.12.15 08:58 Сейчас в теме
(31) TreeDogNight, Легко... если пользователь отправляет команду, допустим MyId - то отправляешь ему Его ID дальше ручками вносишь ее в спр пользователи.
а потом уже, чтобы отсеить ненужных проверяешь если ChatId есть в спр пользователей - велком , если нет ну не судьба тогда )))

Это первый вариант - при котором можно использовать первый вариант получения обновлений.

2 вариант - придумка для корпоративных систем (с которым нужно использовать второй вариант получения обновлений) - запрос на добавление, запоминаем ID и просим ввести адрес корпоративной почты, отправляем на этот адрес какой то сгенерированый ПИН, и ждем подтверждения.
Kireno; TreeDogNight; +2 Ответить
34. TreeDogNight 21 09.12.15 20:12 Сейчас в теме
(33) iolko, Интересные варианты реализации) Пока что решил просто сравнивать логин и пароль, с твердо прописанными в коде значениями=) А так, в сообщении выше, я имел виду аудентификацию в 1С уже существующих пользователей. На данный момент я склоняюсь к мнению, что осуществить это невозможно, так как пароль пользователя прочитать нельзя...
35. eskor 94 10.12.15 09:55 Сейчас в теме
(34) TreeDogNight, я пока эксперименты отложил, но в первом варианте сделал таблицу разрешенных пользователей и чатов, плюс лог всех входящих сообщений. Нужных добавляешь, остальные в игноре.
TreeDogNight; +1 Ответить
48. Vigor06 14.04.16 12:19 Сейчас в теме
(31) TreeDogNight, Ну и Вам адресую этот вопрос)

Есть ли варианты кроме перебора дерева с поиском значения message_id?
49. PLAstic 285 25.04.16 10:11 Сейчас в теме
(48) Vigor06, если сформулируешь вопрос точнее, вероятно, сможет помочь более широкий круг.
47. Vigor06 14.04.16 12:02 Сейчас в теме
(30) iolko, а можно чуть поподробнее,как полученные двоичные данные загнать массив?
36. vmannoor 20.12.15 22:44 Сейчас в теме
(24) eskor,
Можно использовать "%0D%0A" Вместо Символы.ПС
37. eskor 94 22.12.15 11:17 Сейчас в теме
(36) vmannoor, да, это оно. Теперь переносы расставляются корректно!!! Спасибо.
26. TreeDogNight 21 05.12.15 10:29 Сейчас в теме
Теперь у меня встал новый вопрос. Как вывести клавиатуру?

Как я понял, мы должны передать в метод sendMessage сериализованную JSON-структуру, но к сожалению примеров этой структуры нигде не приводится...
28. TreeDogNight 21 07.12.15 19:04 Сейчас в теме
Уже пробовал использовать запрос POST, сделал так:
Соединение  = Новый HTTPСоединение(Объект.Сервер,443,,,,,Новый ЗащищенноеСоединениеOpenSSL());		 
Заголовки   = Новый Соответствие;
Заголовки.Вставить("reply_markup", ТекстJSON);
Запрос	    = Новый HTTPЗапрос(Ресурс, Заголовки);
Ответ	    = Соединение.ОтправитьДляОбработки(Запрос);

Где ТекстJSON равен:
[
{
"Да": "Так точно!"
},
{
"Нет": "Никак нет"
}
]

Но к сожалению клавиатура не появилась... Либо текст JSON неправильно сформировали, либо его нужно сувать не в заголовки...
29. TreeDogNight 21 07.12.15 21:25 Сейчас в теме
Всё, наконец разобрался с этой клавиатурой!
Оказывается текст с параметрами нужно было приклеить к строке с ресурсмом и установить как тело запроса!
Вот код:
&НаСервереБезКонтекста
Функция ПолучитьКлавиатуру()

	ГлавныйМассив = Новый Массив;
	
	МассивКнопок = Новый Массив;
	МассивКнопок.Добавить("Так точно!");
	МассивКнопок.Добавить("Никак нет!");
	ГлавныйМассив.Добавить(МассивКнопок);
	
	МассивКнопок = Новый Массив;
	МассивКнопок.Добавить("Я подумаю...");
	ГлавныйМассив.Добавить(МассивКнопок);
	
	ПутьКФайлу = ПолучитьИмяВременногоФайла("txt"); 	
	
	Структура = Новый Структура;
	Структура.Вставить("keyboard"			, ГлавныйМассив);
	Структура.Вставить("one_time_keyboard"	, Истина);
	
	Файл = Новый ТекстовыйДокумент;
	Файл.Записать(ПутьКФайлу, "UTF-8");
	
	ЗаписьJSON = Новый ЗаписьJSON;
	ЗаписьJSON.ОткрытьФайл(ПутьКФайлу);
	ЗаписатьJSON(ЗаписьJSON, Структура);
	ЗаписьJSON.Закрыть();
	
	Файл.Прочитать(ПутьКФайлу, "UTF-8");
	
	ТекстJSON = Файл.ПолучитьТекст();
	ТекстJSON = СтрЗаменить(ТекстJSON, "Истина", "True");
	
	Возврат ТекстJSON;

КонецФункции

&НаСервере
Процедура ОтправитьСообщение(chat_id, ТекстСообщения, СтилизованныйТекст = Ложь, ОтображатьСсылки = Ложь, IDСообщенияДляОтвета = 0, Клавиатура = "")
	
	ПараметрыЗапроса = "?chat_id=" + Формат(chat_id, "ЧГ=0") + "&text=" + ТекстСообщения;
	
	Если СтилизованныйТекст = Истина Тогда 
		ПараметрыЗапроса = ПараметрыЗапроса + "&parse_mode=Markdown";	
	КонецЕсли;
	
	Если ОтображатьСсылки = Истина Тогда 
		ПараметрыЗапроса = ПараметрыЗапроса + "&disable_web_page_preview=True";	
	КонецЕсли;
	
	Если IDСообщенияДляОтвета > 0 Тогда 
		ПараметрыЗапроса = ПараметрыЗапроса + "&reply_to_message_id=" + Формат(IDСообщенияДляОтвета, "ЧГ=0");	
	КонецЕсли;
	
	Если Не ПустаяСтрока(Клавиатура) Тогда 
		ПараметрыЗапроса = ПараметрыЗапроса + "&reply_markup="+Клавиатура;	
	КонецЕсли;
			                                                    
	Ресурс 		= "bot" + Объект.Токен + "/sendMessage"+ПараметрыЗапроса;
	Соединение  = Новый HTTPСоединение(Объект.Сервер,443,,,,,Новый ЗащищенноеСоединениеOpenSSL());	      
	Запрос		= Новый HTTPЗапрос(Ресурс);
	Запрос.УстановитьТелоИзСтроки(ПараметрыЗапроса);
	Ответ		= Соединение.ОтправитьДляОбработки(Запрос);          
	
КонецПроцедуры
Показать
Kireno; maksa2005; mevgenym; AlX0id; JohnyDeath; ui69; rayastar; Renegade; Anchoret; madonov; METAL; WanGoff; _also; Luchik; eskor; +15 Ответить
161. user853472 25.02.18 22:11 Сейчас в теме
Подскажите как вывести фото с кнопками обратной связи?

Фото получается отослать, а вот вывести вместе с клавиатурой вообще никак....

////КЛАВИАТУРА
				клСтруктура = Новый Структура;
				мСтрок = Новый Массив;
				мКнопок = Новый Массив;
				мКнопок.Добавить(Новый Структура("text, callback_data", "В корзину", Блюдо.Ссылка.Код));
				мСтрок.Добавить(мКнопок);	
				клСтруктура.Вставить("inline_keyboard",мСтрок);
				ЗаписьJSON = Новый ЗаписьJSON;
				ЗаписьJSON.УстановитьСтроку();  //Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет,,,ЭкранированиеСимволовJSON.СимволыВнеASCII)  
				ЗаписатьJSON(ЗаписьJSON,клСтруктура,,);
				Клавиатура = ЗаписьJSON.Закрыть();
				
				ТекстДляОтправки = ТекстДляОтправки + "--" +  Boundary + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""reply_markup""" + Символы.ПС + Символы.ПС;    
				ТекстДляОтправки = ТекстДляОтправки + СокрЛП(Клавиатура) + Символы.ПС;
Показать
32. iolko 290 09.12.15 07:53 Сейчас в теме
Легко... если пользователь отправляет команду, допустим MyId - то отправляешь ему Его ID дальше ручками вносишь ее в спр пользователи.
а потом уже, чтобы отсеить ненужных проверяешь если ChatId есть в спр пользователей - велком , если нет ну не судьба тогда )))
TreeDogNight; +1 Ответить
38. TreeDogNight 21 23.12.15 05:06 Сейчас в теме
 HTTPЗапрос.Заголовки.Вставить("Content-Type", "multipart/form-data; boundary="+Boundary);

Какой нужно указывать Content-Type если передаешь фото или видео?
39. iolko 290 21.01.16 17:16 Сейчас в теме
Всем придоброго. Не уверен, что модераторы пропустят отдельный пост, по этому отпишу так. С 1Си Telegram разобрался, отчеты, логи статусы и пр отсылает. Но вот решил дома прикрутить. Итог... возможности: Выключить комп, сделать снимок с камеры и передать, принять торрент файл и скачать его, запустить upnp сервак для того чтобы посмотреть его на smart tv.

Автору статьи - миль пардон, надеюсь не удалит комент. Если кому то нужны сорцы - пишите. Все на python. Скрипт в автозагрузке, работает на ура.
40. maxx 958 22.01.16 16:43 Сейчас в теме
Здорово. Но файл отправить всё-таки не получилось, по отладке отправляет, ошибок нет, но файл не приходит.

Всё-так получилось к функции отправки нужно ещё добавить:
Таб.Записать(ИмяФайла,ТипФайлаТабличногоДокумента.XLSX);


также обернуть число chat_id в обертку
 ТекстДляОтправки = ТекстДляОтправки + СтрЗаменить(Формат(chat_id, "ЧДЦ=; ЧС=; ЧРГ=."), ".", "") + Символы.ПС;
rayastar; +1 Ответить
42. PLAstic 285 09.03.16 11:08 Сейчас в теме
(40) maxx, ой, да, ещё вот это недоразумение
СтрЗаменить(Формат(chat_id, "ЧДЦ=; ЧС=; ЧРГ=."), ".", "")

надо исправить на следующее:
Формат(Выборка.chat_id, "ЧГ=")
41. PLAstic 285 02.03.16 16:17 Сейчас в теме
Небольшие оптимизации.

Можно получать из HTTPОтвет и просто текст, а не двоичные данные:

В процедуре ПоказатьСообщения текст
	ДвоичныеДанныеОтвета = Ответ.ПолучитьТелоКакДвоичныеДанные();

заменить на:
	ТекстовыеДанныеОтвета = Ответ.ПолучитьТелоКакСтроку();


Теперь можно вызывать процедуру ПрочитатьДвоичныеДанныеОтвета, передавая ей текстовую строку. Зачем? Чтобы не записывать эти двоичные данные в файл и не читать из него назад:

Процедура ПрочитатьДвоичныеДанныеОтвета(ДвоичныеДанныеОтвета)
            ИмяФайла = ПолучитьИмяВременногоФайла("tgm");
            ДвоичныеДанныеОтвета.Записать(ИмяФайла);
            ДеревоЗн = Новый ДеревоЗначений();
            //{Для версии 1С 8.3.6 и выше
            ЧтениеJSON = Новый ЧтениеJSON();
            ЧтениеJSON.ОткрытьФайл(ИмяФайла);

заменить на:
Процедура ПрочитатьДвоичныеДанныеОтвета(ТекстовыеДанныеОтвета)
	ДеревоЗн = Новый ДеревоЗначений();
	ЧтениеJSON = Новый ЧтениеJSON();
	ЧтениеJSON.УстановитьСтроку(ТекстовыеДанныеОтвета);


Испытал удивление от потэгового анализа JSON. Есть функция ПрочитатьJSON(), которая в структурированном виде считывает весь пакет:

	ЧтениеJSON = Новый ЧтениеJSON();
	ЧтениеJSON.УстановитьСтроку(ТекстовыеДанныеОтвета);
	Результат = ПрочитатьJSON(ЧтениеJSON);
	ЧтениеJSON.Закрыть();

	Если НЕ Результат.ok Тогда
		Возврат;
	КонецЕсли;

	СписокЗапросов = Результат.result;
	Для каждого Запрос Из СписокЗапросов Цикл
		...
	КонецЦикла;
Показать
mpeg1989; Anchoret; 7OH; drjc; biformatus; Luchik; +6 Ответить
43. Crush 10.03.16 12:13 Сейчас в теме
Спасибо! Изложено легко и понятно. Получилось с первого раза.
44. Dobermann86 30.03.16 07:40 Сейчас в теме
Кто нибудь подскажет как ботом получить файл(или фото) в 1С и дальше сохранить его на HDD?
45. Dobermann86 30.03.16 13:00 Сейчас в теме
//Определение имён файла и пути файла криво написано. Но это на скорую руку чтобы проверить.
//Сильное не пинайте. Если получится скачивать файлы тогда и оформлю.

//getfile - Определение пути файла по id_file
https://api.telegram.org/bot<Токен>/getfile?file_id=<ид_файла>;
//file - Прямая ссылка на файл
https://api.telegram.org/file/bot<Токен>/photo\/file_1.jpg
Процедура СкачатьФайл(id_file);
		////////////////////////////////////////////////////////////­///////////////// Определение пути к файлу
		Ресурс = "/bot" + Токен + "/getfile?file_id=" + id_file;
		Соединение  =  Новый HTTPСоединение(Сервер,443,,,,,Новый ЗащищенноеСоединениеOpenSSL());
		
		Запрос = Новый HTTPЗапрос(Ресурс);
		Ответ = Соединение.Получить(Запрос);
		
		ДДСО= Ответ.ПолучитьТелоКакСтроку();//ДвоичныеДанныеСтрокаОтвета 
		
		Если Найти(ДДСО,"photo\") Тогда
			ПутьКФалу = Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3);
			ИмяСохраненияДляФайла = Сред(Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3),8,1024);
		
                ИначеЕсли Найти(ДДСО,"document\") Тогда
			ПутьКФалу = Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3);
			ИмяСохраненияДляФайла = Сред(Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3),11,1024);

		КонецЕсли;

                ////////////////////////////////////////////////////////////­///////////////// Скачивание самого файла
		
		Ресурс = "/file/bot" + Токен + "/" + ПутьКФалу;

		Соединение  =  Новый HTTPСоединение(Сервер,443,,,,,Новый ЗащищенноеСоединениеOpenSSL());
		
		HTTPЗапрос = Новый HTTPЗапрос(Ресурс);
		
		//И вот тут ступор возвращаемые значения 404 и т.д.
		//с http дел не имел. Не знаю что думать.
	        //можно Соединение.Получить(HTTPЗапрос, "C:\" + ИмяСохраненияДляФайла); - но получается файл с ошибкой 404 в нутри
КонецПроцедуры;
Показать
50. PLAstic 285 25.04.16 10:25 Сейчас в теме
(45) Немного оптимизации:
1) надо получить file_path
2) надо принять файл с этим file_path

Сначала получаем всю инфу о файле. Например, это текстовый документ.
Информация о файле в сообщении получается так:
Документ = ДанныеЗапроса.message.document;

Далее строим запрос, имея file_id этого файла:
Ресурс = "bot" + Объект.Токен + "/getFile?file_id=" + Документ.file_id;

В ответ приходит JSON, который парсим стандартно:
Соединение = Новый HTTPСоединение(Объект.Сервер, 443,,,,, Новый ЗащищенноеСоединениеOpenSSL());
Запрос = Новый HTTPЗапрос(Ресурс);
Ответ = Соединение.Получить(Запрос);
ТекстовыеДанныеОтвета = Ответ.ПолучитьТелоКакСтроку();

ЧтениеJSON = Новый ЧтениеJSON();
ЧтениеJSON.УстановитьСтроку(ТекстовыеДанныеОтвета);
Результат = ПрочитатьJSON(ЧтениеJSON);
ЧтениеJSON.Закрыть();

Если НЕ Результат.ok Тогда
  Сообщить("Что-то пошло не так...");
  Возврат;
КонецЕсли;
ПутьКФайлу = Результат.result.file_path;
Показать

Теперь, имея file_path, полученный из структуры, как сказано в апи, "описывающей подготовленный к скачиванию файл", мы можем его скачать:
Ресурс = "file/bot" + Объект.Токен + "/" + ПутьКФайлу;
Соединение = Новый HTTPСоединение(Объект.Сервер, 443,,,,, Новый ЗащищенноеСоединениеOpenSSL());
Запрос = Новый HTTPЗапрос(Ресурс);
Ответ = Соединение.Получить(Запрос);
ТекстовыеДанныеОтвета = Ответ.ПолучитьТелоКакСтроку();

Обращаю внимание, что метод ПолучитьТелоКакСтроку() актуален только для текстовых файлов. В остальных случаях надо получать бинарные данные и записывать их в файл. В нашем же случае переменная ТекстовыеДанныеОтвета будет содержать текст файла.
artb; Renegade; drjc; +3 Ответить
126. rayastar 1160 28.06.17 18:07 Сейчас в теме
46. Dobermann86 30.03.16 13:50 Сейчас в теме
Допетрил.
Процедура СкачатьФайл(id_file);
        ////////////////////////////////////////////////////////////­///////////////// Определение пути к файлу
        Ресурс = "/bot" + Токен + "/getfile?file_id=" + id_file;
        Соединение  =  Новый HTTPСоединение(Сервер,443,,,,,Новый ЗащищенноеСоединениеOpenSSL());
        
        Запрос = Новый HTTPЗапрос(Ресурс);
        Ответ = Соединение.Получить(Запрос);
        
        ДДСО= Ответ.ПолучитьТелоКакСтроку();//ДвоичныеДанныеСтрокаОтвета 
        
        Если Найти(ДДСО,"photo\") Тогда
            ПутьКФалу = Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3);
            ИмяСохраненияДляФайла = Сред(Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3),8,1024);
        
                ИначеЕсли Найти(ДДСО,"document\") Тогда
            ПутьКФалу = Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3);
            ИмяСохраненияДляФайла = Сред(Сред(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024),0,СтрДлина(Сред(ДДСО, Найти(ДДСО,"""file_path""") +13 ,1024))-3),11,1024);

        КонецЕсли;

                ////////////////////////////////////////////////////////////­///////////////// Скачивание самого файла
        
        Ресурс = "htpps://" + Сервер + "/file/bot" + Токен + "/" + СтрЗаменить(ПутьКФалу,"\","/");
           КопироватьФайл(Ресурс,"C:\" + ИмяСохраненияДляФайла); 

КонецПроцедуры;
Показать
rayastar; +1 Ответить
125. rayastar 1160 28.06.17 16:58 Сейчас в теме
(46)
Ресурс = "htpps://" + Сервер + "/file/bot" + Токен + "/" + СтрЗаменить(ПутьКФалу,"\","/");
КопироватьФайл(Ресурс,"C:\" + ИмяСохраненияДляФайла);


Приветствую!
делаю по Вашему подобию, но возникает ошибка при скачивании:

{ВнешняяОбработка.Telegram.Форма.ФормаУпр.Форма(145)}: Ошибка при вызове метода контекста (КопироватьФайл): Ошибка копирования файлов: Неправильный путь к файлу 'htpps://api.telegram.org/file/bot***/documents/file_19.txt'. Схема не зарегистрирована

ругается вот здесь:
КопироватьФайл(Ресурс,"C:\" + ИмяСохраненияДляФайла);

в чем может быть проблема?
127. PLAstic 285 28.06.17 18:36 Сейчас в теме
(125) За такой код надо руки отрывать автору в (46). Что пытаетесь сделать?
51. =Kollega= 3 19.05.16 14:51 Сейчас в теме
Хорошая статья, доходчиво и понятно. Правда до всего практически дошел сам, курением над FAQ-ом и методом проб и ошибок. Единственное уточнение - файл в формате excel отправленный ботом, приходит немного битым. Excel, конечно его восстанавливает, но осадок остается.
Проблема в объединении файлов, а точнее в последнем файле-окончании. Мы открываем его в UTF-формате, что приводит к записи 3-х дополнительных байт идентификаторов формата. В итоге файл приходит именно с этими 3-мя лишними байтами. Для некоторых файлов может это и не критично и незаметно, но Excel 2012 ругается на поврежденный файл.
Проблему решил просто - окончание открываю в формате ANSI, а не UTF.
dremlin_rus; +1 Ответить
52. Vigor06 27.05.16 15:09 Сейчас в теме
(51) =Kollega=, о,это хорошая помощь!
Но у меня все равно экселька в таком виде приходит...


Сохраняю как xls, офис 2013й

Как победить можно?какие кодировки попробовать?
53. Vigor06 30.05.16 10:54 Сейчас в теме
(52) Vigor06, разобрался)
Строку
ТабДок.Записать(ИмяФайла,"xls");

заменил на
ТабДок.Записать(ИмяФайла,ТипФайлаТабличногоДокумента.XLS);
54. foralex2004 14.06.16 12:26 Сейчас в теме
Уважаемые форумчане.
Был бы признателен за пример чтения сервиса Telegram, когда ты не не являешься владельцем бота.
Т.е. тебе не известен токен бота.
Например я хочу считывать данные как пользователь у бота StrafyBot.
Спасибо.
55. PLAstic 285 16.06.16 23:36 Сейчас в теме
(54) foralex2004, Никак. Если бы можно было так легко читать сообщения, то какая тут приватность?
56. foralex2004 20.06.16 17:19 Сейчас в теме
Я же могу через WEB с ботом общаться, почему не могу посредством API?
Прикрепленные файлы:
57. eskor 94 20.06.16 17:48 Сейчас в теме
(56) foralex2004, читай описание. Здесь обсуждается управление СВОИМ ботом из 1С. Хочешь общаться с другим ботом - без проблем, получи его ID и заставь своего бота обращаться к другому.
58. Punk 22.06.16 15:15 Сейчас в теме
(57) eskor, Боты не могут видеть сообщения от других ботов. Сделано в целях защиты от бесконечной рекурсии. (По крайней мере в справке так написано)
61. eskor 94 22.06.16 23:02 Сейчас в теме
(58) Punk, я не скажу, что могут или не могут видеть, по моему это лишнее. Принципиально, каждый из респондентов имеет свой id, и на запрос бот отвечает тому же id. Сам ботов не "дружил", но что мешает проверить? Механика процессов простая, я сменил место работы, сейчас другие проекты и задачи, так что проверить не на чем.
59. Punk 22.06.16 15:30 Сейчас в теме
Доброго времени суток уважаемые форумчане!
Подскажите пожалуйста, если кто работал через webhook, как можно установить вебхук имея самоподписанный сертификат?
Или если конкретнее, как указать второй параметр certificate?

Делаю примерно так:

Сервер            = "api.telegram.org";
АдресБазы      = "https://<MойСервер>:8443/<МояБаза>/hs/<МойСервис>/";	
АдресВебХука = АдресБазы<ТокенБота>;	
Команда          = "setWebhook";
Ресурс             = "bot"<ТокенБота> + "/" + Команда + "?url=" + АдресВебХука + "&certificate=C:\ИмяСертификата.pem";	
	
Соединение = Новый HTTPСоединение(Сервер, 443,,,,,Новый ЗащищенноеСоединениеOpenSSL);
	
Запрос = Новый HTTPЗапрос(Ресурс); 
	
Ответ = Соединение.Получить(Запрос); 
Показать


В ответ приходит что вебхук успешно установлен, но сообщения на http-сервис не идут. :(
60. Luchik 641 22.06.16 16:25 Сейчас в теме
(59) Punk, В переменной Ресурс не надо указывать адрес к файлу сертификата, но указать сертификат в конструкторе Новый HTTPСоединение().
примерно так (сейчас не имею возможности посмотреть в синтакс-помощнике):
Сертификат = Новый СертификатКлиентаФайл("C:\ИмяСертификата.pem");//вторым параметром можно указать пароль файла клиентского сертификата
ssl = Новый ЗащищенноеСоединениеOpenSSL(Сертификат);
Соединение = Новый HTTPСоединение(Сервер, 443,,,,,ssl);
62. Punk 23.06.16 10:46 Сейчас в теме
(60) Сделал как вы сказали. Но увы, http сервис все равно молчит.
Пробовал указывать сертификат с паролем и без.
Тестовый Http сервис использует метод Post и просто создает новый элемент справочника.
При отправке запроса на данный сервис с помощью утилиты "Fiddler 4" получаем ответ с кодом 200 и имеем новый элемент справочника.

Может есть какие подводные камни о которых необходимо знать?
81. biformatus 26.08.16 19:08 Сейчас в теме
(59) Punk, Получилось в итоге? Как вообще получить pem сертификат. Сертификат вообще делал по статье http://infostart.ru/public/146288/.
137. Al-77 71 22.09.17 15:07 Сейчас в теме
(59) Добрый день. вы победили сертификаты ?
219. Goody 114 04.11.21 14:08 Сейчас в теме
(59) Чтобы повесить вебхук на защищенный порт 443 требуется сертификат. Вот тут я привел пример как это сделать https://infostart.ru/1c/articles/1542836/
64. Luchik 641 07.08.16 13:11 Сейчас в теме
Предположу, что это может произойти по причине того, что история хранится за определенный период (т.е. сообщения пользователей остались в удаленном периоде)
65. DanilaDru 263 08.08.16 14:46 Сейчас в теме
(64) Спасибо, этот вопрос решил. Была история зачищена.

А кто-то решал задачу идентификации ? Вот пришёл мне от бота запрос, я вижу что это какой-то id пользователя телеграмма.

А как-то получалось достучаться до номера телефона ? Например я по номеру телефона понимаю что это за контрагент и даю ему текстовое представление по его заказам в системе.
66. Luchik 641 12.08.16 14:48 Сейчас в теме
(65) DanilaDru, идентификация у меня осуществляется по регистру сведений; Id, сотрудник. Получить номер телефона бот не может - прочитайте все возможные функции API Телеграма - https://core.telegram.org/
67. eskor 94 15.08.16 09:49 Сейчас в теме
(66) телефон получить не может, а вот имя и никнейм запросто, я так и запускал пользователей. Пишу в лог все обращения, нужным даю доступ.
68. PLAstic 285 16.08.16 12:05 Сейчас в теме
(65) DanilaDru, (67) eskor, мне кажется, удобнее было бы сделать так: клиент регается у бота (не важно, как конкретно: либо любое новое сообщение боту и бот предлагает зарегаться, или же специальная команда вроде /regme). Когда он регается у бота, то указывает свой ИНН, мыло или телефон - любую КИ, которая содержится у вас в базе и может использоваться для идентификации контрагента.
Далее вы этому заявленному, но не подтверждённому контрагенту, проверив его наличие по базе, шлёте сообщение вроде "Вы или кто-то от вашего имени пытается зарегаться у нашего бота. Если это вы, введите код подтверждения такой-то". Код подтверждения - например, 4хзначное число. Бот в это время, конечно, ожидает код подтверждения, записанный, например, в РС. Как только он его получает, привязываем ид пользователя телеграм к контрагенту в базе. Можно завести его видом КИ и привязывать как к контрагенту, так и его контактным лицам.
69. eskor 94 17.08.16 09:30 Сейчас в теме
(68) PLAstic, чисто технически реализовать легко. Возможно, где-то и есть надобность массовой регистрации. Конкретно в моем случае, бот использовался для получения оперативной информации. Соответственно, пользователей использующих бот было не больше 2х десятков и больше не планировалось. Я, конечно, упростил механизм управления доступом(для себя любимого), но дальше развиваться было некуда.
Для сторонних клиентов все равно придется использовать СМС шлюз, а следовательно смысл бота для сторонних пользователей является избыточным.
70. marat.coolls 17.08.16 12:07 Сейчас в теме
Не подскажите, как можно осуществить следующее. Боту пишут в телеграмм задание текстовое, а он сохраняет его в 1с в отдельный документ(задачи).
71. PLAstic 285 17.08.16 21:45 Сейчас в теме
(70) marat.coolls, Статья именно об этом. Пишете бота, который анализирует присылаемые сообщения и по какому-нибудь признаку выделяет из них задачи и записывает в базу 1С.
marat.coolls; +1 Ответить
72. marat.coolls 18.08.16 08:26 Сейчас в теме
(71) Я пробовал сделать все по инструкции. Но бот никак не реагирует на команды, да и приветствие не выводит. Токен и имя правильно написал, т.к 1с ка показывает когда я писал и мой ID. Но ни приветствия от бота, ни списка команд нет. В чем может быть проблема?
73. Luchik 641 18.08.16 09:28 Сейчас в теме
(72) marat.coolls, а регламентное задание точно выполняется?
74. marat.coolls 18.08.16 09:34 Сейчас в теме
(73) Через отладчик посмотрел, после заполнения дерева ничего не выполняется. Но код ведь тот же. В чем проблема не пойму , уже два дня мучаюсь.
75. eskor 94 18.08.16 09:51 Сейчас в теме
(74) marat.coolls, последовательность выполнения на стороне 1С:
1. Получить набор сообщений бота с хоста telegramm.
2. Обработать полученные данные.
3. Кому необходимо - отправить сообщения на хост telegramm.
Соответственно все форматы должны соответствовать.
Чудес не бывает, проверяй лучше.
76. marat.coolls 18.08.16 10:40 Сейчас в теме
(75) eskor, Тут все работает и автор все написал правильно? если да, то у меня тоже все соответствует. Потому что мой метод Ctrl+c Ctrl+v
77. PLAstic 285 18.08.16 16:00 Сейчас в теме
(76) marat.coolls, там есть ручная однократная проверка сообщений для бота и рег.задание. Попробуй ручками, что будет?
*я плохо помню оригинал из статьи, но в моей версии это точно есть и оно работает
78. eskor 94 19.08.16 09:00 Сейчас в теме
(76) marat.coolls, я использовал куски кода из примера, реализовывал на обычных формах, плюс навешивал кучу функций сверху из разряда регистрации обращений и выполнения, справочника на несколько ботов, справочника выполняемых функций и т.п. Запустил все это где-то в январе, с тех пор работает как часы, добавляю только функции в справочник и пользователей в доступ.
Оставьте свое сообщение

См. также

Конфигурация для просмотра публичных телеграм каналов Промо

Боты v8 Абонемент ($m)

Просмотр и каталогизация в более удобном виде публичных телеграм каналов, групп и чатов.

1 стартмани

02.06.2018    24859    13    DO_WHILE_LOOP    7    

Бесплатная отправка сообщений в Whatsapp бот из 1С

Боты v8 1cv8.cf Абонемент ($m)

Задача: Имеются 200 контрагентов, которым ежедневно нужно из отчета 1С выслать сумму их задолженности или предоплаты в Whatsapp (рассылка должна идти с номера менеджера этих контрагентов).

2 стартмани

08.06.2022    4518    14    John_d    44    

Telegram бот для УТ 11

Боты v8 УТ11 Россия УУ Абонемент ($m)

Бот умеет формировать заказы клиентов в базе УТ 11, осуществлять согласование заказов, показывать остатки товара и отправлять информацию рекламного или справочного характера в ответ на введенную клиентом команду. Предназначен для самостоятельной работы клиентов (дилеров) и сотрудников вашей компании. Файл поставки предназначен для встраивания силами программиста 1С. Связь с чат ботом реализована через HTTP Запрос. При необходимости могу адаптировать и доработать бота для вашей конфигурации. Могу добавить функционал отправки произвольных сообщений клиентам, сотрудникам компании, служебной информации, опросов, верификацию клиентов по номеру телефона и т.д.

10 стартмани

16.03.2022    2121    6    Pira    3    

Telegram. Пример реализации

Боты v8 Абонемент ($m)

Пример реализации основных возможностей работы с Telegram ботом из 1С. Файл с выгрузкой базы предназначен для ознакомления с основными возможностями. Файл с конфигурацией предназначен для использования программистами в качестве базы для настройки вашего чат бота.

5 стартмани

16.12.2021    3066    19    Pira    3    

1С: Предприятие + корпоративный чат, как наладить оперативные уведомления за 10 минут Промо

Боты v8 Абонемент ($m)

Как сделать автоматические уведомления о разных событиях из 1С в корпоративный чат MyChat для сотрудников компании

1 стартмани

14.08.2016    58760    36    Demanoidos    60    

Стек технологий для 1С

Инструментарий разработчика Рефакторинг и качество кода Тестирование QA Групповая разработка (Git, хранилище) Механизмы платформы 1С Бесплатно (free)

Стек технологий, которые могут быть полезны разработчику на 1С и около 1С. По каждой технологии постарался объяснить, зачем она нужна и с чего начать изучение, если заинтересует.

29.11.2021    19249    mrXoxot    78    

Механизм контроля работы приложений на вашем ПК с помощью Telegram бота

Боты v8 v8::УФ Абонемент ($m)

Данная разработка представляет собой конфигурацию для 1С 8.3, в которой реализованы механизмы работы с Telegram ботом и ОС Windows. А именно, выполняется отслеживание работы приложений на вашем ПК, с возможностью контроля их работы. При помощи Telegram можно смотреть список работающих приложений на вашем ПК, завершать работу, блокировать и разблокировать эти приложения.

5 стартмани

23.09.2021    2210    1    serg1234    0    

Центр управления ботами

Боты v8 Абонемент ($m)

Небольшая конфигурация для управления telegram-ботами

26.08.2021    3030    0    nekiy    0    

Telemonitor - объединяем Telegram и 1С Промо

Боты v8 1cv8.cf Абонемент ($m)

Не так давно Telegram предоставил API для создания ботов. Telemonitor - программа, позволяющая легко настроить собственного бота для работы с 1С.

1 стартмани

09.08.2015    87451    236    salexdv    186    

Бот для Telegram, показывающий остатки и заказы поставщикам из 1С: Управление торговлей

Боты v8 ERP2 УТ11 КА2 УУ Абонемент ($m)

Разработка позволяет получать на смартфоне, через мессенджер Телеграм, необходимую информацию о товарах. Есть ли товар в свободном остатке и сколько штук? Есть ли товар в заказах поставщикам? Сколько штук заказано? Когда должен придти? Разработка будет полезна сотрудникам, у которых нет стационарного рабочего места, но которым нужно получать информацию из 1С (например, курьеры или монтажники на объекте).

1 стартмани

04.05.2021    4977    17    simuljakr    9    

Уведомления 1С: Документооборот через Telegram

Боты v8 ДО Россия УУ Абонемент ($m)

В данной публикации я хочу поделиться расширением, с помощью которого можно отключить создание задач ознакомления для бизнес-процессов "Согласование" и "Утверждение" в 1С: Документооборот. Изменен штамп электронной подписи. Также был добавлен модуль для уведомления пользователей через Telegram.

1 стартмани

27.04.2021    4960    20    dronicbest    3    

Проверка работы УТМ ЕГАИС и проверка работы обменов РИБ для Розница, редакция 2.3 с отправкой уведомлений в Телеграм

Боты v8 Розница Россия УУ Абонемент ($m)

Мониторинг работы обменов РИБ, работы УТМ на рабочих местах, проверка загрузки документов ЕГАИС для конфигурации Розница 2.3 с отправкой уведомлений в чат мессенджера Телеграм.

3 стартмани

16.03.2021    3558    3    user1056696    0    

Удаленное управление через Skype Промо

Боты v8 1cv8.cf Абонемент ($m)

Удаленное управление 1С через Skype. Со стороны клиента для работы нужен только Skype. Со стороны сервера любой компьютер с 1С.

1 стартмани

09.02.2014    50442    68    moolex    29    

Массовая рассылка документов контрагентам через Whatsapp

Боты v8 v8::БУ БП3.0 Россия БУ Абонемент ($m)

Рассылает списку контрагентов выбранные печатные формы через Whatsapp. Тестировалась на Бухгалтерии 3.0.87.28.

2 стартмани

16.01.2021    5682    9    Плюшкин_    0    

Простая отправка сообщений в WhatsApp через шлюз chat-api.com

Боты v8 Россия Абонемент ($m)

Это простейшая обработка на обычных формах, которая показывает, как легко отправлять сообщения в WhatsApp через шлюз chat-api.com. Можно дорабатывать для создания списка рассылок, для информирования клиентов о статусе заказа и т.д.

1 стартмани

16.12.2020    13906    13    AlxPop    0    

Интеграция мессенджеров (WhatsApp, Telegram, Viber, и тд) в 1С при помощи Chat2Desk

Боты v8 1cv8.cf Абонемент ($m)

Подсистема для интеграции произвольной конфигурации с Chat2Desk. Общайтесь с клиентами в мессенджерах и контролируйте переписку менеджеров не выходя из 1С. Создайте связь между чатами и вашей учетной системой.

1 стартмани

23.10.2020    8470    22    Segate    18    

1С заговорила - голосовой информатор через Skype Промо

Боты v8 1cv8.cf Абонемент ($m)

Обработка в статье позволяет получить аудиофайл с речью, сгенерированной компьютером на основе текстовой строки, позвонить собеседнику через Skype и произнести его. Функциональность выполнена на основе .Net framework и API для Skype. Разработка будет полезна не только для серьезных бизнес-приложений, но и для домашних опытов и шуток друзьям. Для звонков на реальные номера потребуется пополненный баланс на Skype.

1 стартмани

16.01.2013    20044    48    Elisy    16    

Чатбот WhatsApp

Боты v8 1cv8.cf Абонемент ($m)

Внешняя обработка для написания чат-бота WhatsApp

1 стартмани

21.10.2020    13423    32    ripreal1    30    

Чат бот 1С: Что ты умеешь ? Вывод вариантов действий (расширение)

Боты v8 ДО Россия Абонемент ($m)

Выводит все используемые состояния чат-бота на данный момент времени.

1 стартмани

05.10.2020    5372    1    floodprog    0    

Подключаем WhatsApp к 1С

Боты v8 1cv8.cf Абонемент ($m)

Обработка для быстрого подключения WhatsApp к любой конфигурации 1С.

1 стартмани

30.09.2020    18380    123    andrew_shamin    66    

Звонок через локальный Skype, по команде с терминальной 1С (RDP + Skype) Промо

Боты v8 1cv8.cf Россия Абонемент ($m)

Деловые контакты хранятся в 1С, 1С работает через RDP, скайп стоит на локальной машине - как позвонить из 1С?! Данная методика является одним из решением задачи связки RDP + SKYPE

1 стартмани

09.07.2012    21139    24    binex    15    

Программная настройка структуры отчета СКД и отправка отчета в Telegram

Боты v8 v8::СКД УПП1 Абонемент ($m)

Данная обработка является примером для программного формирования отчетов на СКД и отправка их в канал/группу Telegram.

1 стартмани

07.03.2020    5226    6    algabas    0    

Ретранслятор сообщений в WhatsApp без привязки к платным сервисам (нативное android приложение)

Боты v8 1cv8.cf Абонемент ($m)

По последним данным WhatsApp пользуется четверть населения планеты Земля. Однако на текущий момент у приложения нет бесплатного API для отправки сообщений (за исключением бизнес версии, которую непросто получить). Желающих предоставить платный доступ к этой возможности предостаточно, но цены стартуют от 100 $ в месяц. Данная разработка - нативное android приложение, которое использует ваш аккаунт WhatsApp, получает в формате json файл сообщений (телефон, текст, картинка) и рассылает их адресатам, в этот же файл записывается результат время и отправки. Это бесплатно, вы платите только за интернет трафик и за одноразовое приобретение данной обработки.

17.02.2020    9086    3    capitan    2    

Интеграция 1С с мессенджером WhatsApp через chat-api

Боты v8 1cv8.cf Россия Абонемент ($m)

Это не готовое решение для использования (разве что необходимо будет только массово отправлять сообщения получателям), данная разработка поможет быстрее понять, каким образом необходимо делать интеграцию 1С с мессенджером WhatsApp.

1 стартмани

23.01.2020    7301    54    Hawk_sib    4    

Telegram бот на 1С

Боты v8 1cv8.cf Абонемент ($m)

Telegram бот на 1С в виде внешней обработки, встраиваемой в типовые 1С 8.3.

1 стартмани

24.09.2019    29390    59    budidich    19    

Телеграм 1С – почти коробка

Боты v8 Абонемент ($m)

Почему это решение называется «почти коробка»? Потому, что это почти коробочное решение. С его помощью, просто добавив подсистему в конфигурацию, уже можно начинать взаимодействовать с мессенджером Telegram.

10 стартмани

20.08.2019    22804    45    zfilin    77    

Пример интеграции с Telegram

Боты v8 1cv8.cf Россия Абонемент ($m)

Обработка позволяет отправлять текстовые сообщения в Telegram. Разработана на простых формах.

1 стартмани

29.07.2019    4062    10    Dmitrij-2    1    

Отправление событий журнала регистрации в приватный / публичный канал Telegram в виде сообщений и файлов

Боты v8 v8::УФ Абонемент ($m)

Данная конфигурация позволяет получать события журнала регистрации в телеграм в виде сообщений и файлов.

1 стартмани

29.07.2019    9681    11    serg-lom89    0    

Работа с сервисами Telegram, OpenWeatherMap.org, курсы валют РБ

Боты v8 Абонемент ($m)

Небольшая конфигурация по работе с Telegram. Получение курсов валют, погоды по городу. Сказал бы, что это больше проба пера, а не готовая и быстро работающая. Для себя работать будет быстро)

1 стартмани

09.07.2019    5234    10    serg-lom89    2    

Чат (мессенджер) для управляемых форм 1С 8.3 (Расширение)

Боты v8 v8::УФ 1cv8.cf Абонемент ($m)

Представляю вам чат для управляемых форм платформы 8.3. Давно сталкивался с тем, что просят открыть какой-нибудь документ или справочник, тебе скидывают его номер или название, а ты потом ищешь его по базе. Вам это знакомо? Тогда этот чат для вас. Подробности ниже.

4 стартмани

27.06.2019    16324    34    Isa816    27    

Журнал Регистрации ➜ Телеграмм

Боты v8::УФ 1cv8.cf Россия Абонемент ($m)

Подключаемая обработка для рассылки ошибок журнала регистрации в телеграмм.

1 стартмани

14.05.2019    14314    29    🅵🅾️🆇    9    

WhatsApp чат для 1С

Боты v8 v8::УФ 1cv8.cf Абонемент ($m)

WhatsApp чат для 1С. Расширение конфигурации, подходит для любых конфигураций 1С (управляемые формы).

5 стартмани

15.04.2019    17944    44    ManyakRus    22    

Ошибки, предупреждения и прочее из журнала регистрации на почту и в Telegram автоматически (БП 3, ЗУП 3.1, УТ 11.4, ERP 2.4, Розница 2.2)

Боты v8 Розница УНФ ERP2 ЗКГУ3.0 БП3.0 УТ11 ЗУП3.x Абонемент ($m)

Данная обработка позволяет анализировать журнал регистрации с пользовательским отбором (4 критерия отбора) и высылать отчет пользователю с заданной периодичностью на электронную почту или в Телеграм. Возможно использовать как регламентное задание (автоматическая отправка отчетов по времени), непосредственно запускать из клиента, а также выгружать в форму обработки отфильтрованные данные из журнала регистрации без отправки.

2 стартмани

28.01.2019    17231    47    Redinternational    4    

СМС2 - эрзац-мессенджер в вашей конфигурации 1С

Боты v8 v8::УФ Абонемент ($m)

Обработка предоставит вам некоторый функционал мессенджера внутри используемой конфигурации. Вложения с файлами и ссылками, аватары у пользователей, всё это можно и в 1С.

1 стартмани

17.12.2018    11899    11    semagin@gmail.com    19    

Интеграция WhatsApp в 1С (botcorp.io и api-messenger.com)

Боты v8 Абонемент ($m)

Сейчас у WhatsApp более 1 млрд. пользователей во всём мире. В России мессенджер держится на верхних строчках по популярности среди всех мессенджеров. Из чего следует, что WhatsApp является самым желанным мессенджером для интеграции с 1С.

3 стартмани

22.11.2018    32938    64    17808849    51    

Бот для торговли на криптовалютной бирже Bittrex с интегрированным чат ботом telegram и нейросетями

Боты v8 Финансовые услуги, инвестиции Россия Абонемент ($m)

Бот для торговли на криптовалютной бирже bittrex с возможностью отчитываться и управляться через чат бот telegram.

10 стартмани

04.10.2018    6748    0    avalakh    4    

В Telegram из 1С: сообщения с эмодзи (смайлы, пиктограммы, иконки) пользователям и группам

Боты v8 v8::УФ 1cv8.cf Абонемент ($m)

Обработка отправляет сообщения с эмоджи (смайлы, иконки, пиктограммы) пользователю или группе в Телеграм. Она также показывает список пользователей и групп, которые связывались с Вашим ботом, из этого списка можно выбрать получателя сообщения.

1 стартмани

20.08.2018    24916    99    uno-c    28    

Отправка сообщений через Telegram (через прокси)

Боты v8 v8::УФ 1cv8.cf Абонемент ($m)

Простая обработка для отправки сообщений из 1с в Телеграм конкретному пользователю. Используя прокси-сервер: jqlwb.teletype

1 стартмани

20.07.2018    30471    30    Deda    15    

Telegram Native API

Боты v8::УФ 1cv8.cf Абонемент ($m)

Взаимодействие с Telegram без Bot API. Только C++ компоненты. Только хардкор.

1 стартмани

24.05.2018    27375    94    Infactum    58    

Выгрузка документов из БП 3.0 в Telegram

Боты v8 v8::БУ БП3.0 Абонемент ($m)

Обработка для конфигурации Бухгалтерия предприятия 3.0 выгружает документы в Телеграм канал или пользователю Телеграм.

10 стартмани

22.05.2018    8880    2    astracrypt    3    

Чат бот в 73 строки на 1С - ИИ наступает

Боты v8 1cv8.cf Абонемент ($m)

Интеграция с уже готовой системой чат-бота для различных случаев жизни. Используется API от DialogFlow Google. Обработка тестировалась на 1С:Предприятие 8.3 (8.3.10.2252) Должно работать на всех 8.3 версиях.

1 стартмани

09.04.2018    18356    31    Lapitskiy    7    

Отправка товаров в Telegram

Оптовая торговля Розничная торговля Боты v8 Розничная и сетевая торговля (FMCG) Оптовая торговля, дистрибуция, логистика УУ Абонемент ($m)

Конфигурация предназначена для отправки товаров в месенджер Telegram.

10 стартмани

21.03.2018    12556    6    astracrypt    12    

Оповещения из ЗУП и ERP в TELEGRAM

Боты v8 ERP2 ЗУП3.x Абонемент ($m)

Начитался статей про интеграцию 1С -> Telegram, решил аккумулировать опыт и попробовать сделать какую-нибудь полезную обработку. Как результат - внешняя обработка, уведомляющая ответственных сотрудников по расписанию о необходимости оплаты отпусков, материальной помощи, премий. Данные посылаются в виде PDF файла (Отчет, созданный на основании макета). Можно использовать обработку как обучающую. Тестировалось на ERP 2.4.2.139, на ЗУП 3.X тоже должно работать.

1 стартмани

01.03.2018    20857    64    khabibullin.tu    15    

Легкое тестирование бота телеграм

Боты v8 v8::УФ Розница УНФ ERP2 БП3.0 КА2 ЗУП3.x Абонемент ($m)

Упрощенная в использовании версия другого решения. В исходной версии была конфигурация. В моей только внешняя обработка. Плюс небольшой бонус: отправка сообщений из формы обработки.

1 стартмани

12.01.2018    13349    18    kwazi    2    

Отправка сообщений из 1C на Telegram средствами Python

Боты v8 Абонемент ($m)

Простой функционал для отправки сообщений в Telegram.

1 стартмани

23.11.2017    13109    5    IgorNastenko    7